Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1232to1236
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Speichern unter - ohne Dialog und ohne...

Speichern unter - ohne Dialog und ohne...
KLE
...Meldung, wenn Datei bereits vorhanden.
Hi,
...ich möchte gern eine Datei unter einem bestimmten Namen und Pfad speichern.
In dem Ordner wird es bereits eine Datei mit dem gleichen Namen geben, welche ohne Nachfrage/Hinweis überschrieben werden soll.
Wie kann ich das tun - habe irgendwie ein Blockade im Hirn ;o(
Im Idealfall, wäre es super - wenn man per Code zuvor die Alte Datei umbenennt (Name + Datum der Dateierstellung)...geht sowas ?!?
Gruß und Danke
Kay

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Speichern unter - ohne Dialog und ohne...
25.10.2011 22:36:09
Josef

Hallo Kay,
teste mal.

' **********************************************************************
' Modul: Modul3 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub mySaveAS()
  Const cstrFileName As String = "E:\Forum\Test.xls"
  
  On Error GoTo ErrExit
  tranquilize
  
  If Dir(cstrFileName, vbNormal) <> "" Then
    Name cstrFileName As Replace$(cstrFileName, ".xls", Format(Now, "ddMMyy_hhmmss") & ".xls")
  End If
  
  ThisWorkbook.SaveAs cstrFileName
  
  ErrExit:
  tranquilize True
End Sub


Public Sub tranquilize(Optional ByVal Modus As Boolean = False)
  Static lngCalc As Long
  
  With Application
    .ScreenUpdating = Modus
    .EnableEvents = Modus
    .DisplayAlerts = Modus
    .EnableCancelKey = IIf(Modus, 1, 0)
    If Not Modus Then lngCalc = .Calculation
    If Modus And lngCalc = 0 Then lngCalc = -4105
    .Calculation = IIf(Modus, lngCalc, -4135)
    .Cursor = IIf(Modus, -4143, 2)
  End With
  
  If Modus Then
    With Err
      If .Number <> 0 Then
        MsgBox IIf(Erl, vbLf & "Fehler in Zeile:" & vbTab & Erl & vbLf & vbLf, "") & _
          "Fehlernummer:" & vbTab & .Number & vbLf & vbLf & "Beschreibung:" & vbLf & _
          .Description, vbExclamation, "Fehler"
      End If
      .Clear
    End With
  End If
End Sub



« Gruß Sepp »

Anzeige
AW: Ergänzung...Datum der Datei?
25.10.2011 22:45:41
KLE
Sieht gut aus auf dem ersten Blick...Frage, gibt es eine Möglichkeit von der zu überschreibenden Datei das Datum der Erstellung zu ermitteln und für den Dateinamen zu nutzen ?
Gruß
Kay
AW: Ergänzung...Datum der Datei?
25.10.2011 22:54:44
Josef

Hallo Kay,
klar geht das auch.

Sub mySaveAS()
  Dim strFile As String, strPath As String
  
  Const cstrFileName As String = "E:\Forum\Test.xls"
  
  On Error GoTo ErrExit
  tranquilize
  
  If Dir(cstrFileName, vbNormal) <> "" Then
    strPath = Left(cstrFileName, InStrRev(cstrFileName, "\"))
    strFile = Mid(cstrFileName, InStrRev(cstrFileName, "\") + 1)
    strFile = Left(strFile, InStrRev(strFile, ".") - 1) & "_" & _
      FileDateTime(cstrFileName) & Mid(cstrFileName, InStrRev(cstrFileName, "."))
    Name cstrFileName As strPath & strFile
  End If
  
  ThisWorkbook.SaveAs cstrFileName
  
  ErrExit:
  tranquilize True
End Sub



« Gruß Sepp »

Anzeige
Vielen dank Sepp ;o) !!! o.T.
25.10.2011 23:02:43
KLE

306 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige