Live-Forum - Die aktuellen Beiträge
Datum
Titel
26.04.2024 17:18:47
Große Datenmenge in komplexes Diagramm verpacken
26.04.2024 16:22:47
Aktualisierung Verknüpfung bei geschlossener Quelldatei
26.04.2024 16:05:28
PivotChart-Stapeldiagramm erstellen
26.04.2024 15:34:42
Überlagernde Textbox-Ansicht
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1780to1784
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1780to1784
1780to1784
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Alle Dateien im Ordner bearbeiten

Alle Dateien im Ordner bearbeiten
14.09.2020 10:26:38
Norbert
Hallo zusammen,
ich habe einen Task den ich jetzt schon seit längerer Zeit händisch mache ohne darüber nachzudenken.
Weil ich von euch hier immer gute Hilfe bekommen habe, kam mir die Idee, diese Aufgabe jetzt auch noch einmal zu automatisieren. Die Lösung ist bestimmt leicht aber der Effekt für mich riesig.
Ich habe einen Ordner mit Dateien. Die Dateien die im Dateinamen mit LEG beginnen, müssen von mir angepasst werden. In diese Dateien gehe ich rein, wähle das zweite Worksheet der Datei aus aus und füge in A1 "Person" und B1 "Mobil" ein. Außerdem kopiere ich die zweite Zeile aus dem Worksheet in das zweite Worksheet der Datei. Dann schließe ich und gehe zu der nächsten Datei und immer so weiter.
Kann mir damit jemand helfen? Man müsste wohl mit ThisPath durch den Ordner laufen und überprüfen, welche Datei mit LEG* beginnt um dann die Modifikation automatisiert vorzunehmen. Aber wie? Ist wirklich eine langweilige wiederkehrende Aufgabe, welche sicherlich mit VBA angenehmer ist, ich bekomme das nur leider nicht zusammen.
Ich bin für jede Hilfe sehr dankbar.
Beste Grüße
Norbert

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Alle Dateien im Ordner bearbeiten
14.09.2020 10:51:38
Nepumuk
Hallo Norbert,
teste mal:
Option Explicit

Public Sub UpdateLEG()
    
    Dim strFilename As String
    Dim avntCopyValues As Variant
    Dim objWorkbook As Workbook
    
    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    
    avntCopyValues = Range("A2:B2").Value
    
    strFilename = Dir$(ThisWorkbook.Path & "\LEG*.xls*")
    
    Do Until strFilename = vbNullString
        
        Set objWorkbook = Workbooks.Open(Filename:=ThisWorkbook.Path & "\" & strFilename)
        
        With objWorkbook.Worksheets(2)
            
            .Range("A1:B1").Value = Array("Person", "Mobil")
            .Range("A2:B2").Value = avntCopyValues
            
        End With
        
        Call objWorkbook.Close(SaveChanges:=True)
        
        Set objWorkbook = Nothing
        
        strFilename = Dir$
        
    Loop
    
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk
Anzeige
AW: Alle Dateien im Ordner bearbeiten
14.09.2020 13:58:13
Norbert
Hallo Nepumuk,
vielen lieben Dank, das Makro funktioniert und nimmt mir die händische Arbeit ab :- )
Eine Sache nur noch, die ich vergessen habe: Ich erstelle das zweite Worksheet in jeder Datei immer selbst händisch. Kann man im Code eine Anweisung geben, dass in der aktuellen Datei ein neues Worksheet mit dem Namen "Informationen" erstellt wird? Das müsste ja nur eine Anweisung sein, oder? Ich habe es selbst versucht, aber ich bekomme eine Fehlermeldung wegen dem Objekt.
Vielen Dank noch einmal!
Beste Grüße
Norbert
AW: Alle Dateien im Ordner bearbeiten
14.09.2020 14:05:26
Nepumuk
Hallo Norbert,
so:
Option Explicit

