Microsoft Excel

Herbers Excel/VBA-Archiv

Dezimalzahl in Dualzahl umwandeln

Betrifft: Dezimalzahl in Dualzahl umwandeln von: Michael
Geschrieben am: 20.09.2004 14:14:44

Hallo liebes Forum.

Ich habe folgende Frage:
Gibt es eine Formel mit der ich eine 6 stellige Dezimalzahl in eine Dualzahl umwandeln kann?

Würde mich riesig über Eure Hilfe freuen.

Danke und Gruß
Michael

  


Betrifft: Dezimalzahl in Dualzahl umwandeln (Array) von: WF
Geschrieben am: 20.09.2004 14:20:35

Hi Michael,

{=SUMME(GANZZAHL(REST(A1/2^(SPALTE(1:1)-1);2))*10^(SPALTE(1:1)-1))}

ARRAY-Formel {=geschweifte Klammern} nicht eingeben;
Abschluß der Formel mit gleichzeitig Strg / Shift / Enter; - das erzeugt sie.

trapp, trapp, trapp, trapp, trapp, brrrrr
WF

http://www.excelformeln.de/
die ultimative Formelseite


  


Betrifft: Quatsch; - die geht ja nur bis 2^15 von: WF
Geschrieben am: 20.09.2004 14:28:29

nimm:
{=RECHTS(SUMME(GANZZAHL(REST(A1/2^(ZEILE(16:30)-1);2))*10^(ZEILE(1:15)-1))&TEXT(SUMME(GANZZAHL(REST(A1/2^(ZEILE(1:15)-1);2))*10^(ZEILE(1:15)-1));WIEDERHOLEN("0";15));GANZZAHL(LN(A1)/LN(2))+1)}

ARRAY-Formel {=geschweifte Klammern} nicht eingeben;
Abschluß der Formel mit gleichzeitig Strg / Shift / Enter; - das erzeugt sie.

trapp, trapp, trapp, trapp, trapp, brrrrr
WF

http://www.excelformeln.de/
die ultimative Formelseite


  


Betrifft: 1.000 DANK von: Michael
Geschrieben am: 20.09.2004 14:33:59

Spitze, vielen Dank für die professionelle und superschnelle Hilfe.

DANKE
Michael


  


Betrifft: Eine Frage noch !!! von: Michael
Geschrieben am: 20.09.2004 14:57:01

Hallo, eine Frage noch.

Wenn ich die Formel auf weitere Zeilen (B1:B5000) bezugnehmend auf (A1:A5000)verwenden möchte, klappt es nicht die Formel einfach zu kopieren.

Wie gehe ich dann vor???
Würde mich freuen nochmals professionelle Hilfe zu bekommen.

Danke Michael


  


Betrifft: Auch für ZEILE gibt es: Absoult und relativ von: Boris
Geschrieben am: 20.09.2004 15:05:16

Hi Michael,

so geht´s:
{=RECHTS(SUMME(GANZZAHL(REST(A1/2^(ZEILE($16:$30)-1);2))*10^(ZEILE($1:$15)-1))&TEXT(SUMME(GANZZAHL(REST(A1/2^(ZEILE($1:$15)-1);2))*10^(ZEILE($1:$15)-1));WIEDERHOLEN("0";15));GANZZAHL(LN(A1)/LN(2))+1)}

Grüße Boris
www.excelformeln.de - die Formelseite im www


  


Betrifft: AW: Auch für ZEILE gibt es: Absoult und relativ von: Michael
Geschrieben am: 20.09.2004 15:35:27

Hallo

Ich bekomme es irgendwie nicht gebacken :-(
Ich habe die Datei mal hochgeladen, wäre toll wenn Du das mal an der Datei ausprobieren kannst.
Die Dualzahlen sollen sich auf die Spalte "Steuerzeichen" beziehen.

1.000 Dank im vorraus
Michael

https://www.herber.de/bbs/user/11088.xls


  


Betrifft: Du musst die Bezüge schon anpassen... von: Boris
Geschrieben am: 20.09.2004 16:33:52

...denn die Beispielformel bezieht sich ja auf A1.
Das ist auch das Einzige, was angepasst werden muss - die Bezüge innerhalb ZEILE() NICHT!

Diese Array-Formel in H2 und runterkopieren:

{=RECHTS(SUMME(GANZZAHL(REST(B2/2^(ZEILE($16:$30)-1);2))*10^(ZEILE($1:$15)-1))&TEXT(SUMME(GANZZAHL(REST(B2/2^(ZEILE($1:$15)-1);2))*10^(ZEILE($1:$15)-1));WIEDERHOLEN("0";15));GANZZAHL(LN(B2)/LN(2))+1)}

Grüße Boris


  


Betrifft: Geschafft !!!! von: Michael
Geschrieben am: 20.09.2004 17:09:34

Hallo Boris,

Vielen Dank für Deine Hilfe....und ich habe eine Menge dazugelernt.

DANKE
Michael


 

Beiträge aus den Excel-Beispielen zum Thema "Dezimalzahl in Dualzahl umwandeln"