per VBA Range finden, die im cutcopy-mode ist



Excel-Version: 9.0 (Office 2000)
nach unten

Betrifft: per VBA Range finden, die im cutcopy-mode ist
von: anugyan
Geschrieben am: 14.07.2002 - 12:46:57

Hi Leute,
gibt es eine Möglichkeit in Excel die Range zu finden (und in eine Variable zu speichern), die sich im cutcopy-mode befindet, wenn nach SelectionsChange schon eine andere Zelle markiert ist?
Über eine schnelle Hilfe würde ich mich sehr freuen. Danke
Anugyan

nach oben   nach unten

Re: per VBA Range finden, die im cutcopy-mode ist
von: Andreas
Geschrieben am: 14.07.2002 - 14:49:42

Hallo Anugyan,

mhh auf Anhieb fällt mir da nichts ein. Vielleicht hilft es Dir ja weiter, wenn Du die Tastenkombination STRG+C / +X etwas änderst. Drückt man z.B. STRG+C dann wird automatisch die Selection in eine Variable geschrieben:


'Code in DieseArbeitsmappe:
Private Sub Workbook_Activate()
    CutCopyMerken
End Sub

Private Sub Workbook_Deactivate()
    CutCopyZuruecksetzen
End Sub

'Code in einem Modul:
Public strAddress$

Sub CutCopyMerken()
    With Application
        .OnKey "^c", "SetCopy"
        .OnKey "^x", "SetCut"
    End With
End Sub

Sub CutCopyZuruecksetzen()
    With Application
        .OnKey "^c"
        .OnKey "^x"
    End With
End Sub

Private Sub SetAktAddress()
    strAddress = Selection.Address(False, False)
End Sub

Sub SetCopy()
    SetAktAddress
    Selection.Copy
End Sub

Sub SetCut()
    SetAktAddress
    Selection.Cut
End Sub

Die letzte Selection von CutCopy kannst Du nun der Variablen strAddress entnehmen!

Hoffe das hilft etwas weiter.
Viel Spaß,
Andreas

nach oben   nach unten

Re: per VBA Range finden, die im cutcopy-mode ist
von: anugyan
Geschrieben am: 14.07.2002 - 22:19:26

Hallo Andreas,
dein Tipp hat mich gut weitergebracht, danke.
Ich werde die Onkey-Methode benutzen und einen neuen shortcut (Strg X) erzeugen, der es dann ermöglicht, eine Selection nicht gänzlich auszuschneiden, sondern nur zu kopieren, die Werte in eine Variable zwischenzuspeichern, dann die Werte aller Zellen der Selection löschen und nach SelectionsChange die Variabe zum einfügen von "nur Werten" zur verfügung zu stellen.
Gruß
Anugyan

 nach oben

Beiträge aus den Excel-Beispielen zum Thema "3 Zeilen zu einer machen."