OptionButtons per VBA: Automation Error

Forumthread: OptionButtons per VBA: Automation Error

Sven

Hallo liebe Herber-Gemeinde,
ich hab grad das Problem, dass ich in einer langen Liste in einem Arbeitsblatt Optionbuttons _ per VBA hinzufügen möchte. Dazu benutze ich folgenden Code:


With ActiveSheet
For i = 2 To ende
.OLEObjects.Add(ClassType:="Forms.OptionButton.1", Link:=False, DisplayAsIcon:=False,   _
_
Left:=Cells(i, 10).Left, Top:=Cells(i, 10).Top, Width:=Cells(i, 10).Width, Height:=Cells(i, 10). _
Height).Name = "move" & i
ActiveSheet.OLEObjects("Move" & i).Object.GroupName = "Gruppe" & i
ActiveSheet.OLEObjects("Move" & i).Object.Caption = "Move"
.OLEObjects.Add(ClassType:="Forms.OptionButton.1", Link:=False, DisplayAsIcon:=False,   _
_
Left:=Cells(i, 11).Left, Top:=Cells(i, 11).Top, Width:=Cells(i, 11).Width, Height:=Cells(i, 11). _
Height).Name = "zip" & i
ActiveSheet.OLEObjects("zip" & i).Object.GroupName = "Gruppe" & i
ActiveSheet.OLEObjects("zip" & i).Object.Caption = "Zip"
Next i
End With

'ende' wird dabei mittels


ende = .Cells(Rows.Count, 1).End(xlUp).Row

ermittelt.
Die Liste mit der ich teste umfasst 1133 Zeilen - und bei Zeile 605 tritt der Fehler auf. Optionbutton "Move605' wird noch korrekt erstellt, 'Zip605' jedoch nicht mehr.
Hat jemand eine Idee was da falsch läuft? Vielen Dank im Voraus.... ;)

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: OptionButtons per VBA: Automation Error

20.07.2010 19:50:33

Nepumuk

Hallo,
versuch es mal so:

Public Sub test()
    Dim lngRow As Long
    Dim sngWitdh(1) As Single, sngLeft(1) As Single
    Dim objOLEObject As OLEObject
    Dim objSheet As Worksheet
    Application.ScreenUpdating = False
    Set objSheet = Tabelle1
    With objSheet
        sngWitdh(0) = .Cells(1, 10).Width
        sngWitdh(1) = .Cells(1, 11).Width
        sngLeft(0) = .Cells(1, 10).Left
        sngLeft(1) = .Cells(1, 11).Left
        For lngRow = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
            With .Cells(lngRow, 10)
                Set objOLEObject = objSheet.OLEObjects.Add(ClassType:="Forms.OptionButton.1", _
                    Left:=sngLeft(0), Top:=.Top, Width:=sngWitdh(0), Height:=.Height)
            End With
            With objOLEObject
                .Name = "move" & lngRow
                .Object.GroupName = "Gruppe" & lngRow
                .Object.Caption = "Move"
            End With
            With .Cells(lngRow, 11)
                Set objOLEObject = objSheet.OLEObjects.Add(ClassType:="Forms.OptionButton.1", _
                    Left:=sngLeft(1), Top:=.Top, Width:=sngWitdh(1), Height:=.Height)
            End With
            With objOLEObject
                .Name = "zip" & lngRow
                .Object.GroupName = "Gruppe" & lngRow
                .Object.Caption = "Zip"
            End With
        Next lngRow
    End With
    Set objOLEObject = Nothing
    Set objSheet = Nothing
    Application.ScreenUpdating = True
End Sub

Dauert aber ganz schön lang. Auf unserem schnellsten Rechner fast eine Minute. Und wenn er fertig ist, dann nochmal gut eine Minute bis die richtigen Namen auftauchen. Also nicht hektisch werden wenn da nach dem Programmende immer noch Optionbutton steht.
Gruß
Nepumuk

AW: OptionButtons per VBA: Automation Error

21.07.2010 10:45:27

Sven

Vielen Dank, das funktioniert augenscheinlich ;)

Beliebteste Forumthreads (12 Monate)

OptionButtons per VBA: Automation Error

Forumthread: OptionButtons per VBA: Automation Error

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

OptionButtons per VBA: Automation Error

Forumthread: OptionButtons per VBA: Automation Error

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread