Kalenderwoche und Jahr aus Datum

gerhard · 1970-01-01T00:00:00+00:00

Hallo zusammen. In Spalte A ab A6 steht das Datum im Format Do, 16.07.2009 wie kann ich in Spalte B via Makro automatisch daraus die Kalenderwoche und das Jahr im Format 29/09 darstellen? Vielen Dank Gruß gerhard

Hallo Gerhard,
wozu für eine so einfache AUfgabe VBA?

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.Address = "$A$1" Then Range("B1") = Format(DINKwoche(Target), "00") & Format(Target, "\/yy")
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Function DINKwoche(ByVal Datum As Date) As Integer
  Dim tmp As Date
  tmp = DateSerial(Year(Datum + (8 - Weekday(Datum)) Mod 7 - 3), 1, 1)
  DINKwoche = ((Datum - tmp - 3 + (Weekday(tmp) + 1) Mod 7)) \ 7 + 1
End Function

Gruß Sepp

Hallo Gerhard,

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  With Target
    If .Column = 1 And .Row > 5 And .Count = 1 Then
      'B als Text Formatieren, weil sonst manche Einträge als Datum interpretiert werden!
      .Offset(0, 1).NumberFormat = "@"
      .Offset(0, 1) = Format(DINKwoche(Target), "00") & Format(Target, "\/yy")
    End If
  End With
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Function DINKwoche(ByVal Datum As Date) As Integer
  Dim tmp As Date
  tmp = DateSerial(Year(Datum + (8 - Weekday(Datum)) Mod 7 - 3), 1, 1)
  DINKwoche = ((Datum - tmp - 3 + (Weekday(tmp) + 1) Mod 7)) \ 7 + 1
End Function

Gruß Sepp

Forumthread: Kalenderwoche und Jahr aus Datum

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial