Microsoft Excel

Herbers Excel/VBA-Archiv

Pastespecial-Methode des range objektes konnte nic | Herbers Excel-Forum


Betrifft: Pastespecial-Methode des range objektes konnte nic von: Martin Jockers
Geschrieben am: 11.01.2010 16:31:48

Hallo zusammen!

Ich habe hier ein großes Problem und hoffe jemand kann mir helfen!

Von einer Seite sollen die Daten in ein anderes Dokument übertragen werden. Ich bekomme jedoch immer die o.g. Fehlermeldung wenn es zum Paste kommen soll.

Was ist hier falsch?

Dim y, z, x As String
datum = Date
pfad = ThisWorkbook.Path
Application.ScreenUpdating = False

Blattschutz_aus

y = Format(datum, "yy")
z = Format(datum, "mm")
x = Format(datum, "dd")

Workbooks.Open Filename:=pfad & "\Daten\" & "Umsetzung.xls"
ActiveWorkbook.SaveAs Filename:=pfad & "\" & y & z & x & "Umsetzung.xls"

ThisWorkbook.Activate
Worksheets("Hilfe").Visible = True
Worksheets("Hilfe").Select
Range("A1:F88").Select
Application.CutCopyMode = False
Selection.Copy
Windows(y & z & x & "Umsetzung.xls").Activate
Blattschutz_aus
Worksheets("Hilfe2").Visible = True
Worksheets("Hilfe2").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Worksheets("Hilfe2").Select
Worksheets("Hilfe2").Visible = False
Worksheets("Umsetzung").Select
Range("A1").Select
ThisWorkbook.Activate
Worksheets("Hilfe").Select
Worksheets("Hilfe").Visible = False

Blattschutz_ein

Save:
ThisWorkbook.Save
On Error Resume Next

ThisWorkbook.Close
End Sub

Schonmal vielen vielen Dank für die Hilfe!!!

Martin

  

Betrifft: AW: Pastespecial-Methode des range objektes konnte nic von: Josef Ehrensberger
Geschrieben am: 11.01.2010 16:49:34

Hallo Martin,

du jagst ja den Cursor wie eine Hund in der Gegend herum.

Was bei dir falsch ist! Du kopierst einen Bereich, gibst aber keine Zelle zum einfügen an.

Wenn schon, dann muss es so heißen.

Worksheets("Hilfe2").Range("A1").PasteSpecial xlPasteValues
Ohne Select und Activate sieht es so aus.



Sub copyData()
  Dim objWB As Workbook
  Dim strDate As String, strPfad As String
  
  On Error GoTo ErrExit
  
  Application.ScreenUpdating = False
  
  strPfad = ThisWorkbook.Path
  strDate = Format(Date, "yyMMdd")
  
  Set objWB = Workbooks.Open(Filename:=strPfad & "\Daten\" & "Umsetzung.xls")
  objWB.SaveAs Filename:=strPfad & "\" & strDate & "Umsetzung.xls"
  
  Blattschutz_aus
  
  objWB.Worksheets("Hilfe2").Range("A1:F88") = _
    ThisWorkbook.Worksheets("Hilfe").Range("A1:F88").Value
  
  Blattschutz_ein
  
  ThisWorkbook.Close True
  
  ErrExit:
  Application.ScreenUpdating = True
  
  Set objWB = Nothing
End Sub



Gruß Sepp



  

Betrifft: AW: Pastespecial-Methode des range objektes konnte nic von: Martin Jockers
Geschrieben am: 11.01.2010 18:02:37

R E S P E C T!

Besten Danke für die super Hilfe! Hatt wunderbar geklappt! Vielen herzlichen Dank! Ich habe diese Formel in einer alten Date gehabt, die uns von einer Kollegin gemacht wurde. Der Makro hat in ihrer Datei funktioniert in meiner jedoch nicht mehr.

Schönen Abend noch!

Martin