AW: Bereich als E-Mail versenden
07.09.2022 23:22:49
volti
Hallo Ralf,
in dem von Oberschlumpf referenzierten Beispielcode wird per HTML eine Tabelle nachgebaut. Kann man machen, ist dann aber auch nicht weiter formatiert.
Um einen Bereich als Bereich oder einen Bereich als Bild in eine eMail zu bekommen, gibt es mehrere Methode. Bei Google-Suchen wirst Du sehr oft die Methode über RangeToHTML finden. Klappt ja auch sehr gut.
Ich verwende eher die Copy-Methode. Hier mal zwei Beispiele für einen Bereich als Bereich-Kopie, bei der der Bereich nicht als Bild sondern eben als Tabelle eingefügt wird.
Da Du zu den restlichen Parametern keine Angabe gemacht hast, werden diese Parameter auch aus einem Blatt übernommen. Kann man auch anders machen.
Code:
Private Sub Mail_BereichalsBereich_Word1()
' Sendet Mail mit integriertem Bereich als Bereich mit Signatur
Dim WSh1 As Worksheet, WSh2 As Worksheet
Dim sMailtext As String, sBer As String
sBer = "AS1:AV12" ' Kopierbereich
Set WSh1 = ThisWorkbook.Sheets("Tabelle1") ' Blatt mit Maildaten
Set WSh2 = ThisWorkbook.Sheets("Tabelle2") ' Datenblatt
WSh2.range(sBer).Copy ' Bereich kopieren
With CreateObject("Outlook.Application").CreateItem(0)
.BodyFormat = 2 ' 2=HTML-Format, 3=Richtext
.Subject = WSh1.range("A2").Value ' Betreff
.To = WSh1.range("A3").Value ' Empfänger
.CC = WSh1.range("A4").Value ' Kopie
sMailtext = WSh1.range("A5").Value & vbLf
.GetInspector ' Signatur holen
.htmlbody = Replace(sMailtext, vbLf, "<br>") & .htmlbody
.Display
With .GetInspector.WordEditor.Application.Selection
.start = Len(sMailtext) + 1
.Paste ' Bereich in Mail einfügen
End With
End With
End Sub
Private Sub Mail_BereichalsBereich_Word2()
' Sendet Mail mit integriertem Bereich als Bereich ohne Signatur
Dim WSh1 As Worksheet, WSh2 As Worksheet
Dim sBer As String
sBer = "AS1:AV12" ' Kopierbereich
Set WSh1 = ThisWorkbook.Sheets("Tabelle1") ' Blatt mit Maildaten
Set WSh2 = ThisWorkbook.Sheets("Tabelle2") ' Datenblatt
WSh2.range(sBer).Copy ' Bereich kopieren
With CreateObject("Outlook.Application").CreateItem(0)
.BodyFormat = 2 ' 2=HTML-Format
.Subject = WSh1.range("A2").Value ' Betreff
.To = WSh1.range("A3").Value ' Empfänger
.CC = WSh1.range("A4").Value ' Kopie
.Display
.GetInspector.WordEditor.range.Paste ' Bereich in Mail einfügen
End With
End Sub
_________________________
viele Grüße aus Freigericht 😊
Karl-Heinz