Ich habe in einem Tabellenblatt ca. 8000 Datensätze. Wenn z.B. in der Spalte D der Wert "MusterA" steht, dann soll in diesem Datensatz in der Spalte B ein kleines "c" eingetragen werden. wie würde hier bitte eine VBA Lösung lauten?
Danke
Josef
Option Explicit
Sub Test()
Dim Bereich As Range
Application.ScreenUpdating = False
Set Bereich = Range("D1", Cells(Rows.Count, "D").End(xlUp)).Offset(0, -2)
Bereich.FormulaR1C1 = "=IF(RC4=""MusterA"",""c"","""")"
Bereich.Value = Bereich.Value
Application.ScreenUpdating = True
End Sub
Gruß Tino
Option Explicit
Sub Test()
Dim Bereich As Range
Application.ScreenUpdating = False
Set Bereich = Range("D1", Cells(Rows.Count, "D").End(xlUp)).Offset(0, -2)
Bereich.FormulaR1C1 = _
"=IF(AND(RC4=""MusterA"",RC3=""MusterB""),""c"","""")"
Bereich.Value = Bereich.Value
Application.ScreenUpdating = True
End Sub
Gruß Tino
Option Explicit
Sub Test()
Dim Bereich As Range
Dim Wert(1) As String, strFormel As String
Wert(0) = InputBox("Suchwert1", "Eingabe für Spalte C")
Wert(1) = InputBox("Suchwert2", "Eingabe für Spalte D")
strFormel = "=IF(AND(RC4=""" & Wert(1) & """,RC3=""" & Wert(0) & """),""c"","""")"
Application.ScreenUpdating = False
Set Bereich = Range("D1", Cells(Rows.Count, "D").End(xlUp)).Offset(0, -2)
Bereich.FormulaR1C1 = _
strFormel
Bereich.Value = Bereich.Value
Application.ScreenUpdating = True
End Sub
Gruß Tino
Option Explicit
Sub Test()
Dim Bereich As Range
Dim Wert(1) As String, strFormel As String
Set Bereich = Range("D2", Cells(Rows.Count, "D").End(xlUp)).Offset(0, -2)
If Bereich(1).Address = Range("B1").Address Then
MsgBox "In Spalte D sind keine Daten!", vbCritical, "Abbruch"
Exit Sub
End If
Wert(0) = InputBox("Suchwert1", "Eingabe für Spalte C")
Wert(1) = InputBox("Suchwert2", "Eingabe für Spalte D")
strFormel = "=IF(AND(RC4=""" & Wert(1) & """,RC3=""" & Wert(0) & """),""c"","""")"
Application.ScreenUpdating = False
Bereich.FormulaR1C1 = _
strFormel
Bereich.Value = Bereich.Value
Application.ScreenUpdating = True
End Sub
Gruß Tino