Anzahl wenn kleiner gleich

Forumthread: Anzahl wenn kleiner gleich

Andre

Hallo alle zusammen,
ich benötige eine Formel in der Spalte G, die mir die Anzahl aus der Summe der Zahlen beginnend ab H bis IV
bildet die kleiner gleich der Zahl aus Spalte F ist.
In dem nachfolgenden Bsp. habe ich die Zellen gelb markiert die für die Summe und anschl. daraus die Anzahl gebildet werden soll.
Tabelle1

	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y
1		Anzahl der Zahlen(H:IV) die in Summe <= der Zahl der SpalteF ist
2	250	4	20	150	0	40	50	0	70	0	51	4	5	15	0	0	0	0	0	12
3	350	8	24	0	50	87	55	90	41	2	3	9	8	14	0	0	2	0	0	1

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Hier eine Bsp. Datei
https://www.herber.de/bbs/user/63928.xls
Ich hoffe mir kann jemand helfen.
Vielen Dank im Voraus!
MFG Andre

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Anzahl wenn kleiner gleich

19.08.2009 15:36:15

D.Saster

Hallo,
=ZÄHLENWENN(H2:IV2;"<=" &F2)
Gruß
Dierk

AW: Anzahl wenn kleiner gleich

19.08.2009 15:38:36

{Boris}

Hi Andre,
D2:
{=MAX((TEILERGEBNIS(9;INDIREKT("ZS8:ZS"&SPALTE(H:Y);))<=F2)*SPALTE(A:R))}
und runterkopieren.
ARRAYformel: {geschweifte Klammern} nicht mit eingeben, sondern Formeleingabe mit gleichzeitig Strg+Shift+Enter abschließen.
Grüße Boris

In G2 natürlich (nicht D2) ___oT

19.08.2009 15:41:39

{Boris}

...

AW: In G2 natürlich (nicht D2) ___oT

19.08.2009 15:53:56

Andre

Hallo,
danke für die schnelle Antwort, die Lösung von Boris scheint zu funktionieren.
Ich werde dies ausgibig testen.
Falls noch etwas unklar sein sollte, dann melde ich mich nochmals.
MFG Andre

Alternativen

19.08.2009 21:38:24

Hallo Andre,
wenn Du nur positive Zahlen im Bereich rechts stehen hast, kannst Du die Anzahl auch per HÄUFIGKEIT ermitteln ( Zeile 1 und 2 )
gibt es auch negative Zahlen und wird die Anzahl der Zahlen
a) bis zur letzten Grenze gesucht, dann Formel lt. Zeilen 3 / 4
b) bis zur ersten Grenze, dann Formel lt. Zeile 5 / 6

Tabelle2

	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y
1	210	250	4	20	150		40	50		70		51	4	5	15						12
2	349	350	8	24		50	87	55	90	41	2	3	9	8	14		10	2			1
3	250	250	8	20	150		40	50	-89	70	9	51	4	5	15						12
4	349	350	14	24		50	87	55	90	41	2	3	9	8	14		-34	2			1
5	210	250	4	20	150		40	50	-89	70	9	51	4	5	15						12
6	349	350	8	24		50	87	55	90	41	2	3	9	8	14		-34	2			1

Formeln der Tabelle

E1 : =SUMME(BEREICH.VERSCHIEBEN(H1;;;;G1))
G1 : =HÄUFIGKEIT(TEILERGEBNIS(9;INDIREKT("ZS8:ZS"&SPALTE(H:IV); 0)); F1)
G2 : =HÄUFIGKEIT(TEILERGEBNIS(9;INDIREKT("ZS(1):ZS("&SPALTE(H:$IV)-SPALTE(G2)&")";0)); F2)
G3 : =VERWEIS(9;1/(F3>=TEILERGEBNIS(9;INDIREKT("ZS(1):ZS("&SPALTE(H:$IV)-SPALTE(G3)&")";0))); SPALTE(3:3))
G4 : =VERWEIS(9;1/(F4>=TEILERGEBNIS(9;INDIREKT("ZS(1):ZS("&SPALTE(H:$IV)-SPALTE(G4)&")";0))); SPALTE(4:4))
G5 : {=VERGLEICH(1;--(TEILERGEBNIS(9;INDIREKT("ZS(1):ZS("&SPALTE(H:$IV)-SPALTE(G5)&")";0))>F5); 0)-1}
G6 : {=VERGLEICH(1;--(TEILERGEBNIS(9;INDIREKT("ZS(1):ZS("&SPALTE(H:$IV)-SPALTE(G6)&")";0))>F6); 0)-1}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Bei den Formeln ab Zeile 3 dürfen im Bereich vor der Formel Spalten hinzugefügt / gelöscht werden...
Servus aus dem Salzkammergut
Franz

Beliebteste Forumthreads (12 Monate)

Forumthread: Anzahl wenn kleiner gleich

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Anzahl wenn kleiner gleich

Forumthread: Anzahl wenn kleiner gleich

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread