Bestimmte Werte aus TXT Datei in Zellen schreiben

Forumthread: Bestimmte Werte aus TXT Datei in Zellen schreiben

31.05.2008 21:34:00

Andre´

Hallo alle zusammen,
ich möchte aus einem Ordner unter C:\test aus einer TXT Datei folgendes in die Tabelle 1 einlesen.
Folgendes steht in der txt Datei: https://www.herber.de/bbs/user/52729.txt
Jetzt möchte ich folgendes erreichen:
Suche FUNCTION und gebe das was zwischen > und 2)
Suche Farbe und gebe das was zwischen > und Blau)
Suche Benutzer und gebe das was zwischen > und 456)
So soll es dann aussehen: https://www.herber.de/bbs/user/52730.xls
Danach soll die txt.Datei gelöscht werden. Es ist auch immer nur eine txt-Datei im Ordner C:\test vorhanden.
Wenn wieder eine txt Datei im Ordner ist und das Makro gestartet wird, dann soll der gleiche Such- Vorgang wie bereits beschrieben ablaufen. Jedoch soll wenn in der Zelle B2 etwas steht dann in die Zellen B3, D3 und G3 geschrieben werden. Dann B4,D4 und G4 ....
Ich hoffe mir kann jemand helfen und bedanke mich im voraus!
MFG Andre

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Bestimmte Werte aus TXT Datei in Zellen schreiben

31.05.2008 22:16:49

Josef

Hallo Andre,
probier mal.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub ReadFromTextfile()
Dim strFile As String, strTmp As String, varTmp As Variant
Dim lngRow As Long

strFile = "C:\Test\text.txt" ' Pfad zur Textdatei

If Dir(strFile) <> "" Then

    Open strFile For Input As #1

    Line Input #1, strTmp

    Close #1

    varTmp = Split(strTmp, "><")

    With ThisWorkbook.Sheets("Tabelle1") 'Tabelle
        lngRow = Application.Max(2, .Cells(Rows.Count, 2).End(xlUp).Row + 1)
        .Cells(lngRow, 2) = Replace(Replace(Replace(varTmp(1), "FUNCTION", ""), ">", ""), "</", "")
        .Cells(lngRow, 4) = Replace(Replace(Replace(varTmp(2), "Farbe", ""), ">", ""), "</", "")
        .Cells(lngRow, 7) = Replace(Replace(Replace(varTmp(3), "BENUTZER", ""), ">", ""), "</", "")
    End With

    Kill strFile

Else
    MsgBox "Datei nicht gefunden", vbInformation, "Fehler"
End If

End Sub

Gruß Sepp

AW: Bestimmte Werte aus TXT Datei in Zellen schreiben

31.05.2008 22:36:00

Andre´

Hallo Sepp
vielen Dank für den Tipp es funktioniert prima.
Gibt es auch eine Möglichkeit eine txt Datei unabhängig vom Dateinamen einzulesen.
Nach dem Motto
'strFile = "C:\Test\*.txt" ' Pfad zur Textdatei
MFG Andre

AW: Bestimmte Werte aus TXT Datei in Zellen schreiben

31.05.2008 22:41:49

Josef

Hallo Andre,
kein Problem.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub ReadFromTextfile()
Dim strPath As String, strFile As String, strTmp As String, varTmp As Variant
Dim lngRow As Long

strPath = "C:\Test\" ' Pfad zur Textdatei

If Right(strPath, 1) <> "\" Then strPath = strPath & "\"

strFile = Dir(strPath & "*.txt")

If strFile <> "" Then

    Open strPath & strFile For Input As #1

    Line Input #1, strTmp

    Close #1

    varTmp = Split(strTmp, "><")

    With ThisWorkbook.Sheets("Tabelle1") 'Tabelle
        lngRow = Application.Max(2, .Cells(Rows.Count, 2).End(xlUp).Row + 1)
        .Cells(lngRow, 2) = Replace(Replace(Replace(varTmp(1), "FUNCTION", ""), ">", ""), "</", "")
        .Cells(lngRow, 4) = Replace(Replace(Replace(varTmp(2), "Farbe", ""), ">", ""), "</", "")
        .Cells(lngRow, 7) = Replace(Replace(Replace(varTmp(3), "BENUTZER", ""), ">", ""), "</", "")
    End With

    Kill strPath & strFile

Else
    MsgBox "Datei nicht gefunden", vbInformation, "Fehler"
End If

End Sub

Gruß Sepp

Einfach genial DANKE :-)) oT

31.05.2008 22:50:58

Andre´

Beliebteste Forumthreads (12 Monate)

Bestimmte Werte aus TXT Datei in Zellen schreiben

Forumthread: Bestimmte Werte aus TXT Datei in Zellen schreiben

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Bestimmte Werte aus TXT Datei in Zellen schreiben

Forumthread: Bestimmte Werte aus TXT Datei in Zellen schreiben

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread