Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zelleninhalt löschen mit for Schleife

Zelleninhalt löschen mit for Schleife
13.02.2013 13:53:27
Tobiax
Hallo!
Es soll Zeile für Zeile (51-66) überprüft werden, ob in einer der Zellen in den Spalten R-W ein "e" oder "E" steht.
Wenn ja, dann soll der Inhalt der Zeile von D-W gelöscht werden.
Mit der for Schleife und doppelter Bedingung bekomme ich das leider nicht hin.
Tobiax...

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Zelleninhalt löschen mit for Schleife
13.02.2013 13:58:43
Rudi
Hallo,
Sub aaa()
Dim i As Long
For i = 51 To 66
If WorksheetFunction.CountIf(Cells(i, 18).Resize(, 6), "e") > 0 Then
Cells(i, 4).Resize(, 20).ClearContents
End If
Next
End Sub
Gruß
Rudi

AW: Zelleninhalt löschen mit for Schleife
13.02.2013 16:09:31
Tobiax
DANKE !!!!

AW: Zelleninhalt löschen mit for Schleife
13.02.2013 14:03:18
Klaus
Hi,
nicht optimiert, aber funktional:
Option Explicit
Sub EsuchenUndZellenLoeschen()
Dim lRowFirst As Long
Dim lRowLast As Long
Dim iColCheckFirst As Integer
Dim iColCheckLast As Integer
Dim iColDeleteFirst As Integer
Dim iColDeleteLast As Integer
Dim rBereich As Range
Dim sSearchA As String
Dim sSearchB As String
lRowFirst = 51      'von hier
lRowLast = 66       'bis da
iColCheckFirst = 18 'Spalte R (=18)
iColCheckLast = 23  'Spalte W (=23)
iColDeleteFirst = 4 'Spalte D (=4)
iColDeleteLast = 23 'Spalte W (=23)
sSearchA = "E"      'suche dies
sSearchB = "e"      'oder suche das
'klein / gross hätte man auch anders lösen können, aber vielleicht suchst du ja morgen nach X  _
und y ...
With ActiveSheet
For Each rBereich In .Range(.Cells(lRowFirst, iColCheckFirst), .Cells(lRowLast,  _
iColCheckLast))
'rBereich.Select
If rBereich.Value = sSearchA Or rBereich.Value = sSearchB Then
.Range(.Cells(rBereich.Row, iColDeleteFirst), .Cells(rBereich.Row, iColDeleteLast)). _
ClearContents
End If
Next rBereich
End With
End Sub
Grüße,
Klaus M.vdT.

Anzeige
AW: Zelleninhalt löschen mit for Schleife
13.02.2013 15:25:00
fcs
Hallo Tobiax
und noch eine kleine Variante, nachdem ich die Frage hier erst im Nachlauf bemerkt hab.
Gruß
Franz
Sub CheckZellen()
Dim wks As Worksheet, Spalte As Long, Zeile As Long
Set wks = ActiveSheet
With wks
For Zeile = 51 To 56
For Spalte = 18 To 23 'R bis W
Select Case .Cells(Zeile, Spalte).Value
Case "e", "E"
'D bis W löschen
.Range(.Cells(Zeile, 4), .Cells(Zeile, 23)).ClearContents
exit for
Case Else
'do nothing
End Select
Next
Next
End With
End Sub

Anzeige

307 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige