Mehrer Exceltabellen öffnen und bearbeiten

Hallo Zusammen,
ich bin ein leider ein absoluter VBA Anfänger und ich hoffe ihr könnt mir weiterhelfen.
Aktuell habe ich folgendes Problem.
In von mir erstellten Excellisten sind Dateipfade in diversen Spalten/Zeilen hinterlegt. Leider hat sich diese Dateipfad nun verändert und müsste bei mehr als 1000 Excellisten dies ändern.
Um nicht jede Liste einzeln aufzurufen und zu berabeiten hoffe ich dass es eine möglichkeit gibt per Makro/VBA dies zu bearbeiten.
Im klartext heisst das ich benötige folgendes für mein Skrip.
Makro Starten - Alle .xls und .xlsx dateien in einem Pfad durchsuchen C:\Test - Es soll Test1 in Test2 umbenannt werden.
Ich hoffe sehr soetwas gibt es, ansonsten habe ich lange Nächte vor mir :D
Vielen dank schonmal im Vorraus für eure Unterstützung.
Liebe Grüße
Mischa

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Mischa,
teste mal:

Option Explicit

Public Sub Test1()

    Const FOLDER_PATH As String = "C:\Test\"
    Const SEARCH_TERM As String = "Test1"
    Const SWAP_TERM As String = "Test2"

    Dim strFilname As String, strFirstAddress As String
    Dim objWorkbook As Workbook
    Dim objWorksheet As Worksheet
    Dim enmAutomationSecurity As MsoAutomationSecurity

    On Error Resume Next

    With Application
        enmAutomationSecurity = .AutomationSecurity
        .AutomationSecurity = msoAutomationSecurityForceDisable
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    strFilname = Dir$(FOLDER_PATH & "*.xls*")

    Do Until strFilname = vbNullString

        Set objWorkbook = Workbooks.Open(Filename:=FOLDER_PATH & strFilname)

        For Each objWorksheet In objWorkbook.Worksheets

            Call objWorksheet.Cells.Replace(What:=SEARCH_TERM, _
                Replacement:=SWAP_TERM, LookAt:=xlPart, MatchCase:=True)

        Next

        Call objWorkbook.Close(SaveChanges:=True)

        strFilname = Dir$
    Loop

    With Application
        .AutomationSecurity = enmAutomationSecurity
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Mehrer Exceltabellen öffnen und bearbeiten

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

193 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Mehrer Exceltabellen öffnen und bearbeiten

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

193 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread