Zugriff auf geschlossene Dateien

Oliver · 2006-08-23T16:28:29+00:00

Hallo zusammen, ich möchte mittels einer Formel auf eine geschlossene Excel-Datei zugreifen. Das ist grundsätzlich kein größeres Problem: ='U:\Temp\[Test.xls]Tabelle1'!A1 Schwierig wird es dann, wenn der Pfad bzw. Projektname aus anderen Zelleninhalten zusammengesetzt werden soll. Dies funktioniert weder mit noch ohne INDIREKT: =INDIREKT("'U:\Temp\[" & B3 & "]Deckblatt'!A1") Auch der gelesene Trick, das erste Hochkomma mittels GLÄTTEN zu integrieren, hilft nichts: =INDIREKT(GLÄTTEN(" ' ") & "U:\Temp\[" & B3 & "]Deckblatt'!A1") Habt ihr eine Idee oder gibt es hierfür keine Lösung (ohne VBA)? Danke Oliver

Hallo,
ich habe genau das gleiche Problem mit dem Indirekt-Öffnen (gut zu wissen, dass das nur mit bereits geöffneten Dateien geht) und würde gerne den gleichen Code verwenden.
Leider habe ich absolut keine Ahnung von Makros.
Kann mir einer sagen, wo (oder ob) in dem Makro die Zellbereiche definiert werden, die kopiert werden und aus welchem Tabellenblatt die Zellen kopiert werden?
Ich möchte folgendes machen:
- Ich habe ca. 30 identisch aufgebaute Excel-Dateien in 30 Unterordnern eines Verzeichnisses.
- In jeder Datei habe ich ein Blatt mit Messwerten (Zellbereich A17 bis G35, in diesem Zellbereich sind aber auch Überschriften u.ä. enthalten macht aber nix wenn das mitkopiert wird).
- In meinem Hauptverzeichnis will ich eine Übersichts-Excel mit einem Tabellenblatt in dem ich dynamisch die Messwerte in einer Tabelle darstellen will. Ich brauche eine Funktion/Makro, das mir die Messwerte aus den (ungeöffneten) Unterordnern in meine Übersichts-Excel kopiert.
- Ich habe eine Dropdownliste mit allen Dateien aus denen ich wählen kann, und mir eine Funktion gebastelt, die mir einen Textstring mit dem Pfad zu Datei und zum gewünschten Blatt liefert, aber der Indirekt-Befehl kann die Datei ja nicht öffnen.
Könnte man ein Makro machen, das alles für mich erledigt, jedes Mal, wenn ich eine Quelle aus der Dropdownliste gewählt habe?
Oder (vielleicht noch viel einfacher) ein Makro (durch einen Aktualisieren-Button gestartet), das die Datei öffnet, den Indirekt-Befehl ausführt und die Datei wieder schließt. Damit der Indirekt-Befehl die Daten rüberkopiert während die Datei geöffnet war (wenn das funktioniert?)
Sorry für den langen Text, aber ich wollte halbwegs eindeutig sein.
Vielen Dank für alle Antworten.
David

Hallo David,
versuch's vielleicht mal so:
- in A1 schreibe den Pfad zur Quelldatei, z.B. E:\TEST\
- in A2 schreibe den Namen der Quelldatei, z.B. source.xls
- benutze in Deinen Formeln (weiterhin) Indirekt mit A2, z.B.C1: =INDIREKT("[" & A2 & "]Tabelle1!$A$1" )
- erstelle einen Button aus Steuerelemente und gib ihm den Namen cmdUpdate
- tu sowas in das Klassenmodul Deiner Tabelle
Wenn es 'vollautomatisch' gehen soll, nimm zusätzlich ein Worksheet_Change auf, s.u., sonst wirf das einfach raus. Das Teil öffnet die Quelldatei, berechnet neu und schließt sie dann wieder. Könnte eigentlich ausreichen.
HTH, Bernd
--
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A1:A2")) Is Nothing Then
        Application.EnableEvents = False
        Call cmdUpdate_Click
        Application.EnableEvents = True
    End If
End Sub

Private Sub cmdUpdate_Click()
    Dim strDataFile As String, strDataPath As String

    strDataPath = Range("A1")
    strDataFile = Range("A2")
    If strDataFile <> "" And strDataPath <> "" Then
        If Not WorkBookExists(strDataFile) Then
            If Right(strDataPath, 1) <> "\" Then strDataPath = strDataPath & "\"
            If Dir(strDataPath & strDataFile) <> "" Then
                Workbooks.Open strDataPath & strDataFile, ReadOnly:=True
                Me.Calculate
                ActiveWorkbook.Close False
            Else
                MsgBox "Datei nicht gefunden", vbCritical, strDataPath & strDataFile
            End If
        End If
    End If
End Sub

Private Function WorkBookExists(ByVal strName As String) As Boolean
    Dim wb As Workbook

    strName = UCase(strName)
    WorkBookExists = True

    For Each wb In Workbooks
        If UCase(wb.Name) = strName Then Exit Function
    Next
    WorkBookExists = False
End Function

Forumthread: Zugriff auf geschlossene Dateien

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Zugriff auf geschlossene Excel-Dateien

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)