AW: GetOpenFilname
12.01.2007 08:04:07
haw
Hallo,
besser (und neu) ist folgende Möglichkeit:
Sub FileDialog_zum_Öffnen_einer_Datei()
Dim PfadDatei$, wb As Workbook
Dim fd As FileDialog
Set fd = Application.FileDialog(msoFileDialogOpen)
'** Eigenschaften des FileDialogs setzen
fd.AllowMultiSelect = False
fd.Title = "Projekte - Datei öffnen"
fd.ButtonName = "&Ubernehmen"
fd.InitialFileName = "C:\Daten\Excel\1Projekte"
fd.InitialView = msoFileDialogViewDetails
fd.Filters.Clear
fd.Filters.Add Description:="Excel-Dateien", Extensions:="*.xls"
fd.Filters.Add Description:="Excel-Vorlgen", Extensions:="*.xlt"
fd.FilterIndex = 1
'** Dialog darstellen und prüfen, ob der Benutzer abgebrochen hat
If fd.Show = 0 Then 'Der Benutzer hat Abbrechen gedrückt
MsgBox "Abbruch durch den Benutzer"
Exit Sub
End If
'** Ergebnis der Dateiauswahl auswerten
PfadDatei = fd.SelectedItems(1)
If MsgBox("Ausgewählte Datei:" & vbNewLine & PfadDatei & vbNewLine & vbNewLine & _
"Soll die Datei geöffnet werden?", vbYesNo) = vbYes Then
Set wb = Workbooks.Open(Filename:=PfadDatei)
End If
End Sub
l
unter fd.InitialFileName = "C:\Daten\Excel\1Projekte" kannst du Pfad (und evtl.) Datei vorgeben
Gruß Heinz