Public Sub UpdateLEG()
    
    Dim strFilename As String
    Dim avntCopyValues As Variant
    Dim objWorkbook As Workbook
    Dim objWorksheet As Worksheet
    
    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    
    avntCopyValues = Range("A2:B2").Value
    
    strFilename = Dir$(ThisWorkbook.Path & "\LEG*.xls*")
    
    Do Until strFilename = vbNullString
        
        Set objWorkbook = Workbooks.Open(Filename:=ThisWorkbook.Path & "\" & strFilename)
        
        With objWorkbook
            
            Set objWorksheet = .Worksheets.Add(After:=.Worksheets(1))
            
        End With
        
        With objWorksheet
            
            .Range("A1:B1").Value = Array("Person", "Mobil")
            .Range("A2:B2").Value = avntCopyValues
            
        End With
        
        Call objWorkbook.Close(SaveChanges:=True)
        
        Set objWorksheet = Nothing
        Set objWorkbook = Nothing
        
        strFilename = Dir$
        
    Loop
    
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk
Anzeige
AW: Alle Dateien im Ordner bearbeiten
14.09.2020 14:38:00
Norbert
Super genau so, vielen Dank!!!
AW: Alle Dateien im Ordner bearbeiten
14.09.2020 16:43:14
Nepumuk
Hallo Norbert,
den Namen der Tabelle habe ich vergessen. Daher:
Option Explicit

Public Sub UpdateLEG()
    
    Dim strFilename As String
    Dim avntCopyValues As Variant
    Dim objWorkbook As Workbook
    Dim objWorksheet As Worksheet
    
    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    
    avntCopyValues = Range("A2:B2").Value
    
    strFilename = Dir$(ThisWorkbook.Path & "\LEG*.xls*")
    
    Do Until strFilename = vbNullString
        
        Set objWorkbook = Workbooks.Open(Filename:=ThisWorkbook.Path & "\" & strFilename)
        
        With objWorkbook
            
            Set objWorksheet = .Worksheets.Add(After:=.Worksheets(1))
            
        End With
        
        With objWorksheet
            
            .Name = "Informationen"
            
            .Range("A1:B1").Value = Array("Person", "Mobil")
            .Range("A2:B2").Value = avntCopyValues
            
        End With
        
        Call objWorkbook.Close(SaveChanges:=True)
        
        Set objWorksheet = Nothing
        Set objWorkbook = Nothing
        
        strFilename = Dir$
        
    Loop
    
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk
Anzeige

152 Forumthreads zu ähnlichen Themen

Suche Code zum umbenennen von Dateien
Dateien

Hallo,
ich suche reinen VBcode um die Dateien aus einem Ordner nach dem Dateierstelldatum umzubenennen. Und alles über UserForm ohne sheets.
Hat jemand das schon mal gemacht?
Viele Grüße aus dem mal sonnigen Hamburg
Ray
23.10.2008 15:59:58
Thread-ID: 1018718
6 Beiträge
Anzeige
Dateien im aktuellen Ordner auslesen
Mister

Hallo und guten morgen,
vor langer Zeit habe ich folgendes Makro aus dem Forum das die Dateien im angegebenen Ordner ausliest und in der Tabelle "PDF" auflistet. Wie muss ich das Makro ändern damit die Dateien aufgelistet werden die sich im gleichen Ordner befinden wie die Datei die das Ma...
24.09.2009 10:20:27
Thread-ID: 1105169
3 Beiträge
Vba Markro für mehrere Dateien ermöglichen | Herbers Excel-Forum
BENNY
Hallo,
habe ein riesen Problem: Ich soll für meinen Arbeitgeber folgenden VBA Code umbauen. Momentan kann man mit Hilfe dieses Codes eine .fdf Datei einlesen und sie wir in Excel in Zeile 1 (Überschrift) und 2 (Werte) ausgelesen.
Mein Chef möchte nun, dass man mehrere Dateien einlesen kann...
13.01.2010 14:52:54
Thread-ID: 1129510
5 Beiträge
Anzeige
Umbenennen von Dateien in einem Ordner
Dateien

Hallo,
ich habe folgende Frage:
Ich nutze Excel 2007.
Ich habe einen Ordner mit über 100 Excel-Dateien. Diese sollen so umbenannt werden, daß an den vorhandenen und unterschiedlich langen Dateinamen vier Buchstaben angehangen werden sollen.
Gibt es eine Möglichkeit dieses zu aut...
04.06.2010 13:20:53
Thread-ID: 1160328
4 Beiträge
alle Dateien in einem Ordner umbenennen
Joachim

Hallo,
ich hab in einem Ordner ca. 400 pdf-Files. Diese muss ich jetzt umbenennen. Die Dateinamen beginnen immer gleich, erst 7 Zeichen, dann eine 14-stellige Nummer, dann der Rest, der aber unterschiedlich lang sein kann. Ich muss nun aus der 14-stelligen Nummer eine 15-stellige machen, sp...
02.08.2010 11:07:41
Thread-ID: 1169991
23 Beiträge
Dateien im Ordner unbenennen
bruno

Hallo zusammen
Ich habe einen Ordner, in dem eine Variable Anzahl von pdf-Dateien sind. Kann ich mit einem Macro alle Dateien unbennenen? (unter unbenennen meine ich in diesem Fall, den alten Namen verkürzen auf die ersten 14 Zeichen)
Gruess ond Danke
de Bruno
27.10.2010 13:19:04
Thread-ID: 1184116
5 Beiträge
Auswertung aller Dateien in einem Ordner
Joerg.Kaiser1@web.de

Hallo
Habe eine Datei mit folgendem Aufbau:
---- A------B-----------------C----
1-----------------------------------
2-----------------------------------
3-----------------------------------
4--------Drehen---------Schmidt
5--------Fräsen----------Schulze
6------...
13.12.2011 07:22:59
Thread-ID: 1241758
14 Beiträge
VBA: mehrere Dateien nacheinander einlesen
H.Benitz

Hallo,
da meine VBA-Kenntnisse zur Zeit noch recht bescheiden sind, habe ich mir das Script für mein Vorhaben aus verschiedenen Beiträgen zusammengebastelt.
Funktioniert soweit schon ganz gut, aber ein Problem gibt es noch!
Das Ziel ist:
Es sollen aus einem vom Anwender vorgegeb...
06.12.2012 11:06:13
Thread-ID: 1289572
3 Beiträge
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige
Archiv - Verwandte Themen
Forumthread
Beiträge
5
7
2
4
2
3
22
4
13
2
1
1
2
3
5
2
1
1
1
7
1
2
1
4
3