Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

Excel Objects ins Powerpoin per VBA übertragen

Betrifft: Excel Objects ins Powerpoin per VBA übertragen von: Anja
Geschrieben am: 13.08.2004 13:17:38

Hallo Leute,

vor Paar Wochen hatte ich das Problem. Ich wollte mehrere Diagrams aus Excel automatisch in PowerPointPräsentation übertragen...
Und zwar so dass die Verknüpfunge nach neuen Version aktualisert werden.

Der Ramses war so freundlich und hat mir diese Code gegeben...
Nur manchmal funktioniert es nicht richtig... Bzw. wenn ich die tabelle unbenenne und die Folien in Präsentation übernehmen möchte...
Nimmt er immer den alten Pfad... und aktualisert nicht nach neu.... obwohl bei den Meldungen wird es richtig angezeigt...
Nur nach dem die Präsentaion gestartet wird sehe ich dass ea nichts passiert ist... Und da stehen die alte Verknüpfunge.

Ist da vielleicht ein Fehler aufgetretten oder?
Kann mir jemand den Tipp geben, wie so das passiert...


Option Explicit
Private Declare

Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, _
ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, _
ByVal lpnShowCmd As Long) As Long

'Begin Code Sequenz
Const ppPresName As String = "\POWER_POINT_KPI\KPI.ppt"
Const LinkIni As String = "\POWER_POINT_KPI\ppLink.ini"

Sub PP_Presentation_Start_and_Update_ObjectLinks()
'(C) Ramses
'Eine Powerpoint Präsentation enthält verschiedene verknüpfte Objecte auf eine EXCEL Tabelle
'Der Namen dieser Tabelle ändert sich jedoch immer wieder
'Um die manuellen Anpassungen zu umgehen werden diese automatisch upgedatet
'
'Dazu wird eine INI Datei angelegt in welcher die alte Verknüpfungsdatei gespeichert wird
'Existiert noch keine, wird eine INI Datei angelegt mit dem Bezug auf die AKTUELLE ARBEITSMAPPE
'Die Objecte in der Präsentation MÜSSEN beim erstmaligen Start also auf
'die aktuell geöffnete Mappe mit diesem Makro verweisen
'
'Beim starten wird dann gefragt ob auf eine neue Mappe Bezug genommen werden soll,
'der Benutzer wählt eine neue Datei aus ( Diese Datei MUSS Identisch sein mit der Originaldatei )
'd.h. die ursprünglich erstellte Datei darf nur unter einem anderen Namen gespeichert werden !!!
'Die Objectnamen dürfen NICHT geändert werden !!!
'
'Die Tabelle kann kaskadieren nach dem Vater - Sohn Prinzip
'Aus der Sohn-Tabelle können weitere Objecte in die Präsentation kopiert werden
'wenn die Objecte mit den neuen Werten auf diese Sohn Tabelle verweisen
'Bei einem Verweis auf die VATERTABELLE werden die Objecte in der Präsentation
'die in der Sohn-Tabelle vorhanden sind, nicht mehr dargestellt!!
'************************
'Integer Delaration
Dim i As Integer, Qe As Integer
'Object Deklaration
Dim ppApp As Object, ppPres As Object, sh As Object
'String Deklaration
Dim ppFile As String, iniFile As String
Dim LinkFile As String, oldLinkfile As String, NewLinkfile As String
Dim tmpLink As String, onlyOldFileName As String, onlyNewFileName As String, cBSl As Integer
'Variablen füllen
NewLinkfile = ""
'Prüfen ob PP-Datei vorhanden
ppFile = ThisWorkbook.Path & ppPresName
If Dir(ppFile) = "" Then
      Beep
      Qe = MsgBox("Die Datei " & ppFile & " existiert nicht!", vbCritical + vbOKOnly, "Datei Fehler")
      Exit Sub
End If
'Zwischenspeichern des Namens für die Quelldatei
iniFile = ThisWorkbook.Path & LinkIni
'Prüfen ob INI Datei vorhanden
If Dir(iniFile) = "" Then
    Qe = MsgBox("Die Datei " & Chr$(13) & iniFile & Chr$(13) & "wurde noch nicht definiert," & Chr$(13) & _
        "Es wird eine neue " & Chr$(13) & LinkIni & Chr$(13) & "erstellt mit der Quelle zu " & Chr$(13) & _
        ThisWorkbook.FullName, vbInformation + vbOKCancel, "Source Fehler")
    If Qe = vbCancel Then
        Qe = MsgBox("Das Erstellen der Datei " & Chr$(13) & _
            LinkIni & Chr$(13) & _
            " wurde abgebrochen," & Chr$(13) & _
            "Das Makro zum Starten der Präsentation wird " & Chr(13) & _
            "gestoppt und die PP Links nicht upgedatet !", vbInformation + vbOKOnly, "Source Fehler")
            Exit Sub
    End If
    'Erstellen einer neuen Link.ini
    Open iniFile For Output As #1
        'Schreiben der aktuell geöffneten Datei als Verknüpfung
        Print #1, ThisWorkbook.FullName
    Close #1
