nach Makro " Blattnummer" um eins erhöhen

Forumthread: nach Makro " Blattnummer" um eins erhöhen

10.12.2016 10:00:29

Andi

Hallo,
habe folgendes Makro,


Sub Makro1()
' Objektdaten Übernehmen auf Blatt Drucken
Range("V6:Z9").Select
Selection.Copy
Sheets("Drucken").Select
Range("B5").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Sheets("Bearbeiten").Select
Range("V13:X16").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("Drucken").Select
Range("I5").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Sheets("Bearbeiten").Select
Range("X11").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("Drucken").Select
Range("K4").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
End Sub

Bei der Prozedur: Range("X11").Select wird die Nummer ins Blatt Drucken übertragen. Diese hat, (ich weiß, man sollte dies nach Möglichkeit nicht in eine einzige Zelle Schreiben) folgende Merkmale:
01-0066.16
Ist es möglich, nach dem Ausführen des Makros1, die Zahl ( zur Zeit 0066 )um eins zu erhöhen? und diesen Wert dann in das Blatt "Bearbeiten " in diese Zelle zu Übertragen?
wenn z.B 01-0120.16 dann nach Makro1 01-0121.16
Würde diese Möglichkeit bestehen? Wie könnte der Code dafür aussehen?
MfG Andi

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: nach Makro " Blattnummer" um eins erhöhen

10.12.2016 10:51:56

Gerd
AW: nach Makro " Blattnummer" um eins erhöhen

10.12.2016 11:13:07

Andi

AW: nach Makro " Blattnummer" um eins erhöhen

10.12.2016 10:51:56

Gerd

Hallo Andi,
teste mal.

Sub Uebertragen_und_weiterzaehlen()
Dim wsQuelle As Worksheet, wsZiel As Worksheet
Set wsQuelle = Worksheets("Bearbeiten")
Set wsZiel = Worksheets("Drucken")
Call Werte_kopieren(wsQuelle.Range("V6:Z9"), wsZiel.Range("B5"))
Call Werte_kopieren(wsQuelle.Range("V13:X16"), wsZiel.Range("I5"))
Call Werte_kopieren(wsQuelle.Range("X11"), wsZiel.Range("K4"))
With wsQuelle.Range("X11")
.Replace Mid$(.Cells, 4, 4), Format$(Val(Mid$(.Cells, 4, 4) + 1), "0000")
End With
Set wsQuelle = Nothing: Set wsZiel = Nothing
End Sub
Sub Werte_kopieren(rngQuelle As Range, rngZiel As Range)
rngQuelle.Copy
rngZiel.PasteSpecial xlPasteValues
Application.CutCopyMode = False
End Sub

Gruß Gerd

AW: nach Makro " Blattnummer" um eins erhöhen

10.12.2016 11:13:07

Andi

Danke Gerd- hätte ich so nicht hinbekommen-
geht super- danke fürs "eindampfen"
habe mal noch "Application.ScreenUpdating = False" davor gesetzt.
Am Ende das "Application.ScreenUpdating = True" kann glaube ich, entfallen.
Gruß Andi

Beliebteste Forumthreads (12 Monate)

nach Makro " Blattnummer" um eins erhöhen

Forumthread: nach Makro " Blattnummer" um eins erhöhen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread