Herbers Excel/VBA-Archiv

soll heißen .. ich rechne etwas durch... und wenn das ergebnis "gleich" ist... dann soll das ergebnis blinken...

geh mal in der Recherche zu "Suche in den Themenlisten" und gib als Suchbegriff "blinken" an, da gibt's verschiedene Threads, in denen das Problem behandelt ist.

Gruß
Martin Beck

hier mal ein Ansatz für die Zelle A1

in DieseArbeitsmappe

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Ende
End Sub

in die Tabelle
Private Sub Worksheet_Change(ByVal Target As Range)
    If Range("A1") = 10 Then
        ersteFarbe
    Else
        Ende
    End If
End Sub

und in ein Modul
Public ET As Variant

Sub ersteFarbe()
    [a1].Interior.ColorIndex = 3
    ET = Now + TimeValue("00:00:01")
    Application.OnTime ET, "zweiteFarbe"
End Sub

Sub zweiteFarbe()
    [a1].Interior.ColorIndex = 33
    ET = Now + TimeValue("00:00:01")
    Application.OnTime ET, "ersteFarbe"
End Sub

Sub Ende()
    On Error Resume Next
    Application.OnTime EarliestTime:=ET, Procedure:="ErsteFarbe", Schedule:=False
    Application.OnTime EarliestTime:=ET, Procedure:="zweiteFarbe", Schedule:=False
End Sub

Gruß Hajo

getestet werden

der korrigierte Code lautet
in DieserArbeitsmappe

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Ende
End Sub

in der Tabelle
Private Sub Worksheet_Change(ByVal Target As Range)
    If Range("A1") = 10 Then
         If ET = "" Then ersteFarbe
    Else
        Ende
    End If
End Sub

und im Modul
Public ET As Variant

Sub ersteFarbe()
    [a1].Interior.ColorIndex = 3
    ET = Now + TimeValue("00:00:01")
    Application.OnTime ET, "zweiteFarbe"
End Sub

Sub zweiteFarbe()
    [a1].Interior.ColorIndex = 33
    ET = Now + TimeValue("00:00:01")
    Application.OnTime ET, "ersteFarbe"
End Sub

Sub Ende()
    On Error Resume Next
    Application.OnTime EarliestTime:=ET, Procedure:="ErsteFarbe", Schedule:=False
    Application.OnTime EarliestTime:=ET, Procedure:="zweiteFarbe", Schedule:=False
    ET = ""
End Sub

Gruß Hajo

Re: blinkende zahlen ausgabe in excel
von: Dennys
Geschrieben am: 08.06.2002 - 08:56:45

danke hajo,

aber wie kann ich deinen code ändern damit deine vorgabe "10" ein feldwert aus dem arbeitsblatt ist .. z.b. feld B2 ??

Re: blinkende zahlen ausgabe in excel
von: Hajo
Geschrieben am: 08.06.2002 - 16:00:49

Hallo Dennys

schreibe für =10 =Range("B2")

Gruß Hajo