Microsoft Excel

Herbers Excel/VBA-Archiv

Zelladresse statt Wertrückgabe aus Sverweis



Excel-Version: Excel 97

Betrifft: Zelladresse statt Wertrückgabe aus Sverweis
von: Lothar Reimann
Geschrieben am: 03.09.2002 - 11:44:06

Hallo Excelgemeinde!

Folgendes Problem: (engl. Office 97)

Mit VLOOKUP (Sverweis) bekomme ich problemlos die Suchwerte als Rückgabe:
=(VLOOKUP($A2;Tabelle!$A:$D;4;0)) [ergibt den Suchwert]
Ich benötige jedoch die absolute Zelladresse, da in der Suchtabelle mehrere Werte zur Suchzelle vorhanden sein können, die ich dann in der Ergebnistabelle in verschiedenen Spalten darstellen will. Meine Überlegung geht dahin, mit der gefundenen Zelladresse den Suchbereich zu ändern, da ich über eine Zählewenn Funktion die Anzahl der mehrfach vorkommenden Werte kenne.

Leider scheiterten bslang alle Versuche mit

=CELL("address";(VLOOKUP($A2;Tabelle!$A:$D;4;0))
bzw.
=CELL("address";INDIRECT((VLOOKUP($A2;Tabelle!$A:$D;4;0)))

Kann jemand helfen?
Danke schon mal im Voraus

Lothar

  

="D"&MATCH(A2;D:D;0)
von: WF
Geschrieben am: 03.09.2002 - 12:18:55

http://www.excelformeln.de/
die ultimative Formelseite
  

Re: ="D"&MATCH(A2;D:D;0)
von: Lothar Reimann
Geschrieben am: 03.09.2002 - 14:18:55

Danke!
Aber das trifft nicht das Problem: Ich hole mal etwas mehr aus:

Tabelle1 (die Zieltabelle) Hat in Spalte A mehrere Namen
Anton
Berta
Cesar
Dora
usw.

In die Spalten B bis E sollen verschiedene Kriterien zu den Namen in Spalte A hinzugefügt werden.

In der Quelltabelle (Tabelle2) stehen die Namen in Spalte A sortiert und die verschiedenen Krieterien in Spalte B.

Anton Kriterium2
Anton Kriterium3
Berta Kriterium1
Berta Kriterium2
Berta Kriterium3
Cesar Kriterium1
Cesar Kriterium3
Dora Kriterium2
Dora Kriterium4

usw.

Das Ergebnis soll so aussehen

Anton - Kriterium2 Kriterium3 -
Berta Kriterium1 Kriterium2 Kriterium3 -
Cesar Kriterium1 - Kriterium3 -
Dora - Kriterium2 - Kriterium4

Danke!
Lothar

  

mehrfach vorkommendes Suchkriterium
von: WF
Geschrieben am: 03.09.2002 - 15:04:07

Hi Lothar,

in B1 steht die Array-Formel:
{=INDEX(Tabelle2!B:B;KKLEINSTE(WENN((Tabelle2!A$1:A$1000=A1);ZEILE($1:$1000));1))}

in C1:
{=WENN(ZÄHLENWENN(Tabelle2!A$1:A$1000;A1) < 2;"";INDEX(Tabelle2!B:B;KKLEINSTE(WENN((Tabelle2!A$1:A$1000=A1);ZEILE($1:$1000));2)))}

in D1:
{=WENN(ZÄHLENWENN(Tabelle2!A$1:A$1000;A1) < 3;"";INDEX(Tabelle2!B:B;KKLEINSTE(WENN((Tabelle2!A$1:A$1000=A1);ZEILE($1:$1000));3)))}

und in E1:
{=WENN(ZÄHLENWENN(Tabelle2!A$1:A$1000;A1) < 4;"";INDEX(Tabelle2!B:B;KKLEINSTE(WENN((Tabelle2!A$1:A$1000=A1);ZEILE($1:$1000));4)))}

ARRAY-Formel {=geschweifte Klammern} nicht eingeben;
Abschluß der Formel mit gleichzeitig Strg / Shift / Enter; - das erzeugt sie.

trapp, trapp, trapp, trapp, trapp, brrrrr
WF


http://www.excelformeln.de/
die ultimative Formelseite

  

B1 bis E1 dann runterkopieren o.T.
von: WF
Geschrieben am: 03.09.2002 - 15:33:59

.

  

Re: DANKE!!! Super, klappt prima!!
von: Lothar Reimann
Geschrieben am: 03.09.2002 - 16:35:35

Vielen Dank!!

 

Beiträge aus den Excel-Beispielen zum Thema "Zelladresse statt Wertrückgabe aus Sverweis"