End If
'Schliessen einer eventuell geöffneten INI-Datei
Close #1
'Der Speicherort der INI Datei wird in der Const LiniIni definiert
Open iniFile For Input As #1
Do While Not EOF(1)
    'Einlesen der SourceQuelle für die Präsentation
    Input #1, oldLinkfile
Loop
'Schliessen der Datei
Close #1

'Abfrage ob neue Verknüpfungdatei definiert werden soll
Qe = MsgBox("Die aktuelle Verknüpfungdatei von " & Chr$(13) & ppPresName & Chr$(13) & _
    "ist derzeit die Datei " & Chr$(13) & _
    oldLinkfile & "." & Chr$(13) & _
    "Soll die Verknüpfungsdatei geändert werden ?", vbQuestion + vbYesNo, "Source Definition")
If Qe = vbYes Then
    'Wenn ja
    NewLinkfile = Application.GetOpenFilename("XLS Dateien (*.xls),", True, "Neue Verknüpfungsdatei auswählen", "Übernehmen", False)
    'sicherheitsabfrage
    Qe = MsgBox("Soll die Datei " & Chr$(13) & NewLinkfile & Chr$(13) & "als neue Verknüpfung definiert werden?", _
        vbQuestion + vbOKCancel, "Source Definition")
    If Qe = vbNo Then
        'Verwendung der bisherigen Datei um Update der Präsentation
        Qe = MsgBox("Die Definition der Datei" & Chr$(13) & _
            NewLinkfile & Chr$(13) & _
            " wurde abgebrochen," & Chr$(13) & _
            "Es wird die alte Datei " & oldLinkfile & "verwendet !", vbInformation + vbOKOnly, "Source Definition")
    Else
        'Neue Linkdatei wird geschrieben und zum Update verwendet
        Open iniFile For Output As #1
        'Schreiben der aktuell geöffneten Datei als Verknüpfung
            Write #1, NewLinkfile
        Close #1
    End If
End If
Set ppApp = CreateObject("PowerPoint.Application")
ppApp.Visible = msoTrue
Set ppPres = ppApp.Presentations.Open(ppFile)
'---------------------
'Verknüpfungen updaten
'Wenn die Verknüpfungdatei nicht geändert wurde
'werden nur die Werte aktualisiert
If NewLinkfile = "" Then
    For i = 1 To ppPres.Slides.Count
        For Each sh In ppPres.Slides(i).Shapes
            If sh.Type = msoLinkedOLEObject Then
                With sh.LinkFormat
                    .Update
                End With
            End If
        Next
    Next i
Else
    'Die Verknüpfungsdatei wurde geändert
    'Dazu muss der Filenamen extrahiert werden
    'den die directen Object Bezüge müssen ebenfalls angepasst werden
    'Variante für alle Excel Versionen
    cBSl = 0
    For i = Len(oldLinkfile) To 1 Step -1
        If Mid(oldLinkfile, i, 1) = "\" Then
            onlyOldFileName = Right(oldLinkfile, Len(oldLinkfile) - i)
            Exit For
        End If
    Next i
    cBSl = 0
    For i = Len(NewLinkfile) To 1 Step -1
        If Mid(NewLinkfile, i, 1) = "\" Then
            onlyNewFileName = Right(NewLinkfile, Len(NewLinkfile) - i)
            Exit For
        End If
    Next i
    For i = 1 To ppPres.Slides.Count
        For Each sh In ppPres.Slides(i).Shapes
            If sh.Type = msoLinkedOLEObject Then
                With sh.LinkFormat
                    'Externen Filebezug updaten
                    tmpLink = Replace(.SourceFullName, oldLinkfile, NewLinkfile, 1)
                    'Updaten der direkten Object Bezüge
                    tmpLink = Replace(tmpLink, onlyOldFileName, onlyNewFileName, 1)
                    .SourceFullName = tmpLink
                    .Update
                End With
            End If
        Next
    Next i
End If
'---------------------
ppPres.SlideShowSettings.Run
'ppApp.Quit
Set ppPres = Nothing
Set ppApp = Nothing
End Sub





Viele Grüße
Anja
  


Betrifft: AW: Excel Objects ins Powerpoin per VBA übertragen von: Anja
Geschrieben am: 13.08.2004 14:58:05

:(

Niemand sieht mich...

Wie so...

Mannn, kann vielleicht jemand 1 Minut Ziet für mich finden? :'(

Viele Grüße

Anja


  


Betrifft: @Ramses von: andre
Geschrieben am: 13.08.2004 18:16:57




  


Betrifft: @Ramses von: andre
Geschrieben am: 13.08.2004 18:18:08




 

Beiträge aus den Excel-Beispielen zum Thema "Excel Objects ins Powerpoin per VBA übertragen"