Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zahlen in Word mit Zahlen aus Excel ersetzen

Zahlen in Word mit Zahlen aus Excel ersetzen
22.09.2017 14:48:42
Claudia
Hallo Zusammen,
ist es möglich Zahlen in Word durch eine Abgleich/Verknüpfung mit Excel zu ersetzen?
Ich habe hier ein Wordfile (800 Seiten). Diese behinhaltet Zahlen (Nummern), welche
durch neue Nummern ersetzt werden müssen. Die entsprechenden Nummern sind in einer Exceltabelle bereits zugeordnet. Um in Word nicht jede Nummern einzeln manuell austauschen zu müssen, wie bekomme ich dies mit einer klugen Verknüpfung / Abgleich von Excel zu Word automatisiert?
Danke für Eure Hilfe. Ihr würdet mir tagelange Arbeit ersparen... :)
Claudia

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Zahlen in Word mit Zahlen aus Excel ersetzen
22.09.2017 15:28:39
mmat
Wo ist der gemeinsame Nenner?
Ich könnte mir vorstellen, dass es in Word eine Textmarke gibt (z. B. "Position001"), in der eine Zahl steht. Dann gibt's in Excel eine Tabelle; in Spalte A steht der Name der Textmarke (ebenfalls "Position001") und in der Spalte daneben eine (andere) Zahl.
Aus einer derartige Datenstruktur lässt sich mit überschaubarem Aufwand eine Aktualisierung aus Excel realisieren.
Aber wie siehts bei dir aus ?
AW: maybe ...
22.09.2017 15:32:10
Fennek
Hallo,
ob es möglich ist, hängt von den Details ab. Deshalb nur ein Tip:
Lade 1-2 Seiten der Word-Datei UND die dazu passende Excel-Tabelle hoch. Erkläre wie das Matching gehen könnte (bookmarks, Position in einer Tabelle, ID).
Zu überlegen wäre auch, die Frage in einem Word-Forum zu stellen, z.B.
http://office-loesung.de/p/viewforum.php?f=162
http://ms-office-forum.net/forum/forumdisplay.php?f=30
Falls die Frage in mehreren Foren gestellt werden sollte, bitte kenntlich mach.
Zum einlesen:
http://vbanet.blogspot.de/
und nach den codes für Word suchen.
mfg
Anzeige
AW: maybe ...
23.09.2017 15:34:47
Robert
Hallo Claudia,
ich habe mal auf die Schnelle ein Word-Makro geschrieben, das Du in Deiner Word-Datei ausführen kannst. Es sollte die Ersetzungen wie gewünscht machen. Deine Excelliste mit den Entsprechungen sollte ab Zelle A1 in der ersten Tabelle der Datei Mappe1.xlsx im selben Verzeichnis wie das Word-Dokument stehen.
Sub Ersetzen()
Dim xlApp As Excel.Application
Dim xlWkb As Workbook
Dim xlWks As Worksheet
Dim rng As Excel.Range
Dim iCounter As Integer
Set xlApp = CreateObject("Excel.Application")
Set xlWkb = xlApp.Workbooks.Open(ActiveDocument.Path & "\Mappe1.xlsx")
Set xlWks = xlWkb.Worksheets(1)
Set rng = xlWks.Range("A1").CurrentRegion
For iCounter = 1 To rng.Rows.Count
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find
.Text = xlWks.Cells(iCounter, 1)
.Replacement.Text = xlWks.Cells(iCounter, 2)
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
Next
xlWkb.Close
xlApp.Quit
Set xlWks = Nothing
Set xlWkb = Nothing
Set xlApp = Nothing
End Sub
Probiere es mal aus, aber wie immer bei wichtigen / umfangreichen Sachen, am Besten in einer Kopie Deiner Word-Datei.
Gruß
Robert
Anzeige
Zahlen in Word mit Zahlen aus Excel ersetzen
24.09.2017 06:13:54
fcs
Hallo Robert, hallo Claudia,
ich hatte mich auch schon mit dem Problem beschäfftigt.
Vorraussetzung für korrekte Funktion von Roberts Makro:
Die Zuordnung der Zahlen in der Excelliste ist eindeutig! D.h., neue Zahlen kommen nicht in den alten Zahlen vor, alte nicht in den neuen.
Falls die Zuordnung nicht eindeutig ist, dann muss man einigen Aufwand treiben, um die Ersetzungen korrekt durchzuführen.
Wichtige Anpassung in Roberts Makro:
Es müssen immer die ganzen Wörter (Zahlen) ersetzt werden - also
         .MatchWholeWord = True  

Weitere Optimierungen:
  • Variablen für Excel-Objekte als Object deklarieren - dann muss man den Verweis auf die Microsoft Excel x.x Object Library in der Worddatei nicht setzen

  • Excel-Datei schreibgeschützt öffnen

  • Excel-Datei ohne speichern wieder schliessen

  • Excel-Anwendung in der Testphase sichtbar machen

  • Das Makro speichert man am besten in einem allgemeinen Modul in der Word-Normal.dotm.
    Dann ist das Makro jederzeit verfügbar und die Word-Datei bleibt Makrofrei.
    Gruß
    Franz
    Optimiertes Makro:
    'Makro in Word
    'Erstellt/getestet und Word/Excel 2010 unter Windows Vista
    Sub ErsetzenZahlen_aus_Excelliste()
    Dim xlApp As Object 'Excel.Application                'geändert fcs
    Dim xlWkb As Object 'Excel.Workbook                   'geändert fcs
    Dim xlWks As Object 'Excel.Worksheet                  'geändert fcs
    Dim rng As Object ' Excel.Range                       'geändert fcs
    Dim iCounter As Long                                  'geändert fcs
    Set xlApp = CreateObject("Excel.Application")
    xlApp.Visible = True                    'sinnvoll während der Testphase des Makros
    Set xlWkb = xlApp.Workbooks.Open(ActiveDocument.Path & "\Zahlen_in_Word_Ersetzen.xlsx", _
    ReadOnly:=True)                 'Dateiname anpassen - geändert fcs
    Set xlWks = xlWkb.Worksheets(1)
    Set rng = xlWks.Range("A1").CurrentRegion
    For iCounter = 1 To rng.Rows.Count         'Startzeile ggf.anpassen
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
    .Text = xlWks.Cells(iCounter, 1)
    .Replacement.Text = xlWks.Cells(iCounter, 2)
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = True               'geändert fcs - sehr wichtig!!!
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    Next
    xlWkb.Close False                                   'geändert fcs
    xlApp.Quit
    Set xlWks = Nothing
    Set xlWkb = Nothing
    Set xlApp = Nothing
    End Sub
    

    Anzeige
    AW: Zahlen in Word mit Zahlen aus Excel ersetzen
    25.09.2017 12:32:03
    Claudia
    Hallo Robert,hallo Franz,
    ihr seid ja großartig. Ich habe es getestet, funktioniert hervorragend. pure magic :)
    Vielen Dank!!!

    313 Forumthreads zu ähnlichen Themen

    Anzeige
    Anzeige
    Anzeige
    Anzeige

    Beliebteste Forumthreads (12 Monate)

    Anzeige

    Beliebteste Forumthreads (12 Monate)

    Anzeige
    Anzeige
    Anzeige