Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zellen verbinden & die Zahl 0?

Zellen verbinden & die Zahl 0?
01.11.2008 14:21:34
Markus
Hallo,
ich bearbeite gerade meine Telefonliste um diese in die neue Anlage zu übersielen.
Ich habe aber ein paar Probleme:
1. Im Moment steht in einer Zelle z.B. 02134 - 25232 Büro
Diese Nummer kann die Anlage aber nicht lesen, es darf nur die Nummer dort stehen, also 021342523.
2. Die Nummern in den Zellen sind meist unterschiedlich, um die Nummer zu isolieren bekomme ich das über suchen und ersetzen irgenwie hin, also alle Leerzeichen etc raus usw. dann habe ich am ende noch 0213425232Büro stehen.
Wie kann ich die Nummer dann von dem Text trennen?
Und wenn das irgendwie geht glaube ich das ich dann vorne immer die Null verliere und es kommt 213425232 raus und mir fehlt dann die Null?
Kann jemand einen Tipp geben wie ich die Liste formatiere?
Vielen Dank.
Markus
P.S. ist eine CSV datei.

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Zellen verbinden & die Zahl 0?
01.11.2008 14:34:14
Tino
Hallo,
hier mal eine Möglichkeit mit Formel
 AB
102134 - 25232 Büro0213425232

Formeln der Tabelle
ZelleFormel
B1=TEIL(ERSETZEN(A1;FINDEN(" ";A1); 3;""); 1;FINDEN(" ";ERSETZEN(A1;FINDEN(" ";A1); 3;"")))

Gruß Tino
Anzeige
AW: Zellen verbinden & die Zahl 0?
01.11.2008 14:53:21
Tino
Hallo,
hier noch eine VBA Variante
Modul Modul1
Option Explicit 
 
Sub Formatieren() 
Dim rRange As Range 
Dim vArea 
Dim i As Long 
Dim tempText As String 
 
'Bereich mit Telefonnummern 
Set rRange = Range("A1", Cells(Rows.Count, "A").End(xlUp)) 
'Zellen in einer Area speichern 
vArea = rRange 
rRange.NumberFormat = "@" 'Zellen in Textformat 
 
For i = 1 To Ubound(vArea) 
 If vArea(i, 1) <> "" Then 'leere Zellen überspringen 
  'Zeichen ersetzen 
  tempText = Replace(vArea(i, 1), " - ", "") 
  'Zahlen bis leerzeichen zurückgeben 
  vArea(i, 1) = Left$(tempText, InStrRev(tempText, " ") - 1) 
 End If 
Next i 
'Area in Zelle zurückschreiben 
rRange = vArea 
 
 
End Sub 


Gruß Tino

Anzeige
AW: Zellen verbinden & die Zahl 0?
01.11.2008 15:11:00
Markus
Vielen Dank schon aml, aber so bekomme ich das nicht hin, hier mal ein Beispiel für die Formatierung wie sie jetzt aussieht, am Ende sollen nur noch die Nummern das stehen, allerdings muss die Null vorne auch gezeigt werden. Bei einer Zahl wird die wohl immer wieder verschluckt glaube ich.
0281 9857121
04471-93 19 291
04340 - 499 0324
02152 91 67 222
02152 91 67 201
02845-29 52 603
0203362601 Büro
02066 -41 70 724
02159 - 67 66 805
0211-40 54 2335
0208-77 96 50
02841 - 57 345
02162 - 224 22 Büro
Danke und Gruss Markus
AW: Zellen verbinden & die Zahl 0?
01.11.2008 15:26:00
Tino
Hallo,
machen wir es eben so.
Modul Modul1
Option Explicit 
 
Sub Formatieren() 
Dim rRange As Range 
Dim vArea 
Dim i As Long, A As Integer 
Dim tempText As String 
 
'Bereich mit Telefonnummern 
Set rRange = Range("A1", Cells(Rows.Count, "A").End(xlUp)) 
'Zellen in einer Area speichern 
vArea = rRange 
rRange.NumberFormat = "@" 'Zellen in Textformat 
 
For i = 1 To Ubound(vArea) 
 If vArea(i, 1) <> "" Then 'leere Zellen überspringen 
  'Zeichen ersetzen 
  tempText = Replace(vArea(i, 1), " ", "") 
  tempText = Replace(tempText, "-", "") 
   
  For A = Len(tempText) To 1 Step -1 'suche erste Zahl von hinten 
   If IsNumeric(Mid(tempText, A, 1)) Then 
    tempText = Left$(tempText, A) 
    Exit For 
   End If 
  Next A 
 
  vArea(i, 1) = tempText 
 End If 
Next i 
'Area in Zelle zurückschreiben 
rRange = vArea 
 
 
End Sub 


Gruß Tino

Anzeige
AW: Zellen verbinden & die Zahl 0?
01.11.2008 15:36:38
Tino
Hallo,
möchtest Du die Zellen nicht ins Textformat umstellen, kann man dies auch so machen, mit dem führenden Hochkomma ' .
Modul Modul1
Option Explicit 
 
Sub FormatierenOhneTextFormat() 
Dim rRange As Range 
Dim vArea 
Dim i As Long, A As Integer 
Dim tempText As String 
 
'Bereich mit Telefonnummern 
Set rRange = Range("A1", Cells(Rows.Count, "A").End(xlUp)) 
'Zellen in einer Area speichern 
vArea = rRange 
 
For i = 1 To Ubound(vArea) 
 If vArea(i, 1) <> "" Then 'leere Zellen überspringen 
  'Zeichen ersetzen 
  tempText = Replace(vArea(i, 1), " ", "") 
  tempText = Replace(tempText, "-", "") 
   
  For A = Len(tempText) To 1 Step -1 'suche erste Zahl von hinten 
   If IsNumeric(Mid(tempText, A, 1)) Then 
    tempText = Left$(tempText, A) 
    Exit For 
   End If 
  Next A 
 
  vArea(i, 1) = "'" & tempText 
 End If 
Next i 
'Area in Zelle zurückschreiben 
rRange = vArea 
 
 
End Sub 


Gruß Tino

www.VBA-Excel.de


Anzeige
AW: Zellen verbinden & die Zahl 0?
01.11.2008 16:30:00
Markus
Vielen Dank Tino, hat geklappt !!

318 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige