(eigentlich fehlt hier das Level 'Excel geht so'
Hallo,
im Bereich A5:A155 befinden sich Ganzzahlwerte im Bereich von 0 - 999.
Werte können doppelt/mehrfach auftreten. Leere Zellen oder Textwerte sind nicht enthalten
Mit der Formel -MAX(A1:A155) finde ich den/die größten Wert(e) aus der Matrix.
Kann ich mit einer Formel die Zelladresse/n oder die Zeilennummer/n ermitteln?
Gruß
Jochen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Zelladressee des MAX-Wertes einer Matrix ausgeben

Tino
AW: Ja das ist es, danke oT

JOWE
Zeilen des MAX-Wertes in einer Spalte

Erich
Dir ebenfalls Danke oT

JOWE
Adressen des MAX-Wertes in einer Spalte

Erich
Das war ein wenig Unfug

Erich
AW: Das war ein wenig Unfug

JoWE

AW: Zelladressee des MAX-Wertes einer Matrix ausgeben

15.07.2010 09:13:04

Tino

Hallo,
vielleicht so.

	A	B	C
1	0		$A$5
2	1
3	6
4	9
5	29
6	15
7	18
8	24

Formeln der Tabelle

Zelle	Formel
C1	=ADRESSE(VERGLEICH(MAX(A:A); A:A;0); 1)

Gruß Tino

AW: Ja das ist es, danke oT

15.07.2010 09:28:01

JOWE

Zeilen des MAX-Wertes in einer Spalte

15.07.2010 09:13:36

Erich

Hi Jochen,
so?

	A	B
1	413	5
2	123	7
3	645
4	82
5	997
6	162
7	997
8	341

Formeln der Tabelle

Zelle	Formel
B1	{=KKLEINSTE(WENN(A$1:A$155=MAX(A$1:A$155); ZEILE($1:$155)); ZEILE())}
B2	{=WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; KKLEINSTE(WENN(A$1:A$155=MAX(A$1:A$155); ZEILE($1:$155)); ZEILE()))}
B3	{=WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; KKLEINSTE(WENN(A$1:A$155=MAX(A$1:A$155); ZEILE($1:$155)); ZEILE()))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Dir ebenfalls Danke oT

15.07.2010 09:36:24

JOWE

Adressen des MAX-Wertes in einer Spalte

15.07.2010 09:26:56

Erich

Hi Jochen,
und noch zwei bis drei Varianten: (VERGLEICH habe ich von Tino abgeschaut.)

	A	B	C	D
1	413	5	A5	5
2	123	7	A7	7
3	645	9	A9	9
4	82
5	997
6	162
7	997
8	341
9	997
10	2

Formeln der Tabelle

Zelle	Formel
B1	=VERGLEICH(MAX(A:A); A:A;0)
C1	="A"&VERGLEICH(MAX(A:A); A:A;0)
D1	{=MIN(WENN(A$1:A$155=MAX(A$1:A$155); ZEILE($1:$155)))}
B2	=WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; B1+VERGLEICH(MAX(A:A); INDEX(A:A;B1+1):INDEX(A:A;9999); 0))
C2	="A"&WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; TEIL(C1;2;5)+VERGLEICH(MAX(A:A); INDEX(A:A;TEIL(C1;2;5)+1):INDEX(A:A;9999); 0))
D2	{=WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; KKLEINSTE(WENN(A$1:A$155=MAX(A$1:A$155); ZEILE($1:$155)); ZEILE()))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Das war ein wenig Unfug

15.07.2010 09:34:28

Erich

Hi,
statt INDEX(A:A;9999) schreibt man doch besser gleich A$9999...

	A	B	C
1	413	5	A5
2	123	7	A7
3	645	9	A9
4	82
5	997
6	162
7	997
8	341
9	997
10	2

Formeln der Tabelle

Zelle	Formel
B1	=VERGLEICH(MAX(A:A); A:A;0)
C1	="A"&VERGLEICH(MAX(A:A); A:A;0)
B2	=WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; B1+VERGLEICH(MAX(A:A); INDEX(A:A;B1+1):A$9999;0))
C2	="A"&WENN(ZÄHLENWENN(A$1:A$155;MAX(A$1:A$155))<ZEILE(); ""; TEIL(C1;2;5)+VERGLEICH(MAX(A:A); INDEX(A:A;TEIL(C1;2;5)+1):A$9999;0))