Datenüberprüfung mittels VBA

Hallo liebes Forum,
ich hab ein Problem bei welchem ich hoffe das ihr mir weiterhelfen könnt....
Ich habe eine Datei mit zwei Tabellenblättern. Das erste Tabellenblatt weißt in Spalte A Mitarbeiter auf und die einzelnen Wochentage. Das zweite Tabellenblatt die jeweiligen Stationen für die jeder Mitarbeiter qualifiziert ist.
Jetzt möchte ich mittels VBA Code erreichen, dass in der jeweiligen Mitarbeiterzeile im Tabellenblatt 1 nur die Station auswählbar ist, für die der Mitarbeiter qualifiziert ist.
Also dürfte bei Dieter in den Spalten Mo-Fr nur eine 3 oder 4 einsetzbar sein.
Ich kann die Anforderung leider nicht mit Excel Datenüberprüfung durchführen, da immer wieder Zeilen entfernt und neu hinzugefügt werden und in Folge dessen die Formeln zerstört werden.
Hat jemand eine Idee ob und wenn wie dies mit VBA durchführbar ist.
https://www.herber.de/bbs/user/134856.xlsx
Danke im Voraus für eure Mühe und Grüße!

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo,
Hajo einfach ignorieren, der antwortet zu 90% mit unsinnigen Textbausteinen.
In das Modul der Tabelle1:

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim objCell As Range
    Dim lngColumn As Long, lngRow As Long
    Dim strTemp As String
    If Target.Count = 1 Then
        If Not Intersect(Target, Range("B4:F12")) Is Nothing Then
            Call Target.Validation.Delete
            Set objCell = Tabelle2.Columns(1).Find(What:=Cells(Target.Row, 1).Text, _
                LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=False)
            If Not objCell Is Nothing Then
                lngRow = objCell.Row
                With Tabelle2
                    For lngColumn = 2 To .Cells(lngRow, .Columns.Count).End(xlToLeft).Column
                        With .Cells(lngRow, lngColumn)
                            If IsNumeric(.Text) Then strTemp = strTemp & "," & .Text
                        End With
                    Next
                End With
                If strTemp <> vbNullString Then
                    With Target.Validation
                        Call .Add(Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
                            Operator:=xlBetween, Formula1:=Mid$(strTemp, 2))
                        .InCellDropdown = True
                    End With
                End If
            End If
        End If
    End If
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread