Datum Suche

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Datum Suche
von: Steffen
Geschrieben am: 27.08.2015 08:07:33

Hallo,
ich habe mit mit Hilfe vom Forum usw folgenden Code zum suchen des aktuellen Datums in einer Zeile gebastelt:

Sub DatumFinden()
   Dim rng As Range
   Dim lngDatum As Long
   lngDatum = CLng(Date)
   For Each rng In Range("A6:GT6")
      If IsDate(rng) Then
         If CLng(rng) = lngDatum Then
            rng.Select
         
           Exit Sub
           
         End If
         
      End If
      
    Next
        
End Sub

Soweit so gut jetzt bekomme ich aber es nicht hin, eine MSGBOX zu erhalten wenn er das Datum in der Zeile nicht finden kann...
Könnt ihr meinen Knoten zerschlagen?
Danke!!!

Bild

Betrifft: AW: Datum Suche
von: Beverly
Geschrieben am: 27.08.2015 08:41:36
Hi,
vielleicht so:

    Dim intSpalte As Integer
    Dim lngDatum As Long
    If Not IsError(Application.Match(CLng(Date), Range("A6:GT6"), 0)) Then
        intSpalte = Application.Match(CLng(Date), Range("A6:GT6"), 0)
        Application.Goto reference:=Cells(6, intSpalte), scroll:=True
    Else
        MsgBox "Nicht gefunden"
    End If



Bild

Betrifft: AW: Datum Suche
von: Steffen
Geschrieben am: 27.08.2015 09:12:03
Hallo Beverly,
Ok so funzt die suche auch und es kommt die Meldung beim nicht finden.
Danke!!!!!
Grüße Stefefn

Bild

Betrifft: AW: Datum Suche
von: hary
Geschrieben am: 27.08.2015 08:53:38
Moin

Dim zelle As Range
  Set zelle = Worksheets("Tabelle1").Range("A6:GT6").Find(What:=Date, LookIn:=xlValues, lookat:= _
xlWhole)
    If Not zelle Is Nothing Then
      zelle.Select
    Else
     MsgBox "Datum nicht vorhanden"
    End If

gruss hary

Bild

Betrifft: AW: Datum Suche
von: Werner
Geschrieben am: 27.08.2015 10:28:48
Hallo Steffen,
oder mit deinem Code angepasst

Sub DatumFinden()
   Dim rng As Range
   Dim lngDatum As Long
   Dim schalter As Boolean
   lngDatum = CLng(Date)
   For Each rng In Range("A6:GT6")
      If IsDate(rng) Then
         If CLng(rng) = lngDatum Then
            rng.Select
            schalter = True
           Exit Sub
         End If
      End If
    Next
    If schalter = False Then
    MsgBox "Kein Datum"
End If
End Sub
Gruß Werner

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Excel findet Dateien nicht"