Microsoft Excel

Herbers Excel/VBA-Archiv

Erstes/letztes Datum zu Kürzel pro Jahr ermitteln

Betrifft: Erstes/letztes Datum zu Kürzel pro Jahr ermitteln von: Peter
Geschrieben am: 09.10.2014 16:34:27

Guten Tag

Ich habe in Spalte A ab Zeile 3 Kurzzeichen und in Spalte B Datumsangaben eingetragen. Pro Kurzzeichen gibt es pro Jahr ein oder mehrere Datumseinträge
Innerhalb eines Jahres möchte ich jeweils das erste und das letzte Datum pro Kurzzeichen in Spalte C (erstes) resp. Spalte D (letztes) mit einem X auf der jeweiligen Zeile markieren.

Mir ist nicht klar, wie ich das in eine Formel packen kann.

Wer kann mir helfen?

Gruss, Peter

https://www.herber.de/bbs/user/93065.xlsx

  

Betrifft: aber die Formelergebnisse zeigen, dass ... von: neopa C (paneo)
Geschrieben am: 09.10.2014 17:01:24

Hallo Peter,


... Du Dich händisch bei letzte etwas vertan hast ;-)

Die Formeln nach unten kopieren.

 ABCD
1  ersteletzte
2    
3ABC01.01.2012x 
4DEF01.01.2012xx
5ABC01.06.2012 x
6GHI01.12.2012x 
7GHI15.12.2012 x
8DEF01.01.2013x 
9GHI01.01.2013xx
10JKL01.01.2013xx
11ABC05.01.2013x 
12ABC13.05.2013  
13ABC01.06.2013 x
14DEF01.12.2013 x
15    

Formeln der Tabelle
ZelleFormel
C3{=IF(MIN(IF((A$3:A$99=A3)*(YEAR(B$3:B$99)=YEAR(B3)),B$3:B$99))=B3,"x","")}
D3{=IF(MAX((A$3:A$99=A3)*B$3:B$99*(YEAR(B$3:B$99)=YEAR(B3)))=B3,"x","")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4


Gruß Werner
.. , - ...


  

Betrifft: oh, das war ja in neudeutsch ;-) ... von: neopa C (paneo)
Geschrieben am: 09.10.2014 17:04:05

Hallo,

... hier vorsichtshalber noch für deutsches Excel:

 ABCD
1  ersteletzte
2    
3ABC01.01.2012x 
4DEF01.01.2012xx
5ABC01.06.2012 x
6GHI01.12.2012x 
7GHI15.12.2012 x
8DEF01.01.2013x 
9GHI01.01.2013xx
10JKL01.01.2013xx
11ABC05.01.2013x 
12ABC13.05.2013  
13ABC01.06.2013 x
14DEF01.12.2013 x
15    

Formeln der Tabelle
ZelleFormel
C3{=WENN(MIN(WENN((A$3:A$99=A3)*(JAHR(B$3:B$99)=JAHR(B3)); B$3:B$99))=B3;"x";"")}
D3{=WENN(MAX((A$3:A$99=A3)*B$3:B$99*(JAHR(B$3:B$99)=JAHR(B3)))=B3;"x";"")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Werner
.. , - ...


  

Betrifft: AW: Erstes/letztes Datum zu Kürzel pro Jahr ermitteln von: fcs
Geschrieben am: 09.10.2014 17:05:24

Hallo Peter,

Matrixformel in C3:
=WENN(B3=MIN(WENN((A3=$A$3:$A$14)*(JAHR($B$3:$B$14)=JAHR(B3));$B$3:$B$14;MAX($B$3:$B$14)));"X";" _
")

Matrixformel in D3:
=WENN(B3=MAX(WENN((A3=$A$3:$A$14)*(JAHR($B$3:$B$14)=JAHR(B3));$B$3:$B$14;MIN($B$3:$B$14)));"X";"") 
Gruß
Franz


  

Betrifft: AW: Erstes/letztes Datum zu Kürzel pro Jahr ermitteln von: Peter
Geschrieben am: 09.10.2014 22:51:05

Hallo miteinander
Vielen Dank für die Lösungen.
Beide funktionieren.
Gruß
Peter


 

Beiträge aus den Excel-Beispielen zum Thema "Erstes/letztes Datum zu Kürzel pro Jahr ermitteln"