Import von Textdateien

Forumthread: Import von Textdateien

05.02.2005 22:26:29

Textdateien

Hallo Excel Freunde ,
ich suche nach einer Möglichkeit alle Textdateien eines Verzeichnisses in ein Tabellenblatt (nicht in eine Arbeitsmappe) zu importieren .
Wer kann helfen ?

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Import von Textdateien

05.02.2005 22:52:55

Textdateien
AW: Import von Textdateien

05.02.2005 23:05:11

Textdateien
AW: Import von Textdateien

06.02.2005 22:17:41

Textdateien
AW: Import von Textdateien

06.02.2005 23:23:55

Textdateien
AW: Import von Textdateien

07.02.2005 07:20:23

Textdateien

AW: Import von Textdateien

05.02.2005 22:52:55

Textdateien

Hallo A?
Vor kurzem hab ich sowas für jemanden im Forum gemacht.
Probier's mal.

Sub Multi_Text_Import()
'by Josef Ehrensberger
Dim n As Integer
Dim strTemp As String
Dim lRow As Long, i As Long
Dim wks As Worksheet
lRow = 1 'Startzeile in der Tabelle
Set wks = ActiveSheet
With Application.FileSearch
    .LookIn = "D:\Office\Excel\Text" 'Pfad zu deinen Textdateien
    .FileType = msoFileTypeAllFiles
    .Filename = "*.txt"
    .SearchSubFolders = False
    '(True) wenn auch Unterordner durchsucht werden sollen
    .Execute
      For n = 1 To .FoundFiles.Count
         'Import Textfile
         Open .FoundFiles(n) For Input As #1
         Do While Not EOF(1)
            Input #1, strTemp
            wks.Cells(lRow, 1) = strTemp
            lRow = lRow + 1
            Application.StatusBar = lRow

         If lRow = 65536 Then
            i = i + lRow - 1
            wks.Name = i
            wks.Columns("A:A").TextToColumns Destination:=wks.Range("A1"), _
               DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
               ConsecutiveDelimiter:=False, Tab:=True, _
               Semicolon:=True, Comma:=False, Space:=False, Other:=False, FieldInfo _
               :=Array(Array(1, 1))
            wks.Columns.AutoFit
            Set wks = Sheets.Add(after:=wks)
            lRow = 1
         End If

         Loop
         Close #1
      Next

End With
i = i + lRow - 1
wks.Name = i
wks.Columns("A:A").TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
   TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
   Semicolon:=True, Comma:=False, Space:=False, Other:=False, FieldInfo _
   :=Array(Array(1, 1))
wks.Columns.AutoFit
Application.StatusBar = False
End Sub

Gruß Sepp
P.S.: Rückmeldung nicht vergessen!

AW: Import von Textdateien

05.02.2005 23:05:11

Textdateien

Hallo Sepp ,
nun quäle ich mich schon den ganzen Abend mit dem Problem , Deine Lösung hat sofort funktioniert , Danke !!!!!!!!!

AW: Import von Textdateien

06.02.2005 22:17:41

Textdateien

Hallo Josef Ehrensberger ,
wie kann ich bei dieser Art und Weise des Textimports den Dezimal Separator auf "." einstellen ?
Mit freundlichen Grüßen AK

AW: Import von Textdateien

06.02.2005 23:23:55

Textdateien

Hallo A? (willst du deinen Vornamen nicht veraten?)
Probier's mal


wks.Cells(lRow, 1) = strTemp
auszutauschen mit
wks.Cells(lRow, 1) = Replace(strTemp, ",", ".")

Gruß Sepp
P.S.: Rückmeldung nicht vergessen!

AW: Import von Textdateien

07.02.2005 07:20:23

Textdateien

Hallo Josef ,
also mein Vorname lautet Andreas , Dein Tip war erste Klasse !!!!!!!!!!!!!!!!!
bleibt mir eigentlich nur , mich nochmals recht herzlich bei Dir zu bedanken.
Danke !!!!!!!!!!!
Eine Frage noch , kannst Du mir Literatur zum Thema VBA empfehlen ?
Mit freundlichen Grüßen
Andreas Karmann

Beliebteste Forumthreads (12 Monate)

Forumthread: Import von Textdateien

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread