SUMME KGRÖSSTEN

Forumthread: SUMME KGRÖSSTEN

SUMME KGRÖSSTEN

21.04.2009 15:01:27

Martin

hallo experten,
mit forgender formel bekomme ich die summe der 6 grössten zahlen:
=WENN(ISTFEHLER(KGRÖSSTE(D5:D19;1));0;SUMMENPRODUKT(KGRÖSSTE(D5:D19; ZEILE(INDIREKT("1:"&6+((ANZAHL(D5:D19)<6)*(ANZAHL(D5:D19)-6)))))))
was auch prima klappt.
ich möchte aber nun das so umstellen, daß er nur die 6 grössten zahlen nimmt wo in spalte "c" ein "j" vor steht.
ich hoffe ich habe mich verständlich ausgedrückt.
vor eure hilfe bedanke ich mich im voraus.
gruss/martin

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: SUMME KGRÖSSTEN

21.04.2009 15:45:45

Tino
AW: SUMME KGRÖSSTEN

21.04.2009 15:53:01

Martin
AW: SUMME KGRÖSSTEN

21.04.2009 15:57:06

Tino
AW: SUMME KGRÖSSTEN

21.04.2009 16:12:26

Tino
AW: SUMME KGRÖSSTEN

21.04.2009 16:14:43

Martin
AW: SUMME KGRÖSSTEN

21.04.2009 16:46:55

Tino
AW: SUMME KGRÖSSTEN

21.04.2009 16:58:18

Martin

AW: SUMME KGRÖSSTEN

21.04.2009 15:45:45

Tino

Hallo,
geht es so?

	C	D	E	F
2	j	1		13
3		5		11
4	j	4		8
5	j	3		4
6	j	2		3
7		10		2
8	j	8
9	j	13
10	j	11
11		25

Formeln der Tabelle

Zelle	Formel
F2	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A1))}
F3	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A2))}
F4	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A3))}
F5	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A4))}
F6	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A5))}
F7	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A6))}

Gruß Tino

AW: SUMME KGRÖSSTEN

21.04.2009 15:53:01

Martin

hallo tino,
ich brauche nicht die einzelnen 6 ergebnisse sondern es soll ein gesamtergebnis werden.
gruss/martin

AW: SUMME KGRÖSSTEN

21.04.2009 15:57:06

Tino

Hallo,
ach die Summe.
hier mal zwei Möglichkeiten.

	C	D	E	F	G
1				so	oder so ohne Hilfsspalte
2	j	1	Summe:	41	41
3		5		13
4	j	4		11
5	j	3		8
6	j	2		4
7		10		3
8	j	8		2
9	j	13
10	j	11
11		25

Formeln der Tabelle

Zelle	Formel
F2	=SUMME(F3:F8)
G2	{=SUMME(WENN($C$2:$C$11="j";WENN($D$2:$D$11>=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);6);$D$2:$D$11)))}
F3	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A1))}
F4	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A2))}
F5	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A3))}
F6	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A4))}
F7	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A5))}
F8	{=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);ZEILE($A6))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Gruß Tino

AW: SUMME KGRÖSSTEN

21.04.2009 16:12:26

Tino

Hallo,
oder auch so.

	C	D	E
1			Mit Summenprodukt
2	j	1	44
3	j	2
4	j	3
5	j	4
6		5
7	j	11
8		10
9	j	11
10	j	13
11		25

Formeln der Tabelle

Zelle	Formel
E2	=SUMMENPRODUKT(($C$2:$C$11="j")($D$2:$D$11>=KKLEINSTE($D$2:$D$11;ZÄHLENWENN($C$2:$C$11;"j")-5))(D2:D11))

Gruß Tino

AW: SUMME KGRÖSSTEN

21.04.2009 16:14:43

Martin

hallo tino,
klappt, aber wenn in c ein j steht un in d keine zahl kommt die meldung #Zahl!
die müsste man noch unterdrücken dann klappts.
gruß/martin

AW: SUMME KGRÖSSTEN

21.04.2009 16:46:55

Tino

Hallo,
dies liegt nicht an den Buchstaben, sondern dass es keine 6 Größten Werte gibt.
Versuche es mal so.

	C	D	E
1			21
2	j	1
3	j	2
4	j	3
5	j	H
6		5
7	j	G
8		10
9	j	h
10	j	15

Formeln der Tabelle

Zelle	Formel
E1	{=SUMME(WENN($C$2:$C$11="j";WENN($D$2:$D$11>=KGRÖSSTE(WENN($C$2:$C$11="j";$D$2:$D$11);MIN(SUMMENPRODUKT(($C$2:$C$10="j")*($D$2:$D$10<10^208));6));$D$2:$D$11)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Gruß Tino

AW: SUMME KGRÖSSTEN

21.04.2009 16:58:18

Martin

hallo tino,
klappt prima.
danke für deine bemühungen.
gruß/martin

Beliebteste Forumthreads (12 Monate)

Forumthread: SUMME KGRÖSSTEN

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread