Frage zum zugriff auf nicht gespeicherte Datei...!

Hallo Excelfreunde,
ich exportiere eine CSV Datei. Zumindest steht als Hinweis wenn ich mit der Maus über den Button ziehe Daten in CSV exportieren was ich dann bekomme ist eine Exceltabelle. Aus dieser Tabelle würde ich gerne gewisse Spalten ab Zeile 14 in eine andere Mappe übertragen nur ist in der Quelldatei=CSV das Datum in Spalte A absteigend sortiert und in der ZielTabelle= Kasse soll es aufsteigend sortiert in die nächste freie Zeile andere Spalte geschrieben werden.
Ich will die CSV Datei nicht Speichern und daher meine Frage ob es überhaupt möglich ist auf diese per VBA zuzugreifen? Wenn dies gehen sollte anbei ein Beispiel wie das ganze ausschaut.
Tabelle1

	A	B	C	D	E	F	G	H	I	J
1	Tabelle1=Umsaetze_01234567_02.06.2012
2
3	Umsaetze_01234567_ ist fix ändert sich nur immer das Datum was dem Heute entspricht.
4
5
6
7
8
9
10
11
12
13	Buchungstag	Value	Auftraggeber	Empfänger	Text	Text	Text	Text	Umsätze
14	01.06.2012	01.06.2012	Text1	Text a					100	s
15	01.06.2012	01.06.2012	Text2	Text b					200	s
16	30.05.2012	30.05.2012	Text3	Text c					90	h
17	29.05.2012	29.05.2012	Text4	Text d					500	s
18	27.05.2012	27.05.2012	Text5	Text e					1500	h
19
20	Die Anzahl der Zeilen ist unterschiedlich dann kommt noch ein Text.
21	Die CSV Datei ist absteigend sortiert und soll wie in meiner Beispielsmappe in Tabelle Kasse eingetragen werden.
22	Was geprüft werden sollte, ist ob Datum,Empfänger und der Umsatz nicht schon in Tabelle Kosten vorhanden ist.
23

Kasse

	A	B	C	D	E	F	G	H	I
1	Firma	Kosten	Einnahmen	Ausgaben	Text	Text	Datum
2		Text e	1500				27.05.2012
3		Text d		500			29.05.2012		Aus dieser Datei sollen die aus der CSV Datei geholt werden.
4		Text c	90				30.05.2012
5		Text b		200			01.06.2012
6		Text a		100			01.06.2012

Tabellendarstellung in Foren Version 5.37

Ich habe im Internet nichts Ähnliches gefunden für das Übertragen und Umsortieren in andere Tabelle. Auch weil ich verwirrt bin schaut aus wie Exceltabelle und beim Schließen wird ich gefragt ob ich die CSV Datei Speichern möchte.
Aber erst die Frage ob es überhaupt geht und dann zu meinem anliegen.
Gruß Thomas aus Stuttgart

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Thomas,
eine CSV-Datei ist nichts anderes als eine Textdatei, in die die Daten nach einem vorgegeben Schema geschrieben werden. Wichtiges Kriterium ist dabei das Zeichen zum Trennen Datenfeldern/Spalten. In deutschen Anwendungen meist ein ";" in US-Anwendungen meist "," . Das ";" hat sich hier eingebürgert, um es vom Dezimaltrennzeichen unterscheiden zu können.
Excel ist so konfiguriert, das es die in CSV-Dateien enthaltenen Daten beim Öffnen der Datei automatisch als Exceltabelle darstellt. Beim Öffnen von CSV-Datei innerhalb von VBA kann es Probleme geben, da VBA erst einmal davon ausgeht, dass als Trennzeichen ein Komma verwendet wird.
Nachfolgnénd ein Makro, das den Import der Daten ausführen sollte. Beim Start des Makros muss die Datei mit dem Blatt "Kasse" die aktive Arbeitsmappe sein.
Gruß
Franz

'Erstellt mit Office 2010 professional, Excel2010, WindowsVista, alles Deutsch
Sub KassendatenHolen()
Dim wbKasse As Workbook, wksKasse As Worksheet, varAuswahl As Variant
Dim wbCSV As Workbook, wksCSV As Worksheet
Dim ZeileZiel As Long
Dim ZeileCSV As Long, ZeileCSV_1 As Long, ZeileCSV_L As Long
'Objekte in Kassen-Datei setzen
Set wbKasse = ActiveWorkbook
Set wksKasse = wbKasse.Worksheets("Kasse")
With wksKasse
'letzte Zeile in Spalte G (Datum) mit Daten
ZeileZiel = .Cells(.Rows.Count, 7).End(xlUp).Row
End With
'CSV-Datei wählen/öffnen
With Application.FileDialog(msoFileDialogOpen)
.Title = "Bitte CSV-Datei öffnen"
.InitialView = msoFileDialogViewDetails
.InitialFileName = "*.csv"
If .Show = -1 Then
varAuswahl = .SelectedItems(1)
Set wbCSV = Workbooks.Open(Filename:=varAuswahl, ReadOnly:=True, Local:=True)
Set wksCSV = wbCSV.Worksheets(1)
ZeileCSV_1 = 14
ZeileCSV_L = ZeileCSV_1
With wksCSV
'letzte Zeile mit Datum in Spalte A suchen
Do
.Cells(ZeileCSV_L, 1).Value = CDate(.Cells(ZeileCSV_L, 1).Text)
ZeileCSV_L = ZeileCSV_L + 1
Loop Until Not IsDate(.Cells(ZeileCSV_L + 1, 1).Text)
'Sortieren nach Datum
If ZeileCSV_L > ZeileCSV_1 Then
With .Range(.Rows(ZeileCSV_1 - 1), .Rows(ZeileCSV_L))
.Sort key1:=.Range("A1"), order1:=xlAscending, Header:=xlYes
End With
End If
'Daten übertragen
For ZeileCSV = ZeileCSV_1 To ZeileCSV_L
ZeileZiel = ZeileZiel + 1
'Datum - Spalte A nach Spalte G
wksKasse.Cells(ZeileZiel, 7).Value = .Cells(ZeileCSV, 1).Value
'Kosten - Spalte D nach Spalte B
wksKasse.Cells(ZeileZiel, 2).Value = .Cells(ZeileCSV, 4).Value
'Einnahmen,Ausgaben
If LCase(.Cells(ZeileCSV, 10)) = "s" Then
wksKasse.Cells(ZeileZiel, 4).Value = .Cells(ZeileCSV, 9).Value
ElseIf LCase(.Cells(ZeileCSV, 10)) = "h" Then
wksKasse.Cells(ZeileZiel, 3).Value = .Cells(ZeileCSV, 9).Value
End If
Next
End With
wbCSV.Close savechanges:=False
End If
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Frage zum zugriff auf nicht gespeicherte Datei...!

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

303 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Frage zum zugriff auf nicht gespeicherte Datei...!

13 Beiträge zum Forumthread Beiträge zu diesem Forumthread

303 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread