Verschiedene Daten (MZ Datum) nach Jahre

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hi
man kann auch mit der vorhandenen Tabelle das Ergebnis relativ einfach mit Formeln erzeugen, die auch in der angegebenen Excelversion 2016 funktionieren.
(wobei es bei größeren Datenmengen etwas länger rechnen könnte)
Formeln für deine Beispieldatei:
als erstes suchst du nach allem was ein Datum in 2033 hat und lässt dir Zeile und Spalte ausgeben. Dazu schreibst du folgende Formel in G2 (Zeile 1 ist immer Überschift). Das Ergebnis ist Zeile und Spalte in einem Wert, die Zeilennummer mit 100 multipliziert, damit sie von der Spaltennummer getrennt ist


=AGGREGAT(15;6;ZEILE(B2:$E$101)*100+SPALTE($B$2:$E$101)/(JAHR($B$2:$E$101)=2033);ZEILE(A1))

Die dazugehörigen Daten (Name, Anlass, Datum) holst du dir dann mit diesen Formeln in H2, I2, J2


=INDEX($A:$A;QUOTIENT(G2;100))
=INDEX($1:$1;1;REST(G2;100))
=INDEX(A:E;QUOTIENT(G2;100);REST(G2;100))

wenn du nach anderen Bedingungen suchst, die Bedingungsprüfung steht hier in der Formel, das musst du dann ggf anpassen:
=AGGREGAT(15;6;ZEILE(B2:$E$101)*100+SPALTE($B$2:$E$101)/(JAHR($B$2:$E$101)=2033);ZEILE(A1))
Die Sortierung im Ergebnis entspricht der Reihenfolge der Liste
Sollte die Liste auch noch nach Datum sortiert sein, ist es am einfachsten du kopierst die Liste, fügst sie an anderer stelle als Wert ein und sortierst dort.
Gruß Daniel

Wenn man die Formel noch etwas erweitert, gehts auch nach Datum sortiert:
man muss nur in etwa wissen (auf die 10er-Potenz) wieviele Werte in einer Gruppe (Spalte, Zeile, Datum) maximal vorkommen können, damit man entsprechen Multiplizieren kann, damit die einzelnen Werte getrennt bleiben. Der Teil, der die Sortierung bestimmt, bekommt den größten Faktor. Wenn du also die Liste auch gerne nach Jahrestag gruppiert hättest, wäre das auch möglich in dem man der Spaltennummer den größten Faktor gibt
G2:


=AGGREGAT(15;6;($B$2:$E$101*100000+ZEILE($B$2:$E$101)*100+SPALTE($B$2:$E$101))/(JAHR($B$2:$E$101)=2023);ZEILE(A1))

die Auswertung des mittleren Wertes wird dann auch etwas aufwendiger, hier die Formeln für H2, I2, J2:


=INDEX($A:$A;REST(QUOTIENT(G2;100);1000))
=INDEX($1:$1;1;REST(G2;100))
=INDEX(A:E;REST(QUOTIENT(G2;100);1000);REST(G2;100))

Gruß Daniel

Beliebteste Forumthreads (12 Monate)

Verschiedene Daten (MZ Datum) nach Jahre

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

53 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Verschiedene Daten (MZ Datum) nach Jahre

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

53 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread