Hex in Dez mit großen Zahlen

Conrad · 2020-04-06T13:07:48+00:00

Hallo, ich versuche HEX Werte in dezimale Stellen umzuwandeln, die HEX Werte sind allerdings 14 Stellen lang. Da ich keinerlei Erfahrung in VBA habe würde ich mich über etwas Hilfe hier freuen. Beste Grüße Conrad

Hallo Conrad,
teste mal:

Option Explicit

Public Sub Beispiel()
    Dim strHex As String, strSign As String
    Dim lngIndex As Long
    Dim decValue As Variant
    decValue = CDec(decValue)
    strHex = "F0335AF2586204AAA"
    For lngIndex = 1 To Len(strHex)
        strSign = Mid$(strHex, lngIndex, 1)
        Select Case strSign
            Case 0 To 9
                decValue = decValue * 16 + CDbl(strSign)
            Case "A"
                decValue = decValue * 16 + 10
            Case "B"
                decValue = decValue * 16 + 11
            Case "C"
                decValue = decValue * 16 + 12
            Case "D"
                decValue = decValue * 16 + 13
            Case "E"
                decValue = decValue * 16 + 14
            Case "F"
                decValue = decValue * 16 + 15
        End Select
    Next
End Sub

Gruß
Nepumuk

Hallo Conrad,
als Funktion die du in deiner Mappe einsetzen kannst:

	A	B
2	80335AF2586204	36085262724915716
3	80335AF2585F04	36085262724914948

Zelle	Formel
B2	=HexInDec(A2)
B3	=HexInDec(A3)

Option Explicit

Public Function HexInDec(ByVal pvstrHex As String) As String
    Dim strSign As String
    Dim lngIndex As Long
    Dim decValue As Variant
    decValue = CDec(decValue)
    For lngIndex = 1 To Len(pvstrHex)
        strSign = Mid$(pvstrHex, lngIndex, 1)
        Select Case strSign
            Case 0 To 9
                decValue = decValue * 16 + CDbl(strSign)
            Case "A"
                decValue = decValue * 16 + 10
            Case "B"
                decValue = decValue * 16 + 11
            Case "C"
                decValue = decValue * 16 + 12
            Case "D"
                decValue = decValue * 16 + 13
            Case "E"
                decValue = decValue * 16 + 14
            Case "F"
                decValue = decValue * 16 + 15
        End Select
    Next
    HexInDec = CStr(decValue)
End Function

Gruß
Nepumuk

Forumthread: Hex in Dez mit großen Zahlen

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Hex in Dezimal umwandeln: Umrechnung großer Zahlen in Excel

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)