AW: VBA Klick auf Zelle, Wert einfügen
05.09.2022 17:07:50
Daniel
Hi
probier mal das, kopiere dir diesen Code ins Modul des Tabellenblatts "SeiteA"
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim Zelle1 As Range
Dim Zelle2 As Range
Dim Txt As String
Set Zelle1 = Target
Txt = Intersect(Zelle1.EntireRow, Columns(1)).Value & " - "
Txt = Txt & Intersect(Zelle1.EntireColumn, Rows(2)).Value
Sheets("SeiteB").Select
On Error Resume Next
Set Zelle2 = Application.InputBox("Bitte Wert auswählen für " & vbLf & Txt, Type:=8)
On Error Goto 0
Application.Goto Zelle1
If Not Zelle2 Is Nothing Then Zelle1.Value = Zelle2(1).Value
Cancel = True
End Sub
zum ausführen mach in der SeiteA einen Doppelklick auf die Zelle, die du füllen willst.
der Code zeigt dir dann die Tabelle auf SeiteB und du kannst eine Zelle auswählen.
Bei OK springt der Code dann zurück und trägt den Wert von SeiteB in die doppeltgeklickte Zelle auf SeiteA ein.
eine andere Möglichkeit, nur mit Doppelklicks, wäre das:
dieser Code ins Modul des Blattes SeiteA:
Option Explicit
Public KopierenAusführen As Boolean
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
KopierenAusführen = True
Sheets("SeiteB").Select
End Sub
und dieser Code ins Modul von "SeiteB"
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Sheets("SeiteA").KopierenAusführen Then
Cancel = True
Sheets("SeiteA").Select
ActiveCell.Value = Target.Value
End If
End Sub
Private Sub Worksheet_Deactivate()
Sheets("SeiteA").KopierenAusführen = False
End Sub
hier dann einfach in SeiteA die Zelle doppeltklicken, die befüllt werden soll und direkt danach die Zelle in SeiteB.
wenn du zwischendurch das Blatt wechselst, wird die Anfrage gelöscht, dh es ist sichergestellt, dass die Aktion nur ausgeführt wird, wenn zuerst der Doppelklick in SeiteA und danach der Doppelklick in SeiteB erfolgt.
Gruß Daniel