Tabellen miteinander vergleichen

Forumthread: Tabellen miteinander vergleichen

08.05.2006 10:12:30

Fritz

Hallo erstmal schönen guten Tag,
ich habe ein Problem 2 Exceltabellen miteinander zu vergleichen, In jeder Tabelle gibt es eine Spalte Kundennummer. Eine der Tabellen enthält alle Kundennummern, die zweite Tabelle enthält nur bestimmte Kundennummern. Als Ergebniss hätte ich gerne eine Tabelle, die nur diese Kundennummern enthält die in der 2. Tabelle also der selektierten Tabelle nicht da sind.
Ich hoffe mir kann jemand helfen und ich habe mich einigermassen verständlich ausgedrückt.
Vielen Dank für eure Hilfe im Voraus
mfg
Fritz

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Tabellen miteinander vergleichen

08.05.2006 10:15:35

Jan3

Hi Fritz,
Wie sieht es denn mit einer Beispielmappe aus?
Jan

AW: Tabellen miteinander vergleichen

08.05.2006 10:24:40

Erich

Hallo Fritz,
etwa so?

alle

	A
1	KdNr
2	3
3	5
4	6
5	7
6	8
7	9

einige

	B
1	KdNr
2	3
3	7
4	8
5

Rest

	A
1	KdNr
2
3	5
4	6
5
6
7	9
8

Formeln der Tabelle

A2 : =WENN(ISTLEER(alle!A2);"";WENN(ISTNV(SVERWEIS(alle!A2;einige!B:B;1;0));alle!A2;""))
A3 : =WENN(ISTLEER(alle!A3);"";WENN(ISTNV(SVERWEIS(alle!A3;einige!B:B;1;0));alle!A3;""))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Tabellen miteinander vergleichen

08.05.2006 10:55:55

Fritz

Vielen Dank so müsste es funktionieren und genaus so war es gemeint. Jedoch befinden sich die Tabellen im selben Arbeitsblatt und eins verstehe ich noch nicht genau was meinst du mit A2 bzw. A3, besser gesagt wo muss ich die Formel eintragen.
Vielen Dank nochmals
Fritz

AW: Tabellen miteinander vergleichen

08.05.2006 11:10:53

Fritz

Hier noch eine Beispieldatei zum besseren Verständniss
https://www.herber.de/bbs/user/33412.xls

AW: Tabellen miteinander vergleichen

HermannZ

Hallo Fritz;
~f~
trage in M5 folgende Formel ein;
{=INDEX(A:A;KKLEINSTE(WENN($A$5:$A$22$G$5:$G$22;ZEILE($5:$22));ZEILE(A1));1)}
Formel nach rechts und nach unten kopieren.
Hinweis; geschweifte klammern nicht eingeben sondern Formel mit Shift-Strg-Enter abschliessen.
gruß hermann

AW: Tabellen miteinander vergleichen

08.05.2006 12:10:33

Erich

Hallo Fritz,
oder so (mit einer Hilfsspalte L):

Tabelle2

	L	M	N	O	P
4	Hilf	Nummer	Name	Vorname	Strasse
5	10026	10026	Ennis	Helga	Michaelstraße 1
6	10059	10059	Karl	Annemarie	Kufsteiner Straße 121
7	10069	10069	Kreipl	Nelly	Bahnhofstraße 38
8	10294	10294	Schmid	Frieda	Schwarzenbergstr. 7b
9		10532	Schmidt	Helene	Pangerstr. 12
10		71280	Berghammer		Achentalstr. 12
11	10532	71359	Hernandez	Renate	Neubeurer Str. 14
12	71280	71545	Strauß	Friderike	Innstr.9
13	71359	71594	Wohlschlager	Magda	Geisenkamm 29
14	71545	715443	Zeiselmeier	Christine	Inntalstr.2
15	71594	715593	Ruckert	Ilse	Steinstr. 15
16	715443	715782	Neumann	Astrid	Schäfersiedlung 15
17	715593	715877	Lechner	Monika	Gingerting 28
18	715782	715960	Meister	Jutta	Heimgarten 8
19	715877	716056	Marchfelder	Thia	Hauptstr. 3
20	715960	716281	Landratsamt		Wittelsbacherstr.53
21	716056
22	716281

Formeln der Tabelle

L5 : =WENN(ISTLEER($A5);"";WENN(ISTNV(SVERWEIS($A5;$G:$J;1;FALSCH));A5;""))
M5 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(L$5:L$100;VERGLEICH(ZEILE(A5)-5;ZÄHLENWENN($L$5:$L$100;"<"&$L$5:$L$100);0)))}
N5 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(B$5:B$100;VERGLEICH($M5;$L$5:$L$100);0)&"")}
O5 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(C$5:C$100;VERGLEICH($M5;$L$5:$L$100);0)&"")}
P5 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(D$5:D$100;VERGLEICH($M5;$L$5:$L$100);0)&"")}
L6 : =WENN(ISTLEER($A6);"";WENN(ISTNV(SVERWEIS($A6;$G:$J;1;FALSCH));A6;""))
M6 : {=WENN(ZEILE()-4>ANZAHL(L$5:L$100);"";INDEX(L$5:L$100;VERGLEICH(ZEILE(A6)-5;ZÄHLENWENN(L$5:L$100;"<"&L$5:L$100);0)))}
N6 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(B$5:B$100;VERGLEICH($M6;$L$5:$L$100);0)&"")}
O6 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(C$5:C$100;VERGLEICH($M6;$L$5:$L$100);0)&"")}
P6 : {=WENN(ZEILE()-4>ANZAHL($L$5:$L$100);"";INDEX(D$5:D$100;VERGLEICH($M6;$L$5:$L$100);0)&"")}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Tabellen miteinander vergleichen

09.05.2006 08:51:35

Fritz

Hallo Erich G.
vielen Dank für die Hilfe, das funktioniert soweit, ich brauche aber nur die erste Formel zu verwenden in einer Hilfsspalte neben der kompletten Tabelle, später filtere ich nur aus.
Vielen Dank hast mir sehr geholfen.
mfg Fritz

Beliebteste Forumthreads (12 Monate)

Forumthread: Tabellen miteinander vergleichen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Tabellen miteinander vergleichen

Forumthread: Tabellen miteinander vergleichen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread