Wert in Tabelle suchen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Wert in Tabelle suchen
von: Chepe
Geschrieben am: 11.12.2003 08:38:58

Hallo,

ich habe eine Tabelle 1 mit ca. 20 Spalten (Spaltenüberschrift ist z. B. A, B, C, D, usw.)die unterschiedlich lang befüllt sind (Spalte A 20 Einträge, B 25, C 30, D 15 usw.).

Nun möchte ich in Tabelle2 in A1 einen Begriff eingeben, dieser Begriff soll in der Tabelle1 beginnend in der Spalte A gesucht werden. Wird der Begriff gefunden, soll z. B. in C1 der gesuchte Begriff ausgegeben werden und in C2 die Spaltenüberschrift der betreffenden Spalte aus der Tabelle1.

Wird der gesuchte Begriff gefunden ist es mit der beschriebenen Ausgabe schon getan, eine weitere Abfrage, ob der Begriff nochmals in der Tabelle vorhanden ist, ist nicht vorgesehen.

Wird der Begriff nicht in der Spalte A gefunden, soll in Spalte B weitergesucht werden und falls gefunden wieder die beschriebene Ausgabe, usw.. bis zur letzten Spalte.

Ist das Eurer Meinung nach machbar??? DANKE für jede Hilfestellung dazu!!!

Chepe

Bild


Betrifft: AW: Wert in Tabelle suchen
von: WernerB.
Geschrieben am: 11.12.2003 09:23:28

Hallo Chepe,

wenn Du mit "Spaltenüberschrift" den Wert in der Zeile 1 der Trefferspalte meinst, dann sollte das funktionieren:

Sub Chepe()
Dim SuBe As Range
Dim s As String
Dim acC As Integer
    Application.ScreenUpdating = False
    s = Sheets("Tabelle2").Cells(1, 1).Value
    Set SuBe = Sheets("Tabelle1").Cells. _
      Find(s, LookAt:=xlWhole, SearchOrder:=xlByColumns)
    If Not SuBe Is Nothing Then
      acC = SuBe.Column
      Sheets("Tabelle2").Range("C1").Value = s
      Sheets("Tabelle2").Range("C2").Value = _
        Sheets("Tabelle1").Cells(1, acC).Value
    Else
      MsgBox "Der Suchbegriff '" & s & "' konnte nicht gefunden werden !", _
        vbOKOnly + vbInformation, _
        "Dezenter Hinweis für " & Application.UserName & ":"
    End If
    Set SuBe = Nothing
    Application.ScreenUpdating = True
End Sub

Viel Erfolg wünscht
WernerB.

P.S.: Das Forum lebt auch von den Rückmeldungen der Fragesteller an die Antworter (siehe Forums-FAQ).


Bild


Betrifft: JA, genau!!! DANKE
von: Chepe
Geschrieben am: 11.12.2003 13:59:20

Hallo WernerB!

Hab Dein Programm ausprobiert und es funktioniert so wie ich es mir vorgestellt habe!!! Mit der Spaltenüberschrift habe ich wirklich den Wert in Zeile 1 gemeint, also nochmals DANKE


Bild

Beiträge aus den Excel-Beispielen zum Thema " Wert in Tabelle suchen"