Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Bei WENN-Funktion, Prüfung als Dann-Wert

Bei WENN-Funktion, Prüfung als Dann-Wert
11.01.2017 15:13:04
René
Servus,
nichts dazu gefunden, evtl. weil es kein wirkliches "Problem" ist.
Und zwar habe ich oft Funktionen die sinngemäß wie folgende lauten:
wenn(A1=0;"";A1) oder wenn(istnv(A1);"";A1)
Bei so kurzen Formeln ist es noch simpel, aber wenn sie länger werden, wird es unübersichtlich.
Bsp:
WENN(WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5);JAHR($L$5)+1)&"'!$A$1:$C$999");3;FALSCH);0)+WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5)-1;JAHR($L$5))&"'!$A$1:$C$999");3;FALSCH);0)=0;"";WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5);JAHR($L$5)+1)&"'!$A$1:$C$999");3;FALSCH);0)+WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5)-1;JAHR($L$5))&"'!$A$1:$C$999");3;FALSCH);0))
Hier prüfe ich, ob die Formel = 0 ist, wenn ja, dann soll die Zelle leer bleiben, wenn nicht, soll das Ergebnis da rein. Also habe ich die Formel, die ich prüfe, doppelt drin. Gibt es eine allgemeine Möglichkeit das zu lösen/zu verkürzen? (Ohne eine eigene Formel in VBA zu machen)
Ich suche also quasi etwas wie WENN0(Zelle/Formel;Sonstwert) bzw WENNNV(Zelle/Formel;Sonstwert). Wobei "Zelle/Formel" auch als Dannwert fungieren soll.
Hoffe es war verständlich.
Gruß René

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
Ja, zunächst auf die Hälfte
11.01.2017 15:49:57
lupo1
=WENNFEHLER(1/(1/
WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5);JAHR($L$5)+1)&"'!$A$1:$C$999");3;);0)+
WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5)-1;JAHR($L$5))&"'!$A$1:$C$999");3;);0));"")
Mehr wäre dann auf logischer Basis vielleicht möglich, mit SUMMENPRODUKT oder so, für die beiden fast gleichen SVERWEISE. Aber da habe ich nun nicht reingeschaut.
Noch ein wenig Verkürzung
11.01.2017 16:18:25
lupo1
=WENNFEHLER(1/(1/
WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5);JAHR($L$5)+1)&"'!$A$1:$C$999");3;);0)+
WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&WENN(MONAT($L$5)<10;JAHR($L$5)-1;JAHR($L$5))&"'!$A$1:$C$999");3;);0));"")
wird zu
=WENNFEHLER(1/(1/
WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&JAHR($L$5)+(MONAT($L$5)>9)&"'!$A$1:$C$999");3;);0)+
WENNFEHLER(SVERWEIS($C$5;INDIREKT("'Test "&JAHR($L$5)-(MONAT($L$5)<10)&"'!$A$1:$C$999");3;);0));"")
Anzeige
Und noch eine $-Bemerkung
11.01.2017 16:34:58
lupo1
Da Du ausschließlich abs. Bezüge verwendest, ändern sich die Berechnungen ja überhaupt nicht.
Das wäre ok, wenn es die Formel nur einmal gibt.
Dann aber kann man alles auch relativ schreiben - etwas kürzer und besser lesbar.

357 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige