Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1748to1752
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

VBA Windows-Eigenschaftsfenster anzeigen

VBA Windows-Eigenschaftsfenster anzeigen
29.03.2020 08:55:20
W
Hallo VBA-Profis,
gibt es eine Möglichkeit aus VBA heraus das Windows-Eigenschaftsfenster einer externen File anzeigen zu lassen?
Ich habe in einer Tabelle verschiedene Filenamen (ink. Pfad) und würde gerne per Doppelklick das Eigenschaftsfenster für die entsprechende File anzeigen lassen.
Gruß
W H21

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: VBA Windows-Eigenschaftsfenster anzeigen
29.03.2020 09:39:19
Nepumuk
Hallo,
ein Beispiel:
Option Explicit

Private Declare Function ShellExecuteEx Lib "shell32.dll" ( _
    SEI As SHELLEXECUTEINFO) As Long

Private Type SHELLEXECUTEINFO
    cbSize As Long
    fMask As Long
    hwnd As Long
    lpVerb As String
    lpFile As String
    lpParameters As String
    lpDirectory As String
    nShow As Long
    hInstApp As Long
    lpIDList As Long
    lpClass As String
    hkeyClass As Long
    dwHotKey As Long
    hIcon As Long
    hProcess As Long
End Type

Private Const SEE_MASK_INVOKEIDLIST = &HC
Private Const SEE_MASK_NOCLOSEPROCESS = &H40
Private Const SEE_MASK_FLAG_NO_UI = &H400

Public Sub ShowProps(ByVal pvstrFileName As String)
    
    Dim udtShellExecute As SHELLEXECUTEINFO
    
    With udtShellExecute
        
        .cbSize = Len(udtShellExecute)
        .fMask = SEE_MASK_NOCLOSEPROCESS Or _
            SEE_MASK_INVOKEIDLIST Or SEE_MASK_FLAG_NO_UI
        .hwnd = Application.hwnd
        .lpVerb = "properties"
        .lpFile = pvstrFileName
        .lpParameters = vbNullChar
        .lpDirectory = vbNullChar
        .nShow = 0
        .hInstApp = 0
        .lpIDList = 0
        
    End With
    
    Call ShellExecuteEx(udtShellExecute)
    
End Sub

Public Sub test()
    
    Call ShowProps("G:\Eigene Dateien\Eigene PDF\Arraylist_Eigenschaften.pdf")
    
End Sub

Gruß
Nepumuk
Anzeige
AW: VBA Windows-Eigenschaftsfenster anzeigen
29.03.2020 10:07:37
W
Hallo Nepumuk:
Super! Danke! funktioniert!
Gruß
W H21
VBA Windows-Eigenschaftsfenster anzeigen
29.03.2020 10:41:51
Anton
auch hallo ,
Code in Zwischenablage:

Sub b()
  Dim objShell As Object, fso As Object  
  Dim datei As String, oFolder As Object    
  datei = "C:\Users\Anton\Desktop\SI_Abnahmetest_4_8\test.rtf" 'anpassen
  If Len(Dir(datei)) = 0 Then Exit Sub    
  Set fso = CreateObject("Scripting.FileSystemObject")  
  Set objShell = CreateObject("shell.application")  
  Set oFolder = objShell.Namespace(fso.GetParentFolderName(datei))  
  oFolder.ParseName(fso.GetFileName(datei)).invokeverb ("properties")
  Set fso = Nothing  
  Set objShell = Nothing  
End Sub

mfg Anton
Anzeige
AW: VBA Windows-Eigenschaftsfenster anzeigen
29.03.2020 11:26:18
W
Hallo Anton,
auch Dir herzlichen Dank für Dein Beispiel, welches ich probiert habe. Auch dieser Code funktioniert.
Gruß
W H21

147 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige