HERBERS Excel-Forum - das Archiv
Bewerten Sie hier bitte das Excel-Portal

Thema: Jahr anpassen in einer Datumsreihe | Herbers Excel-Forum

Jahr anpassen in einer Datumsreihe
edie

Hallo zusammen,
habe bereits ein Problem das ich nicht ohne Hilfe lösen kann.
Eine Datumsreihe, mit leeren Zeilen und nach unten variabel lang, in der Spalte A
soll beim eingeben eines Jahres in Zelle D1 das Jahr übernehmen.
Im Beispiel sollte statt 2009 dann 2010 stehen.
 ABCDE
1    Jahr2010 
2         
3Datum       
410.02.2009       
520.06.2009       
6         
721.06.2009       
810.11.2009       
9         
1012.03.2009       
1105.05.2009       
12         
1313.04.2009       
1413.07.2009       

Für jede Hilfe bin ich dankbar.
Grüße

AW: Jahr anpassen in einer Datumsreihe
Josef

Hallo Edie,
in das Modul der Tabelle.
' **********************************************************************
' Modul: Tabelle3 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rng As Range, rngDate As Range
  
  On Error GoTo ErrExit
  
  If Target.Address(0, 0) = "D1" Then
    Application.EnableEvents = False
    If IsNumeric(Target) Then
      On Error Resume Next
      Set rngDate = Range("A:A").SpecialCells(xlCellTypeConstants, xlNumbers)
      On Error GoTo ErrExit
      If Not rngDate Is Nothing Then
        For Each rng In rngDate
          If IsDate(rng) Then
            rng = DateSerial(Target, Month(rng), Day(rng))
          End If
        Next
      End If
    End If
  End If
  
  ErrExit:
  Application.EnableEvents = True
End Sub

Gruß Sepp

AW: Jahr anpassen in einer Datumsreihe
edie

Hallo Sepp,
vielen, vielen herzlichen Dank.
Grüße