einzelnes WS in bestehende Datei auf LW speichern

Forumthread: einzelnes WS in bestehende Datei auf LW speichern

06.01.2017 09:35:46

gjunge

Hallo,
mein Makro läuft aktuell wie gewünscht.


Private Sub cmd_save_Click()
ActiveSheet.Copy After:=Worksheets(Worksheets.Count)
ActiveSheet.Name = Range("E19").Text & "_" & Range("H20")
ActiveSheet.Shapes.Range(Array("cmd_loadUF")).Select
Selection.Delete
ActiveSheet.Shapes.Range(Array("cmd_save")).Select
Selection.Delete
Application.Goto Reference:="R9C1:R10C1"
Selection.EntireRow.Hidden = False
ActiveWindow.ScrollWorkbookTabs Position:=xlFirst
Sheets("Eingabe").Select
... usw.
End Sub

Aber nun gibt es eine neue Anforderung ...
Das Blatt soll nun nicht mehr in der aktuell geöffneten Datei gespeichert werden sondern in eine bereits bestehende Datei auf einem LW (z. B. \\server\pool\Pro\NP\AM XXX\*.xls). Die aktuelle Datei soll also nur als Vorlage dienen und nicht abgeändert werden. In den Zellen H18 und I18 stehen die beiden Werte, welche den LW- Pfad "mitbringen". H18 = AM (da steht immer AM); I18 = XXX (max. Länge sind drei Ziffern). Wie bekomme ich das hin? Kann mir bitte jemand helfen?
Danke und Grüße

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: einzelnes WS in bestehende Datei auf LW speichern

06.01.2017 19:47:11

Dieter

Hallo gjunge,
das könnte mit dem folgenden Programm gehen. Den Namen der Zieldatei musst du noch einsetzen.


Private Sub cmd_save_Click()
Dim blattName As String
Dim sh As Object
Dim wbZ As Workbook      ' Zieldatei
Dim zielDatei As String
Dim zielVerzeichnis As String
zielDatei = "Ziel.xlsx"
zielVerzeichnis = "\\server\pool\Pro\NP\AM " & Me.Range("L18") & "\"
If Dir(zielVerzeichnis & zielDatei) = "" Then
MsgBox zielVerzeichnis & zielDatei & vbNewLine & "existiert nicht"
Exit Sub
End If
Set wbZ = Workbooks.Open(Filename:=zielVerzeichnis & zielDatei)
blattName = Me.Range("E19") & "_" & Me.Range("H20")
For Each sh In wbZ.Sheets
If UCase$(sh.Name) = UCase$(blattName) Then
MsgBox blattName & vbNewLine & "existiert schon in der Zieldatei"
GoTo Ende
End If
Next sh
Me.Copy After:=wbZ.Worksheets(wbZ.Worksheets.Count)
ActiveSheet.Name = blattName
ActiveSheet.Shapes("cmd_loadUF").Delete
ActiveSheet.Shapes("cmd_save").Delete
ActiveSheet.Rows("9:10").Hidden = False
Ende:
wbZ.Save
wbZ.Close
End Sub

Viele Grüße
Dieter

AW: einzelnes WS in bestehende Datei auf LW speichern

09.01.2017 09:16:06

gjunge

Hallo Dieter,
Mit dem Code klappt es super :)
Danke und Grüße

Beliebteste Forumthreads (12 Monate)

einzelnes WS in bestehende Datei auf LW speichern

Forumthread: einzelnes WS in bestehende Datei auf LW speichern

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

einzelnes WS in bestehende Datei auf LW speichern

Forumthread: einzelnes WS in bestehende Datei auf LW speichern

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread