Adressen in eine Zelle kopieren
05.12.2006 14:08:37
Tom
Franz hat mir am 14.10.06 sehr geholfen - siehe unten.
Nun möchte ich aber nur die Email-Adressen, die Spalte H stehen, auslesen, wenn in Spalte U ein X steht.
Wer hat ne Lösung?
Gruß
Tom
Hallo Tom,
ich hab die Funktion jetzt etwas allgemeiner aufgebaut. Optional kann jetzt ein 2. Zellbereich angegeben werden. Stimmt der Wert in diesem Bereich mit dem optionalen Begriff überein, dann wird die e-mail-Adresse nicht in die Liste aufgenommen.
Gruss
Franz
Function emailAdressen(Bereich As Range, Optional Ausnahme As Range, Optional Nicht As String) As Variant
'Bereich = Zellbereich mit den emailadressen in der 1. Spalte
'Ausnahme = Zellbereich mit speziellem Eintrag
'Zellbereiche für Bereich und Ausnahme müssen die gleichen Zeilennummern haben
'Nicht = Begriff im Zellbereich Ausnahme, bei Übereinstimmung wird e-mailadresse nicht in die Liste aufgenommen
Dim I As Long
If Ausnahme Is Nothing Then
For I = 2 To Bereich.Rows.Count
If Bereich(I, 1) <> "" Then
If emailAdressen = "" Then
emailAdressen = Bereich(I, 1)
Else
emailAdressen = emailAdressen & "; " & Bereich(I, 1)
End If
End If
Next I
Else
If Bereich.Row < Ausnahme.Row Or Bereich.Rows.Count <> Ausnahme.Rows.Count Then
MsgBox "Bereiche mit e-mailAdressen und Ausnahmen müssen die gleichen Zeilen beinhalten!"
emailAdressen = "Fehler"
Exit Function
End If
For I = 2 To Bereich.Rows.Count
If Bereich(I, 1) <> "" And Ausnahme(I, 1) <> Nicht Then
If emailAdressen = "" Then
emailAdressen = Bereich(I, 1)
Else
emailAdressen = emailAdressen & "; " & Bereich(I, 1)
End If
End If
Next I
End If
End Function
Die Formel in der Tabelle schaut dann z.B. so aus:
=emailAdressen(H7:H40;AF7:AF40;"Absage")