In Word eingebettete Excel Mappe bearbeiten

Hallo
Ich versuche mich in Letzter Zeit etwas an Makros. Das meiste habe ich mithilfe des Recorders und ein etwas Internetrecherche hinbekommen.
Nun stehe ich allerdings vor einem etwas größeren Problem.
Ich habe eine Excel Mappe aus dieser möchte ich ein Makro starten, das folgendes macht:
1.Eine bestimmte Worddatei öffnen, die sich im selben Ordner befindet(folgendes funktioniert soweit)
Dim ort As String
ort = ActiveWorkbook.Path
CreateObject("Word.application").Documents.Open(ort & "\Dateiname").Application.Visible = True
2. Die Word Datei hat eine eingebettete Excel Mappe in diese soll etwas eingetragen werden.
Hier komme ich nicht weiter, ich schaffe es nicht mal die Worddatei anzusprechen, diese bleibt immer im Hintergrund minimiert.(hier einer meiner vielen Versuche)
CreateObject("Word.application").ActiveDocument.InlineShapes(1).OLEFormat.DoVerbv VerbIndex:=wdOLEVerbPrimary
With Workbooks("Tabelle1").Sheets(1).Range("C10").Value = 2
End With
Wenn ich in Word im Menüband auf Layout/Auswahlbereich gehe heißt die eingebettete Excel Mappe "Object 3".
Im Worddokument sind noch 4 Textfelder und ein Bild, falls das was zur Sache tut.
Ich freue mich über jede Hilfe und konstruktiven Kommentar
Freundliche Grüße
Max

Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Max,
das war jetzt etwas Tüftelarbeit in Word und Excel, um die korrekten Objekte anzusprechen.
Außerdem ist eine Fehlerbehandlung erforderlich, die erkennt ob das Word-Dokumnt schon geöffnet ist.
Gruß
Franz

'erstellt unter Office 2010 professional / Windows Vista
Sub Excelobjekt_in_Word_bearbeiten_1()
Dim wdApp As Object ' Word.Application
Dim wdDoc As Object ' Word.Document
Dim wdInlineshape As Object ' Word.InlineShape
Dim wdExcelObjekt As Object
Dim wdExcelTab As Worksheet
Dim iIS As Integer, iTab As Integer
Dim ort As String
On Error GoTo Fehler
ort = ActiveWorkbook.Path
'Word-Anwendung öffnen, anzeigen und aktiv setzen
Set wdApp = CreateObject("Word.application")
wdApp.Visible = True
wdApp.Activate
'Word-Dokumnt öffnen
Set wdDoc = wdApp.Documents.Open(ort & "\Tastdoc.docx") 'Datei-Name anpassen
If wdDoc.ReadOnly = True Then
'Falls Dokument schreibgeschützt geöffnet wurde, weil schon geöffnet
wdDoc.Close False
wdApp.Quit
Else
'eingebettete Excel-Tabllen-Objekte  suchen
For iIS = 1 To wdDoc.InlineShapes.Count
Set wdInlineshape = wdDoc.InlineShapes(iIS)
If wdInlineshape.Type = wdInlineShapeEmbeddedOLEObject Then
If InStr(1, wdInlineshape.OLEFormat.ClassType, "Excel.Sheet") > 0 Then
iTab = iTab + 1 'Zähler für Excel-Tabllen im Word-Dokumnt
Select Case iTab
Case 1
'    wdInlineshape.Select
wdInlineshape.OLEFormat.DoVerb
Set wdExcelObjekt = wdInlineshape.OLEFormat.Object
Set wdExcelTab = wdExcelObjekt.Sheets(1)
With wdExcelTab
.Range("C2").Value = 555
End With
Case Else
' Do Nothing
End Select
End If
End If
Next iIS
End If
'   wdDoc.Save
'   wdDoc.Close True
'    wdApp.Quit
Fehler:
With Err
Select Case .Number
Case 0
Case -2147467259 'DoVerb konnte nicht ausgeführt werden
If Not wdDoc Is Nothing Then wdDoc.Close False
If Not wdApp Is Nothing Then wdApp.Quit
Case 4198 'Abbruch im Word-Dialog wenn Datei schon geöffnet ist.
wdApp.WindowState = 2 'wdWindowStateMinimize
Application.WindowState = xlMaximized
If Not wdApp Is Nothing Then wdApp.Quit
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
End Select
End With
End Sub

Beliebteste Forumthreads (12 Monate)

In Word eingebettete Excel Mappe bearbeiten

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread