Dateinamen mit Zellinhalt vergleichen

Forumthread: Dateinamen mit Zellinhalt vergleichen

27.08.2018 13:36:39

earlycon

Hallo zusammen,
ich habe eine Tabelle in der Bezeichnungen stehen, wie etwa:
- Steuerungs- und Führungsinstrumente
Die entsprechenden Dateien hierzu heißen z.B.
- Begleitdokument Steuerungs- und Führungsinstrumente.pdf und
- BE_Steuerungs_und_Fuehrungsinstrumente_komfort.xls
Oder z.B.:
- Atteststühle/Bürodrehstühle mit senkrecht zweigeteilter Rückenlehne
Und die Dateien:
- be_atteststuehle_anlage.pdf
- be_atteststuehle_standard.xls
Unglücklicher Weise werden die Dateinamen teilweise mit Unterstrich und teilweise mit Vokalen und/oder Umlauten geschrieben und dürfen nicht umbenannt werden.
Über
- Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
fange ich den Doppelclick ab und mit
- With Application.FileDialog(msoFileDialogFilePicker)
öffnet sich das Dateiauswahlfenster.
Ich suche jetzt eine Möglichkeit, die Bezeichnung in der Tabelle mit den Dateinamen zu vergleichen und das alle Dateien die ungefähr bzw. auch nur teilweise der Bezeichnung entsprechen angezeigt werden. Ob das überhaupt geht in dem "Datei-Öffnen"-Fenster und was man als Kriterium nehmen soll weiß ich jedoch auch nicht.
Falls jemand versteht, was ich eigentlich möchte und eine Idee hat, wäre ich für eine Rückmeldung sehr dankbar.
Gruß Stefan

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Dateinamen mit Zellinhalt vergleichen

28.08.2018 00:30:09

fcs
AW: Dateinamen mit Zellinhalt vergleichen

29.08.2018 06:55:23

earlycon

AW: Dateinamen mit Zellinhalt vergleichen

28.08.2018 00:30:09

fcs

Hallo Stefan,
in der folgenden Variante wird das 1. Wort in der angeklickten Zelle als Suchtext für die Dateinamen verwendet.
Gruß
Franz

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim strFile As String, varFile
strFile = "*" & fncWort1(Target.Text) & "*"
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Bitte gewünschte Datei(en) auswählen"
.InitialFileName = strFile
.AllowMultiSelect = True
If .Show = -1 Then
For Each varFile In .SelectedItems
MsgBox "gewählter Dateiename: " & varFile
Next
End If
End With
Cancel = True
End Sub
Function fncWort1(ByVal sText As String)
'1. Wort im Text zurückgeben
Dim sNeu As String
'Umlaute ersetzen
sNeu = LCase(sText)
sNeu = VBA.Replace(sNeu, "ä", "ae")
sNeu = VBA.Replace(sNeu, "ö", "oe")
sNeu = VBA.Replace(sNeu, "ü", "ue")
sNeu = VBA.Replace(sNeu, "ß", "ss")
'Trennzeichen ersetzen
sNeu = VBA.Replace(sNeu, "-", " ")
sNeu = VBA.Replace(sNeu, "_", " ")
sNeu = VBA.Replace(sNeu, ",", " ")
sNeu = VBA.Replace(sNeu, ";", " ")
sNeu = VBA.Replace(sNeu, ".", " ")
sNeu = VBA.Replace(sNeu, "/", " ")
sNeu = VBA.Replace(sNeu, "\", " ")
sNeu = Trim(sNeu)
'1. Wort als Suchtext festlegen
If sNeu = "" Then
fncWort1 = ""
Else
fncWort1 = Left(sNeu, InStr(1, sNeu, " ") - 1)
End If
End Function

AW: Dateinamen mit Zellinhalt vergleichen

29.08.2018 06:55:23

earlycon

Guten Morgen Franz,
sorry, habe Deinen Beitrag erst später gelesen.
Vielen Dank für Deine Rückmeldung, man lernt immer wieder dazu... :-)
Geniale Idee, das erste Wort zu analysieren, funktioniert prima.
Viele Grüße
Stefan

Beliebteste Forumthreads (12 Monate)

Dateinamen mit Zellinhalt vergleichen

Forumthread: Dateinamen mit Zellinhalt vergleichen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread