Hyperlink auf Bilder setzen

Bild

Betrifft: Hyperlink auf Bilder setzen
von: Captain Jack Sparrow
Geschrieben am: 30.04.2015 10:44:26

Moin @all,
ich habe eine Tabelle(Überblick) mit Passfotos; diese sind benamt mit Ziffern von 1 bis 23.
In einer weiteren Tabelle (Bilder) dieser Mappe sind die Bilder mit Daten hinterlegt.
Nun möchte ich die Bilder in der Tabelle Überblick abfragen und mit denen in der Bildertabelle abgleichen - funzt auch.
Gibt es eine Übereinstimmung, dann möchte ich allerdings auf die Bidler der Tabelle Überblick einen Hyperlink setzen... und genau hier halt es bei mir...


Dim objShape As Shape
For Each objShape In Worksheets("Überblick").Shapes
    If IsNumeric(objShape.Name) Then
            For I = 3 To Worksheets("Bilder").UsedRange.Rows.Count
                If Worksheets("Bilder").Cells(I, 2) = objShape.Name Then
                    dummy = Worksheets("Bilder").Cells(I, 4)
                    Exit For
                End If
            Next I
        objShape.Select
        ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:=Worksheets(dummy), ScreenTip:=" _
Hier gelangen Sie Einzelübersicht"
    End If
Next
Die Meldung bei der Zeile mit dem Hyperlink ist simpel: Typen unverträglich
Was mache ich falsch?
Danke
Jack

Bild

Betrifft: AW: Hyperlink auf Bilder setzen
von: fcs
Geschrieben am: 30.04.2015 12:09:49
Hallo Jack,
für Hyperlinks auf Zellen innerhalb einer Arbeitsmappe sieht die Syntax etwas anders aus. Außerdem muss der Hypelink innerhalb der If-Prüfung in der Prüf-/Suchschleife erstellt werden.
Gruß
Franz

Sub MakeHyperlinks()
  'Hyperlinks zu Shape-Objekten zuweisen
  Dim objShape As Shape
  Dim i As Long
  Dim dummy
  For Each objShape In Worksheets("Überblick").Shapes
    If IsNumeric(objShape.Name) Then
      With Worksheets("Bilder")
        For i = 3 To .UsedRange.Rows.Count
            If .Cells(i, 2) = objShape.Name Then
                Set dummy = .Cells(i, 4) 'Zielzelle für den Hyperlink
                Worksheets("Überblick").Hyperlinks.Add Anchor:=objShape, Address:="", _
                    SubAddress:="'" & .Name & "'!" & dummy.Address, _
                    ScreenTip:="Hier gelangen Sie zur Einzelübersicht"
                Exit For
            End If
        Next i
      End With
    End If
  Next
End Sub


Bild

Betrifft: AW: Hyperlink auf Bilder setzen
von: Captain Jack Sparrow
Geschrieben am: 30.04.2015 13:07:24
HI,
das ist schon fast richtig... .-)
Ich möchte ja, dass die Shapes (also die Bilder in Überblick) den Link auf das jeweilige Tabellenblatt gesetzt bekommen. Den Namen des Blattes ist ja eben in .Cells(I,4)

Bild

Betrifft: AW: Hyperlink auf Bilder setzen
von: fcs
Geschrieben am: 30.04.2015 14:08:20
Hallo Jack,
das war in deiner Frage ja nicht so klar formuliert.
Wenn du auf andere Tabellenblätter den Hyperlink setzen willst, dann schaut es wie folgt aus.
Gruß
Franz

Sub MakeHyperlinks()
  'Hyperlinks zu Shape-Objekten zuweisen
  Dim objShape As Shape
  Dim i As Long
  Dim dummy
  For Each objShape In Worksheets("Überblick").Shapes
    If IsNumeric(objShape.Name) Then
      With Worksheets("Bilder")
        For i = 3 To .UsedRange.Rows.Count
            If .Cells(i, 2) = objShape.Name Then
                dummy = .Cells(i, 4).Text 'Zieltabelle für den Hyperlink
                Worksheets("Überblick").Hyperlinks.Add Anchor:=objShape, Address:="", _
                    SubAddress:="'" & dummy & "'!A1", _
                    ScreenTip:="Hier gelangen Sie zur Einzelübersicht"
                Exit For
            End If
        Next i
      End With
    End If
  Next
End Sub


Bild

Betrifft: AW: Hyperlink auf Bilder setzen
von: Captain Jack Sparrow
Geschrieben am: 30.04.2015 14:12:43
Perfekt!
Danke..., ok diesen genauen Hinweis hatte ich nicht. Sorry.
JAck

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Hyperlink auf Bilder setzen"