Kombi Summe & Zählenwenns

Forumthread: Kombi Summe & Zählenwenns

28.08.2024 18:31:13

Möhre_G

Hallo und vorab Danke für Hilfe!

Folgende Formel gibt #DIV/0! wider:

=SUMME(WENN(ODER('[Muster.xlsx]Muster'!$A$2:$A$8333>"";'[Muster.xlsx]Muster'!$T$2:$T$8333>"";'[Muster.xlsx]Muster'!$X$2:$X$8333>"";'[Muster.xlsx]Muster'!$B$2:$B$8333>"";'[Muster.xlsx]Muster'!$V$2:$V$8333>"");1/ZÄHLENWENNS('[Muster.xlsx]Muster'!$A$2:$A$8333;'[Muster.xlsx]Muster'!$A$2:$A$8333;'[Muster.xlsx]Muster'!$T$2:$T$8333;G5;'[Muster.xlsx]Muster'!$V$2:$V$8333;$A$6;'[Muster.xlsx]Muster'!$X$2:$X$8333;$A$2;'[Muster.xlsx]Muster'!$B$2:$B$8333;$A$1)))

Ich versuche hier die Anzahl an Kunden (Dubletten) abhängig von verschiedenen Kriterien zu erfassen.
Die Frage wäre, ob dies überhaupt so mit "Summe" möglich ist, ohne dass das Ergebnis jeweils 0 oder den Fehler ausgibt?
Herzlichen Dank!

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Kombi Summe & Zählenwenns

28.08.2024 18:48:51

daniel
AW: Kombi Summe & Zählenwenns

28.08.2024 19:09:03

Yal
AW: Kombi Summe & Zählenwenns

28.08.2024 19:47:12

daniel
AW: Kombi Summe & Zählenwenns

29.08.2024 09:30:37

Möhre_G
Strategie ändern

29.08.2024 09:38:07

Yal

AW: Kombi Summe & Zählenwenns

28.08.2024 18:48:51

daniel

naja, so ohne Beispieldatei ist es nicht so einfach so eine Monsterformel zu analysieren.

im Prinzip musst du halt die ZählenWenns()=0 für das 1/ZählenWenns() vermeiden.
entweder mit einer zusätzlichen WENN-Abfrage oder einem WENNFEHLER(1/ZählenWenns(...);0)

bei Excel 365 könnte man aber auch eventuell mit FILTER und EINDEUTIG arbeiten.

Gruß Daniel

AW: Kombi Summe & Zählenwenns

28.08.2024 19:09:03

Yal

Hallo Möhre (man spricht sich im Forum per Vorname an ;-)

wenn man deine Formel in einem Texteditor bringt und die Parameter einrückt, bekommt man folgende Sicht:

=SUMME(

	WENN(

		ODER(

			'[Muster.xlsx]Muster'!$A$2:$A$8333>"";

			'[Muster.xlsx]Muster'!$B$2:$B$8333>"";

			'[Muster.xlsx]Muster'!$T$2:$T$8333>"";

			'[Muster.xlsx]Muster'!$V$2:$V$8333>"";

			'[Muster.xlsx]Muster'!$X$2:$X$8333>""

		);

		1/ZÄHLENWENNS(

			'[Muster.xlsx]Muster'!$A$2:$A$8333;'[Muster.xlsx]Muster'!$A$2:$A$8333;

			'[Muster.xlsx]Muster'!$B$2:$B$8333;$A$1;

			'[Muster.xlsx]Muster'!$T$2:$T$8333;G5;

			'[Muster.xlsx]Muster'!$V$2:$V$8333;$A$6;

			'[Muster.xlsx]Muster'!$X$2:$X$8333;$A$2

		)

	)

)

Da sind 2 Sachen sichtbar:
- Dein "Wenn" hat nur ein Wenn-Wahr-Ergebnis und kein Wenn-Falsch. Ein fehlende Wenn-Falsch wird mit "Falsch" befüllt. Für eine Summierung, nicht ideal.
- die erste Bedingung des Zählenwenns vergleicht die Spalte A mit sich selbst, also ist für jeden Zeile wahr.

Ist es nicht so, dass Zählenwenns wird nur eine einzige Wert zurückgeben wird? (oder ist es der Sinne der Vergleich A mit A?). Summe von einen einzige Zahl scheint mir so wenig sinnvoll, dass ich daraus entnehme, dass irgendwas mich entgeht...

Man könnte die Verarbeitung mir Power Query versuchen. Bei 8332 Zeilen + Überschrift aus einer anderen Datei würde es sinn ergeben.

VG
Yal

AW: Kombi Summe & Zählenwenns

28.08.2024 19:47:12

daniel

wenn der jeweils 2. Parameter von ZählenWenns ein Array ist, dann gibt ZählenWenns für jeden Wert des Arrays ein Ergebnis zurück.

der 2. Parameter ist die Bedingung und diese ist in der Regel ein Einzelwert.
wenn als Funktionsparameter ein Einzelwert erwartet wird, aber dort ein Array steht, dann wird das ganze eine Matrixformel und die Formel gibt nicht nur einen, sondern mehrere Werte zurück,

mit deiner Aufschlüsselung würde ich das hier mit Excel 365 so ausrechnen (zur besseren Übersicht habe ich die Tabellenblattbezeichung weggelassen):

=Let(x;Eindeutig(Filter($A$2:$A$8333;($A$2:$A$8333>"")*($B$2:$B$8333=$A$1)*($T$2:$T$8333=G5)*($V$2:$V$8333=$A$6)*($X$2:$X$8333=$A$2);"xxx"));

Wenn(x="xxx";0;Anzahl2(x)))

kleine Einschränkung, das geht so nur, wenn wirklich mit "entspricht Wert" gesucht wird. Dh die Bedingungen dürfen keine Joker(*?) oder Vergleiche enthalten)

Gruß Daniel

AW: Kombi Summe & Zählenwenns

29.08.2024 09:30:37

Möhre_G

Herzlichen Dank an alle für Eure schnelle Hilfe.

Der Grundgedanke war, aus einem Datensheet ein paar Insights zu generieren und diese dann in einem neuen Sheet darzustellen. Das Beispiel war die Anzahl Kunden (Kundennamen inklusive Dubletten in Spalte A), verbunden mit mehreren Kriterien.
Der erste Gedanke war:
=Summe(1/Zählenwenns($A$2:$A$8333;$A$2:$A$8333)
Hat auch soweit funktioniert. Sobald ich aber weitere Kriterien in die "Zählenwenns - Schleife" einbaue, komme ich nicht mehr auf das gewünschte Ergebnis.

Ich werde meine Strategie bezüglich der Verarbeitung ändern und dies nicht über eine Formel lösen, sondern über Hilfstabellen oder Pivots etc. lösen.
Ich dachte, ich kann es eventuell nur über eine Formel lösen.
Danke für Eure Ideen.
Gruß!

Strategie ändern

29.08.2024 09:38:07

Yal

dann werfe ein Auge auf Power Query. Da sind Hilftabelle, -spalten und -formel temporäre Teil davon. Das Ergebnis kannst Du direkt in einem Pivot auswerten, ohne das irgendeine Formel auf einem separaten Blatt zuerst geprüft werden muss.

Ein guter Tutorial: https://excelhero.de/power-query/power-query-ganz-einfach-erklaert/

VG
Yal

Beliebteste Forumthreads (12 Monate)

Forumthread: Kombi Summe & Zählenwenns

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread