Microsoft Excel

Herbers Excel/VBA-Archiv

Datum aus Tag, Jahr, KW auslesen

Betrifft: Datum aus Tag, Jahr, KW auslesen von: Stephan
Geschrieben am: 16.08.2008 22:23:12

Gibt es eine Möglichkeit das Datum auszulesen aus:
Mo = Montag
Jahr=2008
KW=1

Besten Dank
Stephan

  

Betrifft: AW: Datum aus Tag, Jahr, KW auslesen von: Hajo_Zi
Geschrieben am: 16.08.2008 22:26:38

Hallo Stephan,


Kalenderwoche eingeben und Zeitraum erhalten (deutsche DIN)
Ermittlung Montag
http://www.excelformeln.de/ _
formeln.html?welcher=186

In A1 steht die Kalenderwoche.
In A2 die vierstellige Jahreszahl
=DATUM(A2;1;1)+$A$1*7-WOCHENTAG(DATUM(A2;1;1);2)+WENN(WOCHENTAG(DATUM(A2;1;1);2)>4;1;-6)
von Berti


GrußformelHomepage


  

Betrifft: AW: Datum aus Tag, Jahr, KW auslesen von: jockel
Geschrieben am: 16.08.2008 23:14:46

hi Stephan, es gab in 2008 keinen montag in der KW1...

Tabelle1

 AB
1MoMontag
2Jahr2008
3KW1
4  
5 31.12.2007

Formeln der Tabelle
ZelleFormel
B1=B5
B5=("4.1."&B2)+B3*7-7-REST("2.1."&B2;7)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

cu jörg
ein feedback wär ganz reizend


  

Betrifft: AW: Datum aus Tag, Jahr, KW von: Erich G.
Geschrieben am: 17.08.2008 12:10:52

Hi,
es kommt halt darauf an, welches "Jahr" man meint:
- das Kalenderjahr zum Datum oder
- das Jahr, zu dem die Kalenderwoche gehört.

Sicherer ist es immer, nicht nur die KW sondern JahrKW anzugeben.

Vielleicht hilft die Tabelle ein wenig der Klärung:

 ABCDEFGH
1DatumJahrWocheWoJahrWoBeginnJahrKWoder
JahrKW
WoBeg
aus JahrKW
2So    30.12.20072007522007Mo   24.12.20072007w522007w52Mo   24.12.2007
3Mo   31.12.2007200712008Mo   31.12.20072008w012008w01Mo   31.12.2007
4Di     01.01.2008200812008Mo   31.12.20072008w012008w01Mo   31.12.2007
5        
6So    28.12.20082008522008Mo   22.12.20082008w522008w52Mo   22.12.2008
7Mo   29.12.2008200812009Mo   29.12.20082009w012009w01Mo   29.12.2008
8Do    01.01.2009200912009Mo   29.12.20082009w012009w01Mo   29.12.2008
9So    04.01.2009200912009Mo   29.12.20082009w012009w01Mo   29.12.2008
10Mo   05.01.2009200922009Mo   05.01.20092009w022009w02Mo   05.01.2009

Formeln der Tabelle
ZelleFormel
B2=JAHR(A2)
C2=KÜRZEN((A2-DATUM(JAHR(A2+3-REST(A2-2;7)); 1;REST(A2-2;7)-9))/7)
D2=JAHR(A2)-(MONAT(A2)=1)*(C2>9)+(MONAT(A2)=12)*(C2=1)
E2=("4.1."&D2)+C2*7-7-REST("2.1."&D2;7)
F2=MIN(JAHR(A2-1-REST(A2-2;7)+4); JAHR(A2-REST(A2-1;7)+4))&TEXT(KÜRZEN((A2-DATUM(JAHR(A2+3-REST(A2-2;7)); 1;REST(A2-2;7)-9))/7); "w00")
G2=D2&TEXT(C2;"w00")
H2=DATUM(LINKS(F2;4); 1;7*RECHTS(F2;2)-3-WOCHENTAG(DATUM(LINKS(F2;4); ;); 3))

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Datum aus Tag, Jahr, KW auslesen von: lou38
Geschrieben am: 17.08.2008 14:43:33

Hallo Stephan
Hier ein weiterer Lösungsvorschlag:

A1 = Mo (oder Montag)
A2 = 2008
A3 = 1 (d.h. KW)

=DATUM(A2;1;7*A3-3)-WOCHENTAG(DATUM(A2;;);2)+VERGLEICH(LINKS(A1;2);{"Mo";"Di";"Mi";"Do";"Fr";"Sa"; "So"};0)

Gruss
Louis


  

Betrifft: AW: Datum aus Tag, Jahr, KW auslesen von: Erich G.
Geschrieben am: 17.08.2008 17:56:56

Hi,
die Profis von Excelformeln.de können das natürlich etwas kürzer (Formel in E2):

 ABCDE
1KW-JahrKWWoTagErgebnisoder
220091MoXYZMo      29.12.2008Mo      29.12.2008
320091DoDo       01.01.2009Do       01.01.2009
420091SamstagSa       03.01.2009Sa       03.01.2009

Formeln der Tabelle
ZelleFormel
D2=DATUM(A2;1;7*B2-3)-WOCHENTAG(DATUM(A2;;); 2)+VERGLEICH(LINKS(C2;2); {"Mo";"Di";"Mi";"Do";"Fr";"Sa";"So"};0)
E2=("4.1."&A2)+B2*7-8-REST("2.1."&A2;7)+VERGLEICH(LINKS(C2;2); {"Mo"."Di"."Mi"."Do"."Fr"."Sa"."So"};)

(aus der von Hajo schon zitierten Seite http://www.excelformeln.de/formeln.html?welcher=186 )

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort


  

Betrifft: AW: Datum aus Tag, Jahr, KW auslesen von: lou38
Geschrieben am: 17.08.2008 23:12:22

Hallo Erich

Ja, deine Formel ist etwas kürzer - wie meistens bei Excel führen immer mehrere Wege nach Rom. Ich ziehe meine Formel trotzdem vor, weil ich eine Abneigung gegen Datumskonstrukte mit Anführungszeichen ("4.1.") habe.

Gruss
Louis


 

Beiträge aus den Excel-Beispielen zum Thema "Datum aus Tag, Jahr, KW auslesen"