Index und Vergleich?

Bild

Betrifft: Index und Vergleich?
von: yummi
Geschrieben am: 06.07.2015 16:25:55

Hallo Zusammen,
ich hoffe ihr könntm mir weiter helfen. Ich habe eine Beispieldatei beigefügt.
https://www.herber.de/bbs/user/98668.xlsx
Ich möchte automatisch einen Wert aus Tabelle 2 darstellen und zwar den Wert aus Spalte K in der der Name und die Eigenschaft übereinstimmt.
Ich denke ich muss das mit Index, Vergleich und einer und- verknüfung machen oder denke ich zu kompliziert?
Vielen Dank für Eure Hilfe
yummi

Bild

Betrifft: AW: Index und Vergleich?
von: Andreas Emmert
Geschrieben am: 06.07.2015 16:40:35
Hallo yummi,
das kannst du mit zwei Formeln alternativ lösen: nimm in Zelle B5 entweder
Formel 1:
=SUMMEWENNS(Tabelle2!$K$3:$K$50;Tabelle2!$B$3:$B$50;Tabelle1!B$4;Tabelle2!$D$3:$D$50;Tabelle1!$A5)
Formel 2:
=SUMMENPRODUKT(Tabelle2!$K$3:$K$50;--(Tabelle2!$B$3:$B$50=Tabelle1!B$4); --(Tabelle2!$D$3:$D$50=Tabelle1!$A5))
rein und kopiere sie nach rechts und unten entsprechend.
viele Grüße
Andreas

Bild

Betrifft: AW: Index und Vergleich?
von: yummi
Geschrieben am: 06.07.2015 16:54:40
Hallo Andreas,
vielen Dank.
Ich werde das mal in die richitge Tabelle einbaune und dann mal schauen, welche von beiden performanter ist.
In der Beispieldatei funktioniert das auf jeden Fall super
Danke
yummi

Bild

Betrifft: AW: Index und Vergleich?
von: SF
Geschrieben am: 06.07.2015 16:43:20
Hola,
schau mal hier:
http://www.excelformeln.de/formeln.html?welcher=30
Gruß,
steve1da

Bild

Betrifft: AW: Index und Vergleich?
von: yummi
Geschrieben am: 06.07.2015 16:56:06
Hallo steve1da,
danke für den Hinweis, ich denke aber das die SVerweis Funktion in der richitgien Datei zu langsam sein wird, ich werde es auf jeden fall ausprobieren
Danke
yummi

Bild

Betrifft: AW: Index und Vergleich?
von: SF
Geschrieben am: 06.07.2015 16:58:07
Hola,
da kommt nicht ein Sverweis drin vor.
Gruß,
steve1da

Bild

Betrifft: anstelle VERGLEICH() nutze AGGREGAT() ...
von: der neopa C
Geschrieben am: 06.07.2015 16:48:37
Hallo yummi,
... in B5: =WENNFEHLER(INDEX(Tabelle2!$K:$K;AGGREGAT(15;6;ZEILE(A$1:A$99)/(Tabelle2!$B$1:$B$99=B$4)/(Tabelle2!$D$1:$D$99=$A5);1));"") und Formel nach rechts und unten kopieren.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: anstelle VERGLEICH() nutze AGGREGAT() ...
von: yummi
Geschrieben am: 06.07.2015 16:57:11
Hallo Werner,
auch dir ein Dankeschön. Ich werde auch diese VErsion ausprobieren und mal schauen welche am schnellsten ist.
Danke
yummi

Bild

Betrifft: am schnellsten dürfte SUMMEWENNS() sein ...
von: der neopa C
Geschrieben am: 06.07.2015 17:17:28
Hallo yummi,
... doch ich nutze ungern für derartige Lösungen SUMME...(9 oder ZÄHLEN...(), weil nicht wirklich 100% ausgeschlossen werden kann, das die jeweilige Kombination nur einmal vorkommt und dann kommt es zu einer fehlerhaften Ausgabe.
In den Vorschlägen wie sie Rudi und ich aufgezeigt haben, ist das egal. In dem Fall wird immer nur der erste zutreffende Wert ermittelt.
Gruß Werner
.. , - ...

Bild

Betrifft: AW: Index und Vergleich?
von: Rudi Maintaire
Geschrieben am: 06.07.2015 16:48:44
Hallo,
als Matrixformel
{=INDEX(Tabelle2!$K$3:$K$50;VERGLEICH(B$4&$A5;Tabelle2!$B$3:$B$50&Tabelle2!$D$3:$D$50;))}
oder ohne Matrix
=INDEX(Tabelle2!$K:$K;VERGLEICH($A5;INDEX(Tabelle2!$D:$D;VERGLEICH(B$4;Tabelle2!$B:$B;)) :Tabelle2!$D$1000;)+VERGLEICH(B$4;Tabelle2!$B:$B;)-1)
Gruß
Rudi

Bild

Betrifft: AW: Index und Vergleich?
von: yummi
Geschrieben am: 06.07.2015 16:58:30
Hallo Rudi,
auch dir ein Dankeschön, wobei ich glaube, dass die Matrixformel von allen am meisten Ressourcen brauchen wird. ich werde mal alle Vorschläge ausprobieren
Danke
yummi

Bild

Betrifft: AW: Schnellste Formellösung
von: Daniel
Geschrieben am: 06.07.2015 18:00:36
Hi
wenn du eine Schnelle Lösung für grössere Datenmengen suchst, musst du so vorgehen:
1. Fasste in der Tabelle2 Person und Eigenschaft zu einem Suchbegriff zusammen, bspw mit der Formel in Tabelle2!A3:
=B3&"-"&D3
2. sortiere die Tabelle2 nach diesen zusammengefassten Begriff aufsteigend.
4. Richte die Tabelle2 so ein, dass die Zeile 1 die Überschriftenzeile ist und die Daten ab Zeile 2 beginnen (dann kannst du im folgnden SVerweis mit offenen Zellbezügen auf ganze Spalten arbeiten, wenn du die Tabelle anders platzierst, musst du die Zellbezüge auf diese Tabelle mit ZelleObenLink-ZelleUntenRechts angeben).
5. in Tabelle1 kommt folgende Formel in die oberst linke Zelle B5:
=Wenn(Sverweis(B$4&"-"&$A5;Tabelle2!A:A;1;wahr)=B$4&"-"&$A5;SVerweis(B$4&"-"&$A5;Tabelle2!$A:$K;11;wahr);"")
durch die Zusammenfassung der Suchbegriffe zu einem Wert vereinfachst du die Formeln, weil du mit dem einfachen SVerweis arbeiten kannst.
die Sortiertung nach dem Suchbegriff erlaubt die Verwendung des schnellen SVerweises mit 4. Parameter = Wahr
Beachte hierbei jedoch: wenn in Tabelle2 eine Kombination aus Person und Eigenschaft mehrfach vorkommt, dann wird der SVerweis nicht das erste, sondern das letzte Vorkommen dieser Kombination als Ergebnis verwenden.
je nach dem ob du in diesem Fall den grösseren oder kleineren Eigenschaftswert sehen willst, musst du die Spalte K in die Sortierung mit einbeziehen.
Gruß Daniel

Bild

Betrifft: Eine Formel ist genau dann am Schnellsten, ...
von: Luc:-?
Geschrieben am: 07.07.2015 04:27:32
…wenn sie nur das berechnet, was unbedingt erforderlich ist, wobei das Zusammen­suchen(­Müssen) von Werten auch auf Berechnungen basiert, die im Falle einer entsprechend vorgebbaren FktsArgumen­tierung entfallen können.
Das ist das ganze „Geheimnis“ hinter der Wirkungsweise solcher Fktt, egal ob XlStandard oder selbst­pgmmierte UDF!
Morrn, Luc :-?

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Index und Vergleich?"