Change event von ComboBox wird beim Starten ausgef

Hallo,
In meinem VBA Skrip funktioniert alles soweit, bis auf das Starten von der *.xlsm Datei.
Es sieht so aus, als wenn das Change Event der benutzten Combobox noch bevor das Woorkbook_Open Event ausgeführt wird. Und das führt zu einem Fehler.
Auszug aus dem Programm:

Private Sub ComboBox1_Change() 'Transmitter Type
If ComboBox1 = "-" Then
CheckBox35 = False
CheckBox35.Enabled = False
End If
End Sub

Das Problem ist in dem .Enable Befehl.
Fehlermeldung beim Öffnen -> Laufzeitfehler '424': Objekt erforderlich
Wenn ich dem jetzt das komplette Objekt übergebe mit

Private Sub ComboBox1_Change() 'Transmitter Type
If ComboBox1 = "-" Then
Worksheets("RouteCard").CheckBox35 = False
Worksheets("RouteCard").CheckBox35.Enabled = False
End If
End Sub

Nun kommt die Fehlermeldung:
-> Laufzeitfehler '438': Objekt unterstützt diese Eigenschaft oder Methode nicht
Was ja nicht stimmt, weil wenn das Makro einmal gestartet ist, alles prima klappt.
Was mache ich falsch oder muss ich die Combobox noch irgendwie initialisieren?
Wird beim Starten zuerst der Code verifiziert ohne Werte direkt zu setzen?
Übrigens die Combobox wird mit der Eigenschaft "ListFillRange" auf einen im Namensmanager zugewiesenen Wert gesetzt.
Auch nach längerer Suche im Netzt konnte ich kein ähnliches Problem finden und ich habe jetzt schon sehr viel probiert, aber nichts hat geholfen.
Hat jemand eine Idee?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo,
Du müsstest mit einem booleschen Flag den Event-Durchlauf beim Start verhindern und die Checkboxen über Late Binding als Object zur Laufzeit setzen, dann sollte es ohne On Error Resume Next funktionieren:

' ********************************************************************** 
' Modul: DieseArbeitsmappe Typ: Klassenmodul der Arbeitsmappe 
' ********************************************************************** 

Option Explicit

Private Sub Workbook_Open()
Call Application.OnTime(EarliestTime:=Now, Procedure:=CodeName & ".prcEnableEvent")
End Sub

Friend Sub prcEnableEvent()
 Tabelle1.prpblnCheckBoxEvent = True
 Call Tabelle1.Init_Boxes
End Sub

' ********************************************************************** 
' Modul: Tabelle1 Typ: Klassenmodul des Tabellenblattes 
' ********************************************************************** 

Option Explicit

Private mblnCheckBoxEvent As Boolean
Private maobjCheckBoxes(1 To 4) As MSForms.CheckBox

Private Sub CheckBox3_Click()
    If CheckBox3 = True Then
        CheckBox4 = False
        CheckBox5 = False
        CheckBox6 = False
    End If
End Sub

Private Sub CheckBox4_Click()
If CheckBox4 = True Then
    CheckBox3 = False
    CheckBox5 = False
    CheckBox6 = False
End If
End Sub

Private Sub CheckBox5_Click()
If CheckBox5 = True Then
    CheckBox3 = False
    CheckBox4 = False
    CheckBox6 = False
End If
End Sub

Private Sub CheckBox6_Click()
If CheckBox6 = True Then
    CheckBox3 = False
    CheckBox4 = False
    CheckBox5 = False
End If
End Sub

Private Sub ComboBox1_Change()
If mblnCheckBoxEvent Then
    If ComboBox1.Value = "-" Then
        maobjCheckBoxes(1).Enabled = False
        maobjCheckBoxes(1).Value = False
        maobjCheckBoxes(2).Enabled = False
        maobjCheckBoxes(2).Value = False
        maobjCheckBoxes(3).Enabled = False
        maobjCheckBoxes(3).Value = False
        maobjCheckBoxes(4).Enabled = False
        maobjCheckBoxes(4).Value = False
    End If
    
    If ComboBox1.Value = "Excalibur 6" Then
        maobjCheckBoxes(1).Enabled = True
        maobjCheckBoxes(1).Value = True
        maobjCheckBoxes(2).Enabled = True
        maobjCheckBoxes(2).Value = False
        maobjCheckBoxes(3).Enabled = True
        maobjCheckBoxes(3).Value = False
        maobjCheckBoxes(4).Enabled = True
        maobjCheckBoxes(4).Value = False
    End If
End If
End Sub

Friend Property Get prpblnCheckBoxEvent() As Boolean
 Let prpblnCheckBoxEvent = mblnCheckBoxEvent
End Property

Friend Property Let prpblnCheckBoxEvent(ByVal pvblnCheckBoxEvent As Boolean)
 Let mblnCheckBoxEvent = pvblnCheckBoxEvent
End Property

Friend Sub Init_Boxes()
  Set maobjCheckBoxes(1) = CheckBox3
  Set maobjCheckBoxes(2) = CheckBox4
  Set maobjCheckBoxes(3) = CheckBox5
  Set maobjCheckBoxes(4) = CheckBox6
End Sub



VBA/HTML - CodeConverter für Office-Foren

AddIn für Excel/Word 2000-2010 - komplett in VBA geschrieben von Lukas Mosimann
Projektbetreuung durch mumpel


Code erstellt und getestet in Office 12

Gruß, Mullit

' ********************************************************************** ' Modul: DieseArbeitsmappe Typ: Klassenmodul der Arbeitsmappe ' ********************************************************************** Option Explicit Private Sub Workbook_Open() Call Application.OnTime(EarliestTime:=Now, Procedure:=CodeName & ".prcEnableEvent") End Sub Friend Sub prcEnableEvent() Call Tabelle1.Init_Boxes End Sub ' ********************************************************************** ' Modul: Tabelle1 Typ: Klassenmodul des Tabellenblattes ' ********************************************************************** Option Explicit Private maobjCheckBoxes(1 To 4) As MSForms.CheckBox Private Sub CheckBox3_Click() If CheckBox3 = True Then CheckBox4 = False CheckBox5 = False CheckBox6 = False End If End Sub Private Sub CheckBox4_Click() If CheckBox4 = True Then CheckBox3 = False CheckBox5 = False CheckBox6 = False End If End Sub Private Sub CheckBox5_Click() If CheckBox5 = True Then CheckBox3 = False CheckBox4 = False CheckBox6 = False End If End Sub Private Sub CheckBox6_Click() If CheckBox6 = True Then CheckBox3 = False CheckBox4 = False CheckBox5 = False End If End Sub Private Sub ComboBox1_Change() If Not maobjCheckBoxes(1) Is Nothing Then If ComboBox1.Value = "-" Then maobjCheckBoxes(1).Enabled = False maobjCheckBoxes(1).Value = False maobjCheckBoxes(2).Enabled = False maobjCheckBoxes(2).Value = False maobjCheckBoxes(3).Enabled = False maobjCheckBoxes(3).Value = False maobjCheckBoxes(4).Enabled = False maobjCheckBoxes(4).Value = False End If If ComboBox1.Value = "Excalibur 6" Then maobjCheckBoxes(1).Enabled = True maobjCheckBoxes(1).Value = True maobjCheckBoxes(2).Enabled = True maobjCheckBoxes(2).Value = False maobjCheckBoxes(3).Enabled = True maobjCheckBoxes(3).Value = False maobjCheckBoxes(4).Enabled = True maobjCheckBoxes(4).Value = False End If End If End Sub Friend Sub Init_Boxes() Set maobjCheckBoxes(1) = CheckBox3 Set maobjCheckBoxes(2) = CheckBox4 Set maobjCheckBoxes(3) = CheckBox5 Set maobjCheckBoxes(4) = CheckBox6 End Sub VBA/HTML - CodeConverter für Office-Foren AddIn für Excel/Word 2000-2010 - komplett in VBA geschrieben von Lukas Mosimann Projektbetreuung durch mumpel Code erstellt und getestet in Office 12

Beliebteste Forumthreads (12 Monate)

Change event von ComboBox wird beim Starten ausgef

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

195 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Change event von ComboBox wird beim Starten ausgef

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

195 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread