mehrere Excel-Dateien Zusammenfügen

Bild

Betrifft: mehrere Excel-Dateien Zusammenfügen
von: Dimitri
Geschrieben am: 02.09.2015 19:29:19

Hallo Zusammen
Bin auf der Suche nach einer Möglichkeit, mehrere Excel-Dateien welche nur ein Datenblatt enthalten, in eine neue Excel-Datei zusammenzuführen. Das Problem ist aber, das die einzelnen Datenblätter den Namen der Excel-Datei erhalten sollen damit diese beim Zusammenlegen unterschieden werden können. Es handelt sich hier um ca. 90 Dateien.
Gibt es dafür eine Lösung?
Vielen Dank für Eure Hilfe

Bild

Betrifft: AW: mehrere Excel-Dateien Zusammenfügen
von: fcs
Geschrieben am: 03.09.2015 03:59:49
Hallo Dimiti,
hier ein passendes Makro
Gruß
Franz

Public Sub Tabelle_1_holen()
    '1. Tabellenblatt aus mehreren Arbeitsmappen in die aktive Mappe kopieren
    Dim strDatnam As Variant
    Dim wb As Workbook, wbZiel As Workbook
    Dim ws As Worksheet
    Dim i As Integer
    Dim j As Integer
    Dim Anzahl As Long
    
    Set wbZiel = ActiveWorkbook
    
    strDatnam = Application.GetOpenFilename("Datei (*.xls*),*.xls*", False, _
        "Bitte gewünschte Datei(en) markieren ", False, True)
    If Not IsArray(strDatnam) Then Exit Sub
    
    Set wbZiel = ActiveWorkbook
    Application.ScreenUpdating = False
    For i = LBound(strDatnam) To UBound(strDatnam)
        Set wb = Workbooks.Open(strDatnam(i), ReadOnly:=True)
            Set ws = wb.Worksheets(1)
            With wbZiel
                ws.Copy After:=.Sheets(.Sheets.Count)
                .Sheets(.Sheets.Count).Name = Left(wb.Name, InStrRev(wb.Name, ".") - 1)
            End With
        wb.Close savechanges:=False
    Next
    Application.ScreenUpdating = True
    Set ws = Nothing
    Set wb = Nothing: Set wbZiel = Nothing
End Sub


 Bild

Beiträge aus den Excel-Beispielen zum Thema "mehrere Excel-Dateien Zusammenfügen"