Daten aus geschlossener Datei per VBA übertragen..

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Sub Umsatz_uebertragen() ' Umsatz_uebertragen Makro ' Makro am 27.06.2006 von Besitzer aufgezeichnet Workbooks.Open FileName:= _ "C:\Dokumente und Einstellungen\Besitzer\Eigene Dateien\Umsätze.xls" Range("A2:N1100").Select Selection.Copy Windows("Statistik.xls").Activate Range("A2").Select ActiveSheet.Paste Range("B9").Select Windows("Umsätze.xls").Activate ActiveWindow.Close Range("A6").Select End Sub

Hallo Peter!

Sub Umsatz_uebertragen()
Dim objWb As Workbook
Dim objSh As Worksheet
Dim strFile As String

On Error GoTo ErrExit

With Application
  .ScreenUpdating = False
  .EnableEvents = False
  .DisplayAlerts = False
  .Calculation = xlCalculationManual
  .Cursor = xlWait
End With

strFile = "C:\Dokumente und Einstellungen\Besitzer\Eigene Dateien\Umsätze.xls"

If Not ThisWorkbook Is ActiveWorkbook Then ThisWorkbook.Activate

Set objSh = ActiveSheet
Set objWb = Workbooks.Open(strFile)

objWb.Sheets(1).Range("A2:N1100").Copy objSh.Range("A2")

objWb.Close False

ErrExit:

If Err.Number > 0 Then
  MsgBox Err.Number & vbLf & Err.Description, , "Fehler"
  Err.Clear
End If

Set objWb = Nothing
Set objSh = Nothing

With Application
  .ScreenUpdating = True
  .EnableEvents = True
  .DisplayAlerts = True
  .Calculation = xlCalculationAutomatic
  .Cursor = xlDefault
End With

End Sub

Gruß Sepp

Hallo Peter, (da brauchst du nix zu ändern, hast ja einen Namen :-) )
in dem Code kommen zwar die Mappen, aber nicht die Blätter vor, von bzw. in die kopiert wird.
Dann wird jeweils das gerade (zufällig?) aktive Blatt genommen.
Das kann im Zusammhang sinnvoll und richtig sein, es kann aber auch sicherer und klarer sein, die Blätter anzugeben.
Versuchs mal (nach Anpassen der Blattnamen) mit

Sub Umsatz_uebertragen2()
Workbooks.Open Filename:= _
"C:\Dokumente und Einstellungen\Besitzer\Eigene Dateien\Umsätze.xls"
Sheets("abc").Range("A2:N1100").Copy Destination:= _
Workbooks("Statistik.xls").Sheets("xyz").Range("A2")
ActiveWorkbook.Close
Workbooks("Statistik.xls").Activate ' nur wenn die Mappe nicht sowieso schon aktiv ist
Range("A6").Select                  ' nur wenn A6 nachher ausgewählt sein soll
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Beliebteste Forumthreads (12 Monate)

Daten aus geschlossener Datei per VBA übertragen..

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

302 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Daten aus geschlossener Datei per VBA übertragen..

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

302 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread