Live-Forum - Die aktuellen Beiträge
Datum
Titel
26.09.2025 08:51:00
Teilinhalt einer Zelle vergleichen
25.09.2025 23:04:12
Einen von drei möglichen Einträgen in einer Zeile suchen
25.09.2025 19:59:48
Lebenserleichternde Datei, im Bezug auf die Essensauswahl
25.09.2025 16:01:26
VBA - Laufzeitfehler 9105 zu viele Zeichen 255
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1116to1120
1116to1120
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Zeilen ausblenden nach einem oder mehreren Kreteri

Forumthread: Zeilen ausblenden nach einem oder mehreren Kreteri

Zeilen ausblenden nach einem oder mehreren Kreteri
Joachim
Hallo Excel-Gemeinde
folgender Code funktioniert und er blendet die angewiesenen Zellen aus
Sub Zeilen_ausblenden()
Sheets("EG aktuell").Rows("3:325").Hidden = True
End Sub
Wie muss der Code umgeschrieben werden, wenn z. B alle Zellen ausgeblendet werden sollen, deren Datum in Spalte D kleiner als 01.08.2009 sind. Zeilen 1 + 2 sollen generell stehen bleiben.
Leider reichen meine VBA Kenntnisse nicht, um das selbst zu progrmmieren.
Vielen Dank für eure Hilfe
Gruß Joachim
Anzeige
AW: Zeilen ausblenden nach einem oder mehreren Kreteri
21.11.2009 18:33:28
Josef
Hallo Joachim,
grundsätzlich geht das so. (eine von vielen Möglichkeiten!)
Sub Zeilen_ausblenden()
  Dim lngRow As Long, lngLast As Long
  Dim rngHide As Range
  
  With Sheets("EG aktuell")
    lngLast = Application.Max(3, .Cells(.Rows.Count, 4).End(xlUp).Row)
    .Rows.Hidden = False
    For lngRow = 3 To lngLast
      If .Cells(lngRow, 4).Value < DateSerial(2008, 8, 1) Then
        If rngHide Is Nothing Then
          Set rngHide = .Rows(lngRow)
        Else
          Set rngHide = Union(rngHide, .Rows(lngRow))
        End If
      End If
    Next
  End With
  
  If Not rngHide Is Nothing Then rngHide.EntireRow.Hidden = True
  
  Set rngHide = Nothing
End Sub


Gruß Sepp

Anzeige
AW: Zeilen ausblenden nach einem oder mehreren Kreteri
21.11.2009 18:44:28
Joachim
Danke Josef!!!
Das funktioniert wunderbar, vielen Dank.
Ich will nicht unverschämt sein, aber eine Sache wäre mir noch sehr wichtig, ich glaube aber, dass das nur über eine sog. INputbox geht, die ich noch nie selbst eingerichtet habe.
Zeilen aus den Spalten z.B. A - D den Wert "Auswertung" enthalten, sollen stehen bleiben, alle anderen sollen ausgeblendet werden. Der Suchwert soll halt beliebig sein.
Wenn es keine Mühe macht, wäre ich sehr dank, was ich jetzt auch schon bin.
Toll!
Danke Joachim
Anzeige
AW: Zeilen ausblenden nach einem oder mehreren Kreteri
21.11.2009 19:00:04
Josef
Hallo Joachim,
ist sicher noch Ausbaubar.
Sub Zeilen_ausblenden()
  Dim lngRow As Long, lngLast As Long
  Dim lngDate As Long, strFind As String
  Dim rngHide As Range
  
  lngDate = Application.InputBox("Geben Sie das Datum ein", "Datum", CStr(Date), Type:=1)
  
  If lngDate = 0 Or Not IsDate(CDate(lngDate)) Then
    MsgBox "Abbruch!" & vbLf & "Ungültiges Datum!", vbExclamation, "Fehler"
    Exit Sub
  End If
  
  strFind = InputBox("Geben Sie den Suchbegriff ein", "Suchbegriff", "Auswertung")
  
  If strFind = "" Then
    MsgBox "Abbruch!" & vbLf & "Ungültiger Suchbegriff", vbExclamation, "Fehler"
    Exit Sub
  End If
  
  With Sheets("EG aktuell")
    lngLast = Application.Max(3, .Cells(.Rows.Count, 4).End(xlUp).Row)
    .Rows.Hidden = False
    For lngRow = 3 To lngLast
      If .Cells(lngRow, 4).Value < lngDate Then
        If Application.CountIf(.Range(.Cells(lngRow, 1), .Cells(lngRow, 4)), strFind) = 0 Then
          If rngHide Is Nothing Then
            Set rngHide = .Rows(lngRow)
          Else
            Set rngHide = Union(rngHide, .Rows(lngRow))
          End If
        End If
      End If
    Next
  End With
  
  If Not rngHide Is Nothing Then rngHide.EntireRow.Hidden = True
  
  Set rngHide = Nothing
End Sub


Gruß Sepp

Anzeige
AW: Zeilen ausblenden nach einem oder mehreren Kreteri
21.11.2009 19:13:25
Joachim
Hallo nochmal,
sicher mag der Code noch ausbaubar sein, aber bestimmt nicht durch mich, dafür reicht es bei weitem nicht.
Der Code funktioiert mit der Datumseingabe,
aber was, wenn ich kein Datum eingebe, also individuell suchen will und alles was den Suchbegriff enthält eingeblendet bleiben soll und der Rest ausgeblendet wird.
Das meinte ich mit beliebig. Kannst du dass noch enpflegen, dann habe ich mich auch wirklich genug deiner Dienste bemüht.
Trotzdem ziehe ich meinen Hut, für das erzielte Ergebnis.
Gruß Joachim
Anzeige
AW: Zeilen ausblenden nach einem oder mehreren Kreteri
21.11.2009 19:45:43
Josef
Hallo Joachim,
na dann so.
Sub Zeilen_ausblenden()
  Dim lngRow As Long, lngLast As Long
  Dim strFind As String, lngDate As Long, strS As String
  Dim rngHide As Range
  
  strFind = InputBox("Geben Sie den Suchbegriff oder ein Datum ein", "Suchbegriff", "Auswertung")
  
  If strFind = "" Then
    MsgBox "Abbruch!" & vbLf & "Ungültiger Suchbegriff", vbExclamation, "Fehler"
    Exit Sub
  End If
  
  If IsDate(strFind) Then
    lngDate = CDate(strFind)
    strS = ""
  Else
    lngDate = 99999
    strS = strFind
  End If
  
  With Sheets("EG aktuell")
    lngLast = Application.Max(3, .Cells(.Rows.Count, 4).End(xlUp).Row)
    .Range(.Cells(3, 1), .Cells(lngLast, 1)).EntireRow.Hidden = False
    For lngRow = 3 To lngLast
      If .Cells(lngRow, 4).Value < lngDate Or Not IsDate(.Cells(lngRow, 4).Value) Then
        If Application.CountIf(.Range(.Cells(lngRow, 1), .Cells(lngRow, 4)), strFind) = 0 Then
          If rngHide Is Nothing Then
            Set rngHide = .Rows(lngRow)
          Else
            Set rngHide = Union(rngHide, .Rows(lngRow))
          End If
        End If
      End If
    Next
  End With
  
  If Not rngHide Is Nothing Then rngHide.EntireRow.Hidden = True
  
  Set rngHide = Nothing
End Sub

Gruß Sepp

Anzeige
AW: Danke!!!!
21.11.2009 20:03:43
Joachim
Das ist super!
Vielen, vielen Dank
Joachim
;

Forumthreads zu verwandten Themen

VBA Zeilen ein/ausblenden + weiters Problem
oblivion

hallo, ich hab mal wieder ein kleines und ein etwas größeres Problem
erstmal zum kleinen. wie bekomme ich es mit hilfe von einem vba hin, wenn ich ein kontrollkästchen mit einem Hacken versehe, dann bestimmte Zeilen (Sagen wir mal Zeile 20 bis 30), die ich vorher versteckt hatte, nun zum vo...
10.08.2008 00:22:06
Thread-ID: 1000558
3 Beiträge
Zeilen einfärben abhängig von Zellwerten
Zellwerten

Hi Leute
Da ich nicht weiß, wie ich nach meinem Problem suchen kann, beschreibe ich es einfach mal kurz. Vielleicht kann mir ja jemand helfen.
Ich habe ein Excel-File, das xSpalten hat und xZeilen.
In einer Spalte (in meinem Fall Spalte F) stehen die verschiedenen Auftragsnummern, a...
18.08.2008 16:57:26
Thread-ID: 1002687
6 Beiträge
Leerzeilen in markieren Bereich einfügen
Ulrich

Hallo zusammen,
ich möchte gerne einen Bereich markieren und dann ein Makro starten, dass im markierten Bereich unter jeder Zeile eine Leerzeile einfügt und dann den gesamten Bereich (Zeilen+Leerzeilen) markiert.
Habe das versucht - geht nicht:
Dim bereich As Range
Set bereich...
26.08.2008 15:36:00
Thread-ID: 1004840
3 Beiträge
Anzeige
Zeilen nach Abfrage einfärben
Dirk

Hallo, ich möchte gerne in einer Tabelle folgendes abfragen:
Wenn in Spalte P der Wert kleiner 0 ist, dann färbe mir die
Entsprechenden Zeilen in Spalte A,B,C, ein.
Mit der bedingten Formatierung haut so etwas nicht hin.
Wer hat eine einfache Idee ?
Gruß Dirk
04.09.2008 07:51:44
Thread-ID: 1007267
5 Beiträge
Zeilen markieren (ohne Formeleinträge)
Selma

Hallo Leute,
ich habe versucht ab Zeile 2 bis letzte gefüllte Zelle der Spalte B (leere Formelergebnisse sollen nicht berücksichtigt werden) die Zeilen zu markieren, leider ohne Erfolg.
Rows("2:" & Range("B65536").End(xlUp).Row).Select
Was muss ich ändern?
Vielen Dank im Vor...
07.09.2008 18:35:00
Thread-ID: 1007992
5 Beiträge
2 Zeilen einfügen + Schleifenweiterlauf
Herbert

Hallo zusammen,
ich bin neu hier und sehr begeistert von diesem Forum/dieser Website - wirklich toll, dass es so etwas gibt:-)
Allerdings habe ich ein kleines VBA-Problem.....
Dim reihe As Integer
Const spalte As Integer = 5 ' Spalte Teilebezeichnung
reihe = 3 ' Tabelle...
16.09.2008 20:06:00
Thread-ID: 1010193
5 Beiträge
Zeilen löschen verhindern
steffen

Hallo Excelgemeinde,
ich scheiere gerade an dem Versuch, mein Tabellenblatt so zu sichern, dass auch nach dem "Blattschutz aufheben" ein Löschen von Zeilen nicht möglich ist. Das einfachste wäre natürlich ein Blattschutz mit Kennwort. Das will ich aber nicht.
Ich dachte da an sowas, wie...
22.09.2008 10:46:33
Thread-ID: 1011401
2 Beiträge
Anzeige
Makro zur Zeilen löschen verfeinern
Matthias

Hallo Zusammen,
ich habe ein Makro, das alle Zeilen löscht in denen kein Inhalt steht.
Allerdings würde ich das Makro gerne so anpassen, dass er eine Zeile komplett löscht, wenn in einer bestimmten Spalte die Zelle leer ist.
Das Makro soll also nicht die gesamte Zeile nach Inhalten...
22.09.2008 13:23:19
Thread-ID: 1011460
4 Beiträge
optimale Zeilenhöhe einer Zeile
Jakob

Hallo,
ich habe ein kleines Problem mit der optimalen Höhe einer Zeile und vielleicht habt Ihr eine Lösung für mein Problem.
Man kann ja unter Zellen formatieren/Textsteuerung den Haken bei Zeilenumbruch anklicken und Excel paßt die Zeilenhöhe automatisch an. Soweit so gut. Wenn ich abe...
24.09.2008 15:24:00
Thread-ID: 1012091
7 Beiträge
VBA Zellen mit x kopieren aber nur bestimmte Zellen
balta

Hallo zusammen,
habe folgendes problem, undzwar sieht meine Tabelle so aus
__A____B______C______D_____E_______F_____G____H
1_x___alf___test1_________________1234___a____ist ein Auto
2_y________________Ulf____test2__________b____ist ein Krad
3
4
5
6_y_____________...
26.09.2008 23:48:47
Thread-ID: 1012775
6 Beiträge
2 Tabellen verbinden ->zeilenweiser Mengenabgleich
Mike

Hallo erstmal,
als begeisterter Forumsleser habe ich schon viele Tage hier verbracht. Jetzt traue ich mich einmal hinein und hoffe auf Eure Hilfe.
Ich habe 2 laaange Tabellen. In Tabelle1 stehen (neben anderen Daten)
Teilenummer, Auftragsnummer, (Lieferwoche) und Stück und in Tabel...
16.10.2008 11:37:00
Thread-ID: 1016808
8 Beiträge
Anzeige
Anzahl Zeilen mit identischen Eintrag errechnen
Matthias

Hallo,
ich will die folgenden Aufgabe per Makro lösen: ich will wissen, wie viele Zeilen es unterhalb einer Ausgangszeile mit dem gleichen Inhalt gibt, bis der Inhalt der nächsten darunter liegenden Zelle wechselt.
Beispiel:
Dresdner Bank Banken
Historie
Historie
...
16.10.2008 12:50:00
Thread-ID: 1016833
2 Beiträge
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken
Anzeige

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige