Optionsfelder vervielfältigen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Cristina!
Im Prinzip kannst du das so machen, aber bei 800 Stück, würde ich mir überlegen, ob
es nicht eine andere Lösung als mit OptionButtons gibt.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub MakeOptButtons()
Dim objOpt As Object
Dim lngRow As Long, lngStart As Long, lngRowCount As Long
Dim intCol As Integer, intStart As Integer, intCount As Integer
Dim lngCalculation As Long

On Error GoTo ErrExit

With Application
  .ScreenUpdating = False
  .EnableEvents = False
  .DisplayAlerts = False
  lngCalculation = .Calculation
  .Calculation = xlCalculationManual
  .Cursor = xlWait
End With

lngStart = 5 ' Startzeile
lngRowCount = 80 ' Anzahl Zeilen

intStart = 3 ' Startspalte
intCount = 10 ' Buttons pro Zeile

For lngRow = lngStart To lngStart + lngRowCount
  For intCol = intStart To intStart + intCount
    Set objOpt = ActiveSheet.OLEObjects.Add(ClassType:="Forms.OptionButton.1", _
      Left:=Cells(lngRow, intCol).Left + 1, Top:=Cells(lngRow, intCol).Top + 1, _
      Width:=Cells(lngRow, intCol).Width - 1, Height:=Cells(lngRow, intCol).Height - 1)
    With objOpt
      .Object.Caption = CStr("opt_" & lngRow & "_" & intCol)
      .Object.GroupName = ActiveSheet.Name & "_Grp" & lngRow
      .LinkedCell = Cells(lngRow, intCol).Address
      .Object.Value = (intCol = intStart)
    End With
    Set objOpt = Nothing
  Next
Next

ErrExit:

If Err.Number > 0 Then
  MsgBox Err.Number & vbLf & Err.Description, , "Fehler"
  Err.Clear
End If

With Application
  .ScreenUpdating = True
  .EnableEvents = True
  .DisplayAlerts = True
  .Calculation = lngCalculation
  .Cursor = xlDefault
End With

End Sub

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Hallo Christina, das wird natürlich trotzdem ein Aufwand, eigentlich macht man das mit einer Userform nur einmal, aber ich weis nicht was du eigentlich willst,
etwas beschleunigen kann man das folgendermaßen:
mach in einer Zelle die 10 Optionsbutton fertig, natürlich in einem Gruppenfeld, dann lässt du dier das Zeichenmenü anzeigen und schaltest den Cursor um auf Pfeil!!!
danach hälst du die Shift-Taste gedrückt und klickst alle Objekte an oder ziehst einen Rahmen drum, also 10 x die Optionsbuttons und einmal das Gruppenfeld, danach rechte Maustaste auf dieses Objekt und dort gibt es Objekt gruppieren, ab sofort sind alle Objekte der Zelle nur noch eins, danch nächst Zelle gehen und reinkopieren, wenn 10 voll sind dann wieder diese alle markieren und als Gruppe zusammenfassen, dann hat man gleich 10 solcher Objekte und so fortfahren.
Aber wie gesaht sowas macht man eigentlich nicht!
Gruss WS

Beliebteste Forumthreads (12 Monate)

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Optionsfelder vervielfältigen

20 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread