Bereichsnamen vergeben

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Bereichsnamen vergeben
von: DieterG
Geschrieben am: 12.03.2005 12:49:54
Hallo zusammen,
In SpalteB - ZelleB2, ZelleB5, ZelleB9 und Zelle B11 steht jeweils der
Buchstabe A!
Wie kann ich per VBA z.B. die 10 Zellen rechts neben dem Buchstaben A in allen Zeilen gleichzeitig markieren und einen Bereichsnamen vergeben?
Danke für Euere Mühe
Gruß Dieter

Bild

Betrifft: AW: Bereichsnamen vergeben
von: WernerB.
Geschrieben am: 12.03.2005 15:23:09
Hallo Dieter,
wie gefällt Dir das?

Sub Dieter1()
Dim c As Range, SuBe As Range, ErgBereich As Range, _
    laR As Long
    Application.ScreenUpdating = False
    laR = Cells(Rows.Count, 2).End(xlUp).Row
    Set SuBe = Range("B1:B" & laR).Find(What:="A", _
      After:=Range("B" & laR), LookAt:=xlWhole)
    If Not SuBe Is Nothing Then
      Set ErgBereich = Range("C" & SuBe.Row)
      Set SuBe = Nothing
    Else
      MsgBox "Kein 'A' gefunden !" & vbCr & vbCr & "Makro-Abbruch !", _
        16, "Dezenter Hinweis für " & Application.UserName & ":"
      Exit Sub
    End If
    For Each c In Range("B1:B" & laR)
      If c.Value = "A" Then
        Set ErgBereich = Application.Union(ErgBereich, _
          Range("C" & c.Row & ":L" & c.Row))
      End If
    Next c
    ErgBereich.Select
    ActiveWorkbook.Names.Add Name:="Dieter", RefersTo:=ErgBereich
    Set ErgBereich = Nothing
    Application.ScreenUpdating = True
End Sub

Viel Erfolg wünscht
WernerB.
P.S.: Dieses Forum lebt auch von den Rückmeldungen der Fragesteller an die Antworter !
Bild

Betrifft: AW: Bereichsnamen vergeben
von: DieterG
Geschrieben am: 12.03.2005 16:05:45
Hallo Werner,
genau danach habe ich gesucht!
Vielen Dank noch mal
Gruß Dieter
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Bereichsnamen vergeben"